configure.ac

   1 dnl RRDtool AutoConf script ...
   2 dnl ---------------------------
   3 dnl
   4 dnl Created by Jeff Allen, Tobi Oetiker, Blair Zajac
   5 dnl
   6 dnl Inspiration from http://autoconf-archive.cryp.to
   7
   8 dnl tell automake the this script is for rrdtool
   9
  10 dnl the official version number is
  11 dnl a.b.c
  12 AC_INIT([rrdtool],[1.3.4])
  13
  14 dnl for testing a numberical version number comes handy
  15 dnl the released version are
  16 dnl a.bccc
  17 dnl the devel versions will be something like
  18 dnl a.b999yymmddhh
  19 NUMVERS=1.3004
  20 AC_SUBST(NUMVERS)
  21
  22 dnl for the linker to understand which versions the library are compatible with
  23 dnl each other we must keep a separate library version cout of the format c:r:a.
  24 dnl - if only implementation changed but all interfaces are kept, do r++
  25 dnl - if only functionality was added do c++,r=0,a++
  26 dnl - if any functionality was removed do c++,r=0,a=0.
  27 dnl
  28 dnl see http://sourceware.org/autobook/autobook/autobook_91.html
  29 dnl
  30 LIBVERS=4:3:0
  31 AC_SUBST(LIBVERS)
  32
  33 AC_CANONICAL_TARGET
  34 AM_INIT_AUTOMAKE
  35 AM_MAINTAINER_MODE
  36
  37 AC_CONFIG_HEADERS([rrd_config.h])
  38
  39 dnl all our local stuff like install scripts and include files
  40 dnl is in there
  41
  42
  43 dnl determine the type of system we are running on
  44
  45 AC_SUBST(VERSION)
  46
  47 AC_PREFIX_DEFAULT( /usr/local/rrdtool-$PACKAGE_VERSION )
  48
  49 dnl Minimum Autoconf version required.
  50 AC_PREREQ(2.59)
  51
  52 dnl At the TOP of the HEADER
  53
  54 AH_TOP([
  55 #ifndef RRD_CONFIG_H
  56 #define RRD_CONFIG_H
  57
  58 /* IEEE can be prevented from raising signals with fpsetmask(0) */
  59 #undef MUST_DISABLE_FPMASK
  60
  61 /* IEEE math only works if SIGFPE gets actively set to IGNORE */
  62 #undef MUST_DISABLE_SIGFPE
  63
  64 /* realloc does not support NULL as argument */
  65 #undef NO_NULL_REALLOC
  66
  67 /* lets enable madvise defines in NetBSD */
  68 #if defined(__NetBSD__)
  69 # if !defined(_NETBSD_SOURCE)
  70 #  define _NETBSD_SOURCE
  71 # endif
  72 #endif
  73
  74 ])
  75
  76 AH_BOTTOM([
  77
  78 #ifdef MUST_HAVE_MALLOC_MALLOC_H
  79 #  include <malloc/malloc.h>
  80 #endif
  81
  82 #include <rrd_config_bottom.h>
  83
  84 #endif
  85 ])
  86
  87 dnl Process Special Options
  88 dnl -----------------------------------
  89
  90 dnl How the vertical axis label is printed
  91 AC_ARG_VAR(RRDGRAPH_YLEGEND_ANGLE,
  92  [Vertical label angle: -90.0 (default) or 90.0])
  93 AC_DEFINE_UNQUOTED(RRDGRAPH_YLEGEND_ANGLE,${RRDGRAPH_YLEGEND_ANGLE:-90.0},
  94  [Vertical label angle: -90.0 (default) or 90.0])
  95
  96 AC_ARG_ENABLE(rrdcgi,[  --disable-rrdcgi        disable building of rrdcgi],
  97 [],[enable_rrdcgi=yes])
  98
  99 dnl Check if we run on a system that has fonts
 100 AC_ARG_WITH(rrd-default-font,
 101 [  --with-rrd-default-font=[OPTIONS]  set the full path to your default font.],
 102 [RRD_DEFAULT_FONT=$withval],[
 103   if test -d ${WINDIR:-nodir}/cour.ttf ; then
 104         RRD_DEFAULT_FONT=`cd $WINDIR;pwd`/cour.ttf
 105   else
 106         RRD_DEFAULT_FONT='"DejaVu Sans Mono,Bitstream Vera Sans Mono,monospace,Courier"'
 107   fi
 108 ])
 109
 110 dnl Use mmap in rrd_update instead of seek+write
 111 AC_ARG_ENABLE([mmap],
 112 [  --disable-mmap          disable mmap in rrd_update, use seek+write instead],
 113 [],
 114 [enable_mmap=yes])
 115
 116 AC_ARG_ENABLE(pthread,[  --disable-pthread       disable multithread support],
 117 [],[enable_pthread=yes])
 118
 119 AC_ARG_ENABLE(static-programs,
 120      [  --enable-static-programs  Build static programs],
 121      [case "${enableval}" in
 122        yes) staticprogs=yes ;;
 123        no)  staticprogs=no ;;
 124        *) AC_MSG_ERROR(bad value ${enableval} for --enable-static-programs) ;;
 125      esac],[staticprogs=no])
 126 AM_CONDITIONAL(STATIC_PROGRAMS,[test "x$staticprogs" = "xyes"])
 127
 128
 129 CONFIGURE_PART(Audit Compilation Environment)
 130
 131
 132 dnl Check for the compiler and static/shared library creation.
 133 AC_PROG_CC
 134 AC_PROG_CPP
 135 AC_PROG_LIBTOOL
 136
 137 dnl Try to detect/use GNU features
 138 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 139
 140 dnl which flags does the compiler support?
 141 if test "x$GCC" = "xyes"; then
 142   for flag in -fno-strict-aliasing -Wall -std=c99 -pedantic -Wundef -Wshadow -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Winline -Wold-style-definition -W; do
 143     oCFLAGS="$CFLAGS"
 144     CFLAGS="$CFLAGS $flag"
 145     cachename=rd_cv_gcc_flag_`echo $flag|sed 's/[[^A-Za-z]]/_/g'`
 146     AC_CACHE_CHECK([if gcc likes the $flag flag], $cachename,
 147        [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[return 0 ]])],[eval $cachename=yes],[eval $cachename=no])])
 148     if eval test \$$cachename = no; then
 149          CFLAGS="$oCFLAGS"
 150     fi
 151   done
 152 fi
 153
 154
 155
 156 AC_SUBST(RRD_DEFAULT_FONT)
 157
 158 CONFIGURE_PART(Checking for Header Files)
 159
 160 dnl Checks for header files.
 161 AC_HEADER_STDC
 162 AC_HEADER_DIRENT
 163 AC_CHECK_HEADERS(features.h sys/stat.h sys/types.h fcntl.h locale.h fp_class.h malloc.h unistd.h ieeefp.h math.h sys/times.h sys/param.h sys/resource.h signal.h float.h stdio.h stdlib.h errno.h string.h ctype.h)
 164
 165 dnl Checks for typedefs, structures, and compiler characteristics.
 166 AC_C_CONST
 167 AC_HEADER_TIME
 168 AC_STRUCT_TM
 169
 170 CONFIGURE_PART(Test Library Functions)
 171
 172 dnl Checks for libraries.
 173 AC_CHECK_FUNC(acos, , AC_CHECK_LIB(m, acos))
 174
 175
 176 dnl add pic flag in any case this makes sure all our code is relocatable
 177 eval `./libtool --config | grep pic_flag`
 178 CFLAGS="$CFLAGS $pic_flag"
 179
 180
 181 dnl Checks for library functions.
 182 AC_FUNC_STRFTIME
 183 AC_FUNC_VPRINTF
 184
 185 AC_C_BIGENDIAN
 186
 187 dnl for each function found we get a definition in config.h
 188 dnl of the form HAVE_FUNCTION
 189
 190 AC_CHECK_FUNCS(tzset fsync mbstowcs opendir readdir chdir chroot getuid setlocale strerror strerror_r snprintf vsnprintf fpclass class fp_class isnan memmove strchr mktime getrusage gettimeofday)
 191
 192 CONFIGURE_PART(Map/Fadvis/Madvise checking)
 193
 194 dnl Could use these to know if we need to provide a prototype
 195 dnl AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 196
 197 dnl check for fdatasync. Solaris has fdatasync in the librt
 198
 199 AC_CHECK_FUNCS(fdatasync, [],  AC_CHECK_LIB(rt, fdatasync, [LIBS="${LIBS} -lrt"; AC_DEFINE(HAVE_FDATASYNC)],[]))
 200 dnl if there is no fdatasync we may get lucky with fsync
 201 AC_CHECK_FUNCS(fsync)
 202
 203
 204 dnl XXX: dunno about windows.. add AC_CHECK_FUNCS(munmap) there too?
 205 if test "x$enable_mmap" = "xyes"; then
 206   case "$host" in
 207   *cygwin*)
 208     # the normal mmap test does not work in cygwin
 209     AC_CHECK_FUNCS(mmap)
 210     if test "x$ac_cv_func_mmap" = "xyes"; then
 211       ac_cv_func_mmap_fixed_mapped=yes
 212     fi
 213   ;;
 214   *)
 215     AC_CHECK_HEADERS(sys/mman.h)
 216     AC_FUNC_MMAP
 217     AC_CHECK_FUNCS(mmap munmap msync)
 218     AC_CHECK_DECLS(madvise, [], [], [#ifdef HAVE_SYS_MMAN_H
 219                                      # include <sys/mman.h>
 220                                      #endif])
 221     if test "x$ac_cv_have_decl_madvise" = "xyes";
 222     then
 223       AC_CHECK_FUNCS(madvise)
 224     else
 225       AC_CHECK_FUNCS(posix_madvise)
 226       if test "x$ac_cv_func_posix_madvise" != "xyes"; then
 227         AC_MSG_WARN([madvise() nor posix_madvise() found.])
 228       fi
 229     fi
 230   ;;
 231   esac
 232   if test "x$ac_cv_func_mmap" != "xyes";
 233   then
 234     AC_MSG_ERROR([--enable-mmap requested but mmap() was not detected])
 235 dnl enable_mmap="no"
 236   fi
 237 fi
 238
 239 dnl can we use posix_fadvise
 240 AC_CHECK_DECLS(posix_fadvise, [], [], [#define _XOPEN_SOURCE 600
 241 #include <fcntl.h>])
 242 AC_CHECK_FUNCS(posix_fadvise)
 243
 244 CONFIGURE_PART(Libintl Processing)
 245
 246
 247 dnl gettext
 248 GETTEXT_PACKAGE=rrdtool
 249 AC_SUBST(GETTEXT_PACKAGE)
 250 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package])
 251
 252 AM_GLIB_GNU_GETTEXT()
 253
 254 AC_ARG_ENABLE(libintl,[  --disable-libintl        i18n support (libintl)],
 255 [],[enable_libintl=yes])
 256
 257 if test x$enable_libintl = xyes; then
 258   IT_PROG_INTLTOOL([0.35.0],[no-xml])
 259 fi
 260
 261 if test x$enable_libintl = xyes -a x$MSGFMT = xno; then
 262   AC_MSG_WARN(I could not find msgfmt. Diabeling libintl build.)
 263   enable_libintl=no
 264 fi
 265
 266 if test x$enable_libintl = xyes; then
 267   AC_CHECK_HEADERS(libintl.h,[],[AC_MSG_RESULT(disabeling libintl build); enable_libintl=no])
 268 fi
 269
 270 if test x$enable_libintl = xyes ; then
 271   dnl it seems bsd synstems need to link against libintl
 272   dnl when compiling rrdupdate. lets check
 273   AC_CHECK_LIB(intl, libintl_gettext,[LIB_LIBINTL="-lintl"])
 274 fi
 275
 276 dnl use for linking rrdupdate
 277 AC_SUBST(LIB_LIBINTL)
 278
 279 dnl do not touch the po stuff if we are not going to build intl
 280 AM_CONDITIONAL(BUILD_LIBINTL,[test x$enable_libintl = xyes])
 281
 282 if test x$enable_libintl = xyes; then
 283    AC_DEFINE([BUILD_LIBINTL], [], [Use this in code sections to mark them for libintl build])
 284 fi
 285
 286 CONFIGURE_PART(IEEE Math Checks)
 287
 288
 289 dnl actual code to check if this works
 290 AC_CHECK_FUNCS(fpclassify, ,
 291   [AC_MSG_CHECKING(for fpclassify with <math.h>)
 292     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 293 volatile int x;volatile float f; ]], [[x = fpclassify(f)]])],[AC_MSG_RESULT(yes)
 294       AC_DEFINE(HAVE_FPCLASSIFY)],[AC_MSG_RESULT(no)])])
 295
 296 AC_CHECK_FUNCS(isinf, ,
 297   [AC_MSG_CHECKING(for isinf with <math.h>)
 298     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 299 volatile int x;volatile float f;  ]], [[x = isinf(f)]])],[AC_MSG_RESULT(yes)
 300       AC_DEFINE(HAVE_ISINF)],[AC_MSG_RESULT(no)])])
 301
 302 dnl finite is BSD, isfinite is C99, so prefer the latter
 303 AC_CACHE_CHECK([whether isfinite is broken],[ac_cv_have_broken_isfinite],[
 304 AC_TRY_RUN([
 305 #ifdef HAVE_MATH_H
 306 #include <math.h>
 307 #endif
 308 #ifdef HAVE_FLOAT_H
 309 #include <float.h>
 310 #endif
 311 int main ()
 312 {
 313 #ifdef isfinite
 314 #ifdef LDBL_MAX
 315   if (!isfinite(LDBL_MAX)) return 1;
 316 #endif
 317 #ifdef DBL_MAX
 318   if (!isfinite(DBL_MAX)) return 1;
 319 #endif
 320 #endif
 321 return 0;
 322 }],[ac_cv_have_broken_isfinite=no],[ac_cv_have_broken_isfinite=yes],[
 323 case "${target}" in
 324   hppa*-*-hpux*) ac_cv_have_broken_isfinite=yes ;;
 325   *-solaris2.8) ac_cv_have_broken_isfinite=yes ;;
 326   *-solaris2.9) ac_cv_have_broken_isfinite=yes ;;
 327   *) ac_cv_have_broken_isfinite=no ;;
 328 esac])
 329 ])
 330
 331 dnl the test does not seem to work on solaris 2.8/9
 332 dnl so lets fix this by hand
 333 case "${target}" in
 334   *-solaris2.8) ac_cv_have_broken_isfinite=yes ;;
 335   *-solaris2.9) ac_cv_have_broken_isfinite=yes ;;
 336 esac
 337
 338 if test "x$ac_cv_have_broken_isfinite" = "xno"; then
 339   AC_DEFINE(HAVE_ISFINITE)
 340 else
 341   AC_CHECK_FUNCS(finite,[],
 342       [AC_CHECK_FUNCS(isfinite,[],
 343          [AC_MSG_CHECKING(for isfinite with <math.h>)
 344           AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 345 volatile int x;volatile float f;  ]],[[x = isfinite(f)]])],[AC_MSG_RESULT(yes)
 346                 AC_DEFINE(HAVE_ISFINITE)],[AC_MSG_RESULT(no)])])])
 347 fi
 348
 349 AC_FULL_IEEE
 350
 351 CONFIGURE_PART(Resolve Portability Issues)
 352
 353 dnl Do we need getopt_long
 354
 355 build_getopt=no
 356 RRD_GETOPT_LONG="LIBC_HAS_GETOPT_LONG"
 357 AC_CHECK_FUNC(getopt_long,[],[
 358 RRD_GETOPT_LONG="getopt_long"
 359 build_getopt=yes
 360 ])
 361 AC_SUBST(RRD_GETOPT_LONG)
 362 AM_CONDITIONAL(BUILD_GETOPT,[test $build_getopt = yes])
 363
 364 dnl what does realloc do if it gets called with a NULL pointer
 365
 366 AC_CACHE_CHECK([if realloc can deal with NULL], rd_cv_null_realloc,
 367 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
 368               int main(void){
 369               char *x = NULL;
 370               x = realloc (x,10);
 371               if (x==NULL) return 1;
 372               return 0;
 373              }]])],[rd_cv_null_realloc=yes],[rd_cv_null_realloc=nope],[:])])
 374
 375 if test x"$rd_cv_null_realloc" = xnope; then
 376 AC_DEFINE(NO_NULL_REALLOC)
 377 fi
 378
 379 AC_LANG_PUSH(C)
 380 dnl solaris has some odd defines it needs in order to propperly compile ctime_r
 381 AC_MSG_CHECKING([if ctime_r need special care to act posixly correct])
 382 AC_LINK_IFELSE(
 383     AC_LANG_PROGRAM(
 384            [[#include <time.h>]],
 385            [[ctime_r(NULL,NULL,0)]]
 386                    ),
 387     [ CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
 388       AC_LINK_IFELSE(
 389           AC_LANG_PROGRAM(
 390                 [[#include <time.h>]],
 391                 [[ctime_r(NULL,NULL)]]
 392                          ),
 393           [AC_MSG_RESULT([yes, this seems to be solaris style])],
 394           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 395       )
 396     ],
 397     [ AC_LINK_IFELSE(
 398           AC_LANG_PROGRAM(
 399                 [[#include <time.h>]],
 400                 [[ctime_r(NULL,NULL)]]
 401                          ),
 402           [AC_MSG_RESULT(no)],
 403           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 404       )
 405     ]
 406 )
 407 AC_LANG_POP(C)
 408
 409 dnl Check for pthreads
 410 dnl http://autoconf-archive.cryp.to/acx_pthread.m4
 411
 412 AC_SUBST(MULTITHREAD_CFLAGS)
 413 AC_SUBST(MULTITHREAD_LDFLAGS)
 414
 415 if test $enable_pthread != no; then
 416  ACX_PTHREAD([
 417     MULTITHREAD_CFLAGS=$PTHREAD_CFLAGS
 418     MULTITHREAD_LDFLAGS=$PTHREAD_LIBS
 419              ],
 420              [])
 421 fi
 422
 423 dnl since we use lots of *_r functions all over the code we better
 424 dnl make sure they are known
 425
 426 if test  "x$x_rflag" != "xno"; then
 427    CPPFLAGS="$CPPFLAGS $x_rflag"
 428 fi
 429
 430 AM_CONDITIONAL(BUILD_MULTITHREAD,[test $enable_pthread != no])
 431
 432 AC_LANG_PUSH(C)
 433 dnl see if we have to include malloc/malloc.h
 434 AC_MSG_CHECKING([do we need malloc/malloc.h])
 435 AC_LINK_IFELSE(
 436     AC_LANG_PROGRAM(
 437            [[#include <stdlib.h>]],
 438            [[malloc(1)]]
 439                    ),
 440     [ AC_MSG_RESULT([nope, works out of the box]) ],
 441     [ AC_LINK_IFELSE(
 442           AC_LANG_PROGRAM(
 443                 [[#include <stdlib.h>
 444                   #include <malloc/malloc.h>]],
 445                 [[malloc(1)]]
 446                          ),[
 447            AC_DEFINE([MUST_HAVE_MALLOC_MALLOC_H])
 448            AC_MSG_RESULT([yes we do])],
 449           [AC_MSG_ERROR([Can not figure how to compile malloc])]
 450       )
 451     ]
 452 )
 453 AC_LANG_POP(C)
 454
 455 CONFIGURE_PART(Find 3rd-Party Libraries)
 456
 457
 458 AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
 459
 460
 461 CORE_LIBS="$LIBS"
 462
 463 dnl EX_CHECK_ALL(z,          zlibVersion,               zlib.h,                 zlib,        1.2.3,  http://www.gzip.org/zlib/, "")
 464 dnl EX_CHECK_ALL(png,        png_access_version_number, png.h,                  libpng,      1.2.10,  http://prdownloads.sourceforge.net/libpng/, "")
 465 dnl EX_CHECK_ALL(freetype,   FT_Init_FreeType,          ft2build.h,             freetype2,   2.1.10,  http://prdownloads.sourceforge.net/freetype/, /usr/include/freetype2)
 466 dnl EX_CHECK_ALL(fontconfig, FcInit,                    fontconfig.h,           fontconfig,  2.3.1,  http://fontconfig.org/release/, /usr/include)
 467 EX_CHECK_ALL(cairo,      cairo_font_options_create,     cairo.h,                cairo-png,   1.4.6,  http://cairographics.org/releases/, "")
 468 EX_CHECK_ALL(cairo,      cairo_svg_surface_create,      cairo-svg.h,            cairo-svg,   1.4.6,  http://cairographics.org/releases/, "")
 469 EX_CHECK_ALL(cairo,      cairo_pdf_surface_create,      cairo-pdf.h,            cairo-pdf,   1.4.6,  http://cairographics.org/releases/, "")
 470 EX_CHECK_ALL(cairo,      cairo_ps_surface_create,       cairo-ps.h,             cairo-ps,    1.4.6,  http://cairographics.org/releases/, "")
 471 dnl EX_CHECK_ALL(glib-2.0,   glib_check_version,        glib.h,                 glib-2.0,    2.12.12, ftp://ftp.gtk.org/pub/glib/2.12/, "")
 472 EX_CHECK_ALL(pango-1.0,  pango_cairo_context_set_font_options,  pango/pango.h,  pangocairo,  1.17,    http://ftp.gnome.org/pub/GNOME/sources/pango/1.17, "")
 473 EX_CHECK_ALL(xml2,       xmlParseFile,                  libxml/parser.h,        libxml-2.0,        2.6.31,  http://xmlsoft.org/downloads.html, /usr/include/libxml2)
 474
 475 if test "$EX_CHECK_ALL_ERR" = "YES"; then
 476   AC_MSG_ERROR([Please fix the library issues listed above and try again.])
 477 fi
 478
 479 ALL_LIBS="$LIBS"
 480 LIBS=
 481
 482 AC_SUBST(CORE_LIBS)
 483 AC_SUBST(ALL_LIBS)
 484
 485 CONFIGURE_PART(Prep for Building Language Bindings)
 486
 487 dnl Check for Perl and friends
 488 PATH=$PATH:/usr/perl5/bin
 489 export PATH
 490 AC_PATH_PROG(PERL, perl, no)
 491 AC_PATH_PROG(POD2MAN, pod2man, no)
 492 AC_PATH_PROG(POD2HTML, pod2html, no)
 493
 494
 495 AC_ARG_ENABLE(perl,[  --disable-perl          do not build the perl modules],
 496 [],[enable_perl=yes])
 497
 498
 499 AC_ARG_VAR(PERLCC, [[] C compiler for Perl modules])
 500 AC_ARG_VAR(PERLCCFLAGS, [[] CC flags for Perl modules])
 501 AC_ARG_VAR(PERLLD, [[same as PERLCC] Linker for Perl modules])
 502 AC_ARG_VAR(PERLLDFLAGS, [[] LD flags for Perl modules])
 503
 504 if test "x$PERL" = "xno" -o  x$enable_perl = xno; then
 505         COMP_PERL=
 506 else
 507         COMP_PERL="perl_piped perl_shared"
 508         AC_MSG_CHECKING(for the perl version you are running)
 509         PERL_VERSION=`$PERL -MConfig -e 'print $Config{version}'`
 510         AC_MSG_RESULT($PERL_VERSION)
 511         if test -z "$PERLCC"; then
 512             AC_MSG_CHECKING(for the C compiler perl wants to use to build its modules)
 513             perlcc=`$PERL -MConfig -e 'print $Config{cc}'`
 514             AC_MSG_RESULT($perlcc)
 515             if test ! -x "$perlcc"; then
 516                 AC_PATH_PROG(PERL_CC, ${perlcc}, no)
 517                 if test "$PERL_CC" = "no"; then
 518                     AC_MSG_WARN([
 519 I would not find the Compiler ($perlcc) that was originally used to compile
 520 your perl binary. You should either make sure that this compiler is
 521 available on your system, pick an other compiler and set PERLCC
 522 appropriately, or use a different perl setup that was compiled locally.
 523
 524 I will disable the compilation of the RRDs perl module for now.
 525 ])
 526                     COMP_PERL="perl_piped"
 527                 fi
 528             fi
 529         fi
 530 fi
 531
 532 AC_MSG_CHECKING(Perl Modules to build)
 533 AC_MSG_RESULT(${COMP_PERL:-No Perl Modules will be built})
 534
 535 # Options to pass when configuring perl module
 536 ppref=$prefix
 537 test "$ppref" = 'NONE' && ppref=$ac_default_prefix
 538
 539 PERL_MAKE_OPTIONS="PREFIX="'$(DESTDIR)'"$ppref LIB="'$(DESTDIR)'"$ppref/lib/perl/$PERL_VERSION"
 540
 541 dnl pass additional perl options when generating Makefile from Makefile.PL
 542 AC_ARG_ENABLE(perl-site-install,
 543 [  --enable-perl-site-install   by default the rrdtool perl modules are installed
 544                           together with rrdtool in $prefix/lib/perl. You have to
 545                           put a 'use lib qw($prefix/lib/perl)' into your scripts
 546                           when you want to use them. When you set this option
 547                           the perl modules will get installed wherever
 548                           your perl setup thinks it is best.],
 549 [PERL_MAKE_OPTIONS=],[])
 550
 551 if test ! -z "$PERLCC"; then
 552    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CC=$PERLCC"
 553
 554    if test ! -z "$PERLCCFLAGS"; then
 555        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CCFLAGS=$PERLCCFLAGS"
 556    fi
 557
 558    if test -z "$PERLLD"; then
 559        PERLLD=$PERLCC
 560    fi
 561    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LD=$PERLLD"
 562
 563    if test ! -z "$PERLLDFLAGS"; then
 564        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LDFLAGS=$PERLLDFLAGS"
 565    fi
 566 fi
 567
 568 AC_ARG_WITH(perl-options,
 569 [  --with-perl-options=[OPTIONS]  options to pass on command-line when
 570                           generating Makefile from Makefile.PL. If you set this
 571                           option, interesting things may happen unless you know
 572                           what you are doing!],
 573 [PERL_MAKE_OPTIONS=$withval])
 574
 575 AC_SUBST(PERL_MAKE_OPTIONS)
 576 AC_SUBST(PERL)
 577 AC_SUBST(COMP_PERL)
 578 AC_SUBST(PERL_VERSION)
 579
 580 dnl Check for Ruby.
 581 AC_PATH_PROG(RUBY, ruby, no)
 582
 583 AC_ARG_ENABLE(ruby,[  --disable-ruby          do not build the ruby modules],
 584 [],[enable_ruby=yes])
 585
 586 AC_MSG_CHECKING(if ruby modules can be built)
 587
 588 if test "x$RUBY" = "xno" -o  x$enable_ruby = xno; then
 589         COMP_RUBY=
 590         AC_MSG_RESULT(No .. Ruby not found or disabled)
 591 else
 592         if $RUBY -e 'require "mkmf"' >/dev/null 2>&1; then
 593                 COMP_RUBY="ruby"
 594                 AC_MSG_RESULT(YES)
 595         else
 596                 COMP_RUBY=
 597                 AC_MSG_RESULT(Ruby found but mkmf is missing! Install the -dev package)
 598         fi
 599 fi
 600
 601 rpref=$prefix
 602 test "$rpref" = 'NONE' && rpref=$ac_default_prefix
 603
 604 dnl pass additional ruby options when generating Makefile from Makefile.PL
 605 AC_ARG_ENABLE(ruby-site-install,
 606 [  --enable-ruby-site-install   by default the rrdtool ruby modules are installed
 607                           together with rrdtool in $prefix/lib/ruby. You have to
 608                           add $prefix/lib/ruby/$ruby_version/$sitearch to you $: variable
 609                           for ruby to find the RRD.so file.],
 610 [RUBY_MAKE_OPTIONS=],[RUBY_MAKE_OPTIONS="sitedir="'$(DESTDIR)'"$rpref/lib/ruby"])
 611
 612
 613 AC_ARG_WITH(ruby-options,
 614 [  --with-ruby-options=[OPTIONS]  options to pass on command-line when
 615                           generating Makefile from extconf.rb. If you set this
 616                           option, interesting things may happen unless you know
 617                           what you are doing!],
 618 [RUBY_MAKE_OPTIONS=$withval])
 619
 620 AC_SUBST(RUBY_MAKE_OPTIONS)
 621 AC_SUBST(RUBY)
 622 AC_SUBST(COMP_RUBY)
 623
 624
 625 enable_tcl_site=no
 626
 627 AC_ARG_ENABLE(tcl,[  --disable-tcl           do not build the tcl modules],
 628 [],[enable_tcl=yes])
 629
 630 if test  "$enable_tcl" = "yes"; then
 631   dnl Check for Tcl.
 632   withval=""
 633   AC_ARG_WITH(tcllib,[  --with-tcllib=DIR       location of the tclConfig.sh])
 634   enable_tcl=no
 635   for dir in $withval /usr/lib /usr/local/lib /usr/lib/tcl8.4 /usr/lib/tcl8.3 ; do
 636     AC_MSG_CHECKING(for tclConfig.sh in $dir)
 637     if test -f "$dir/tclConfig.sh" ; then
 638         tcl_config=$dir/tclConfig.sh
 639         enable_tcl=yes
 640         AC_MSG_RESULT(yes)
 641         break
 642     else
 643         AC_MSG_RESULT(no)
 644     fi
 645   done
 646
 647   if test "$enable_tcl" = "no"; then
 648         AC_MSG_WARN([tclConfig.sh not found - Tcl interface will not be built])
 649   else
 650         . $tcl_config
 651         TCL_PACKAGE_DIR="$TCL_PACKAGE_PATH/tclrrd$VERSION"
 652         if test -n "$TCL_INC_DIR"; then
 653           TCL_INCLUDE_SPEC="$TCL_INCLUDE_SPEC -I$TCL_INC_DIR"
 654         fi
 655   fi
 656   AC_ARG_ENABLE(tcl,[  --enable-tcl-site        install the tcl extension in the tcl tree],
 657   [],[enable_tcl_site=yes])
 658
 659 fi
 660
 661 AM_CONDITIONAL(BUILD_TCL, test "$enable_tcl" = "yes" )
 662 AM_CONDITIONAL(BUILD_TCL_SITE, test "$enable_tcl_site" = "yes" )
 663
 664
 665 AC_SUBST(TCL_PREFIX)
 666 AC_SUBST(TCL_SHLIB_CFLAGS)
 667 AC_SUBST(TCL_SHLIB_LD)
 668 AC_SUBST(TCL_SHLIB_SUFFIX)
 669 AC_SUBST(TCL_PACKAGE_PATH)
 670 AC_SUBST(TCL_LD_SEARCH_FLAGS)
 671 AC_SUBST(TCL_STUB_LIB_SPEC)
 672 AC_SUBST(TCL_VERSION)
 673 AC_SUBST(TCL_PACKAGE_DIR)
 674 AC_SUBST(TCL_INCLUDE_SPEC)
 675
 676 AC_ARG_ENABLE(python,[  --disable-python        do not build the python modules],
 677 [],[enable_python=yes])
 678
 679 if test  "$enable_python" = "yes"; then
 680 dnl Check for python
 681 AM_PATH_PYTHON(2.3,[],[enable_python=no])
 682 AM_CHECK_PYTHON_HEADERS(,[enable_python=no;AC_MSG_WARN(could not find Python headers)])
 683 fi
 684
 685 if test  x$enable_python = xno; then
 686         COMP_PYTHON=
 687 else
 688         COMP_PYTHON="python"
 689 fi
 690
 691 AC_SUBST(COMP_PYTHON)
 692
 693 dnl Check for nroff
 694 AC_PATH_PROGS(NROFF, gnroff nroff)
 695 AC_PATH_PROGS(TROFF, groff troff)
 696
 697 AC_ARG_VAR(RRDDOCDIR, [[DATADIR/doc/PACKAGE-VERSION] Documentation directory])
 698 if test -z "$RRDDOCDIR"; then
 699    RRDDOCDIR='${datadir}/doc/${PACKAGE}-${VERSION}'; fi
 700
 701
 702 CONFIGURE_PART(Apply Configuration Information)
 703
 704 AC_CONFIG_FILES([examples/shared-demo.pl])
 705 AC_CONFIG_FILES([examples/piped-demo.pl])
 706 AC_CONFIG_FILES([examples/stripes.pl])
 707 AC_CONFIG_FILES([examples/bigtops.pl])
 708 AC_CONFIG_FILES([examples/minmax.pl])
 709 AC_CONFIG_FILES([examples/4charts.pl])
 710 AC_CONFIG_FILES([examples/perftest.pl])
 711 AC_CONFIG_FILES([examples/Makefile])
 712 AC_CONFIG_FILES([doc/Makefile])
 713 AC_CONFIG_FILES([po/Makefile.in])
 714 AC_CONFIG_FILES([src/Makefile])
 715 AC_CONFIG_FILES([src/librrd.sym.in])
 716 AC_CONFIG_FILES([src/librrd.pc])
 717 AC_CONFIG_FILES([bindings/Makefile])
 718 AC_CONFIG_FILES([bindings/tcl/Makefile])
 719 AC_CONFIG_FILES([bindings/tcl/ifOctets.tcl])
 720 AC_CONFIG_FILES([Makefile])
 721
 722 AC_CONFIG_COMMANDS([default],[[ chmod +x examples/*.pl]],[[]])
 723 AC_OUTPUT
 724
 725 AC_MSG_CHECKING(in)
 726 AC_MSG_RESULT(and out again)
 727
 728 echo $ECHO_N "ordering CD from http://tobi.oetiker.ch/wish $ECHO_C" 1>&6
 729 sleep 1
 730 echo $ECHO_N ".$ECHO_C" 1>&6
 731 sleep 1
 732 echo $ECHO_N ".$ECHO_C" 1>&6
 733 sleep 1
 734 echo $ECHO_N ".$ECHO_C" 1>&6
 735 sleep 1
 736 echo $ECHO_N ".$ECHO_C" 1>&6
 737 sleep 1
 738 AC_MSG_RESULT([ just kidding ;-)])
 739 echo
 740 echo "----------------------------------------------------------------"
 741 echo "Config is DONE!"
 742 echo
 743 echo "          With MMAP IO: $enable_mmap"
 744 echo "      Build rrd_getopt: $build_getopt"
 745 echo "       Static programs: $staticprogs"
 746 echo "          Perl Modules: $COMP_PERL"
 747 echo "           Perl Binary: $PERL"
 748 echo "          Perl Version: $PERL_VERSION"
 749 echo "          Perl Options: $PERL_MAKE_OPTIONS"
 750 echo "          Ruby Modules: $COMP_RUBY"
 751 echo "           Ruby Binary: $RUBY"
 752 echo "          Ruby Options: $RUBY_MAKE_OPTIONS"
 753 echo "    Build Tcl Bindings: $enable_tcl"
 754 echo " Build Python Bindings: $enable_python"
 755 echo "          Build rrdcgi: $enable_rrdcgi"
 756 echo "       Build librrd MT: $enable_pthread"
 757 echo "     Link with libintl: $enable_libintl"
 758 echo
 759 echo "             Libraries: $ALL_LIBS"
 760 echo
 761 echo "Type 'make' to compile the software and use 'make install' to "
 762 echo "install everything to: $prefix."
 763 echo
 764 echo "       ... that wishlist is NO JOKE. If you find RRDtool useful"
 765 echo "make me happy. Go to http://tobi.oetiker.ch/wish and"
 766 echo "place an order."
 767 echo
 768 echo "                               -- Tobi Oetiker <tobi@oetiker.ch>"
 769 echo "----------------------------------------------------------------"