configure.ac

   1 dnl
   2 dnl  $Id$
   3 dnl
   4
   5 AC_INIT(ncurses MPD client, 0.12~git, max@duempel.org, ncmpc)
   6 AC_CONFIG_SRCDIR([src/main.c])
   7 AM_INIT_AUTOMAKE([gnu 1.6 dist-bzip2])
   8 AM_CONFIG_HEADER([config.h])
   9 AC_CONFIG_MACRO_DIR([m4])
  10
  11 dnl Check for programs
  12 AC_PROG_CC_C99
  13 AC_PROG_INSTALL
  14 AC_PROG_LIBTOOL
  15
  16 dnl =======================================================
  17 dnl initialize variables
  18 dnl =======================================================
  19
  20 dnl i18n
  21 ALL_LINGUAS="es da de fr gl no ru sv"
  22
  23 set -- $CFLAGS
  24
  25 dnl
  26 dnl Check for types
  27 dnl
  28
  29 AC_MSG_RESULT([$ac_have_socklen_t])
  30
  31 dnl
  32 dnl Check for headers
  33 dnl
  34
  35 AC_CHECK_HEADER([locale.h],
  36                 AC_DEFINE([HAVE_LOCALE_H], [1], [locale.h]),
  37                 ,)
  38
  39
  40 dnl
  41 dnl Check for functions
  42 dnl
  43 AC_CHECK_FUNCS([strcasestr])
  44
  45
  46 dnl
  47 dnl Check for libraries
  48 dnl
  49
  50 dnl Try to find the socket functions
  51 AC_CHECK_FUNC([socket],
  52               [],
  53               [AC_CHECK_LIB([socket],[socket],[LIBS="$LIBS -lsocket"],
  54                             [AC_MSG_ERROR(No UNIX socket API found)])
  55               ])
  56
  57 dnl Try to find the gethostbyname functions
  58 AC_CHECK_FUNC([gethostbyname],
  59               [],
  60               [AC_CHECK_LIB([nsl],[gethostbyname],[LIBS="$LIBS -lnsl"],
  61                             [AC_MSG_ERROR(No UNIX gethostbyname API found)])
  62               ])
  63
  64
  65 dnl ncurses
  66 ncurses=auto
  67 AC_ARG_WITH([ncurses],
  68             AC_HELP_STRING([--with-ncurses], [compile/link with ncurses library] ),
  69             [ncurses=ncurses])
  70 AC_ARG_WITH(ncursesw,
  71             AC_HELP_STRING([--with-ncursesw], [compile/link with wide-char ncurses library @<:@default@:>@]),
  72             [ncurses=ncursesw])
  73
  74 if test "x$ncurses" = "xauto"; then
  75         AC_CHECK_LIB([ncursesw],
  76                      [initscr],
  77                      [ncurses=ncursesw],
  78                      [ncurses=ncurses])
  79 fi
  80
  81 AC_CHECK_LIB([$ncurses],
  82              [initscr],
  83              [LIBS="$LIBS -l$ncurses"],
  84              [AC_MSG_ERROR($ncurses library is required)])
  85
  86
  87
  88 dnl Check for glib-2.4
  89 PKG_CHECK_MODULES([GLIB],
  90                   [glib-2.0 >= 2.4],
  91                   [glib24=yes],
  92                   [AC_MSG_WARN([glib-2.4 is required for NLS support!])])
  93 if test "x$glib24" != "xyes"; then
  94    PKG_CHECK_MODULES([GLIB],
  95                      [glib-2.0 >= 2.2],
  96                      [nls=no],
  97                      [AC_MSG_ERROR([glib-2.2 is required])])
  98 fi
  99
 100
 101 dnl i18n
 102 AM_NLS
 103 if test "x$glib24" = "xyes"; then
 104   nls=$USE_NLS
 105 else
 106   USE_NLS=no
 107   AC_SUBST(USE_NLS)
 108 fi
 109
 110 if test "x$nls" = "xyes"; then
 111    AM_GLIB_GNU_GETTEXT
 112    GETTEXT_PACKAGE=$PACKAGE
 113    AC_SUBST(GETTEXT_PACKAGE)
 114    AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],
 115                       ["${GETTEXT_PACKAGE}"],
 116                       [gettext domain])
 117   nls=$gt_cv_have_gettext
 118   if test "x$nls" != "xyes"; then
 119      AC_MSG_WARN([NLS support disabled!])
 120   fi
 121 else
 122   AM_PO_SUBDIRS
 123 fi
 124
 125 dnl disbale raw mode
 126 AC_MSG_CHECKING([Place the terminal into raw mode])
 127 AC_ARG_ENABLE([raw-mode],
 128         AC_HELP_STRING([--disable-raw-mode],
 129                        [Disable raw terminal mode]),
 130                        [use_raw=$enableval],
 131                        [use_raw=yes])
 132 AC_MSG_RESULT([$use_raw])
 133 if test "x$use_raw" = "xyes" ; then
 134   AC_DEFINE([ENABLE_RAW_MODE], [1], [Place the terminal into raw mode])
 135 fi
 136
 137 dnl enable colors
 138 AC_MSG_CHECKING([color support])
 139 AC_ARG_ENABLE([colors],
 140         AC_HELP_STRING([--enable-colors],
 141                        [Enable color support]),
 142                        [use_colors=$enableval],
 143                        [use_colors=no])
 144 AC_MSG_RESULT([$use_colors])
 145 if test "x$use_colors" = "xyes" ; then
 146     AC_DEFINE([ENABLE_COLORS], [1], [Enable color support])
 147 fi
 148
 149 dnl Debugging
 150 AC_MSG_CHECKING([whether to build with debug support])
 151 AC_ARG_ENABLE([debug],
 152               AC_HELP_STRING([--enable-debug],
 153                              [Enable debugging @<:@default=no@:>@]),
 154               [enable_debug="$enableval"],
 155               [enable_debug=no])
 156 AC_MSG_RESULT([$enable_debug])
 157 if test "x$enable_debug" = "xyes" ; then
 158     CFLAGS="$CFLAGS -g"
 159 else
 160     CFLAGS="$CFLAGS -DNDEBUG"
 161 fi
 162
 163 dnl CFLAGS
 164
 165 AC_SUBST(AM_CFLAGS)
 166
 167 CHECK_CFLAG([-Wall])
 168 CHECK_CFLAG([-Wextra])
 169 CHECK_CFLAG([-Wno-deprecated-declarations])
 170 CHECK_CFLAG([-Wmissing-prototypes])
 171 CHECK_CFLAG([-Wdeclaration-after-statement])
 172 CHECK_CFLAG([-Wshadow])
 173 CHECK_CFLAG([-Wpointer-arith])
 174 CHECK_CFLAG([-Wstrict-prototypes])
 175 CHECK_CFLAG([-Wcast-qual])
 176 CHECK_CFLAG([-Wwrite-strings])
 177
 178 dnl Optional screen - help screen
 179 #AC_MSG_CHECKING([whether to include the help screen])
 180 #AC_ARG_ENABLE([help-screen],
 181 #              AC_HELP_STRING([--enable-help-screen],
 182 #                            [Enable the help screen @<:@default=yes@:>@]),
 183 #             [help_screen="$enableval"],
 184 #             [help_screen=yes])
 185 #AC_MSG_RESULT([$help_screen])
 186 #if test "x$help_screen" = "xyes" ; then
 187 #   AC_DEFINE(ENABLE_HELP_SCREEN, 1, [Enable the help screen])
 188 #fi
 189
 190 dnl Optional screen - browse screen
 191 #AC_MSG_CHECKING([whether to include the browse screen])r
 192 #AC_ARG_ENABLE([browse-screen],
 193 #              AC_HELP_STRING([--enable-browse-screen],
 194 #                            [Enable the browse screen @<:@default=yes@:>@]),
 195 #             [browse_screen="$enableval"],
 196 #             [browse_screen=yes])
 197 #AC_MSG_RESULT([$browse_screen])
 198 #if test "x$browse_screen" = "xyes" ; then
 199 #   AC_DEFINE(ENABLE_BROWSE_SCREEN, 1, [Enable the browse screen])
 200 #fi
 201
 202 dnl Optional - curses getmouse support
 203 AC_MSG_CHECKING([whether to include mouse support])
 204 AC_ARG_ENABLE([mouse],
 205               AC_HELP_STRING([--enable-mouse],
 206                              [Enable curses getmouse support @<:@default=yes@:>@]),
 207               [getmouse="$enableval"],
 208               [getmouse=yes])
 209 AC_MSG_RESULT([$getmouse])
 210 if test "x$getmouse" = "xyes" ; then
 211    AC_CHECK_LIB([$ncurses],
 212                 [getmouse],
 213                 [AC_DEFINE([HAVE_GETMOUSE], [1], [$ncurses - getmouse()])],
 214                 [])
 215 fi
 216
 217 dnl Optional screen - artist
 218 AC_MSG_CHECKING([whether to include the artist screen])
 219 AC_ARG_ENABLE([artist-screen],
 220               AC_HELP_STRING([--enable-artist-screen],
 221                              [Enable artist screen (EXPERIMENTAL) @<:@default=no@:>@]),
 222               [artist_screen="$enableval"],
 223               [artist_screen=no])
 224 AC_MSG_RESULT([$artist_screen])
 225 if test "x$artist_screen" = "xyes" ; then
 226     AC_DEFINE(ENABLE_ARTIST_SCREEN, 1, [Enable artist screen])
 227 fi
 228
 229 AM_CONDITIONAL(ENABLE_ARTIST_SCREEN, test x$artist_screen = xyes)
 230
 231 dnl Optional screen - search
 232 AC_MSG_CHECKING([whether to include the search screen])
 233 AC_ARG_ENABLE([search-screen],
 234               AC_HELP_STRING([--enable-search-screen],
 235                              [Enable search screen (EXPERIMENTAL) @<:@default=yes@:>@]),
 236               [search_screen="$enableval"],
 237               [search_screen=yes])
 238 AC_MSG_RESULT([$search_screen])
 239 if test "x$search_screen" = "xyes" ; then
 240     AC_DEFINE(ENABLE_SEARCH_SCREEN, 1, [Enable search screen])
 241 fi
 242
 243 AM_CONDITIONAL(ENABLE_SEARCH_SCREEN, test x$search_screen = xyes)
 244
 245 dnl Optional screen - key editor
 246 AC_MSG_CHECKING([whether to include the key editor screen])
 247 AC_ARG_ENABLE([key-screen],
 248               AC_HELP_STRING([--enable-key-screen],
 249                              [Enable key editor screen @<:@default=yes@:>@]),
 250               [keydef_screen="$enableval"],
 251               [keydef_screen=yes])
 252 AC_MSG_RESULT([$keydef_screen])
 253 if test "x$keydef_screen" = "xyes" ; then
 254     AC_DEFINE(ENABLE_KEYDEF_SCREEN, 1, [Enable key editor screen])
 255 fi
 256
 257 AM_CONDITIONAL(ENABLE_KEYDEF_SCREEN, test x$keydef_screen = xyes)
 258
 259 dnl Optional screen - lyrics
 260 AC_MSG_CHECKING([whether to include the lyrics screen])
 261 AC_ARG_ENABLE([lyrics-screen],
 262               AC_HELP_STRING([--enable-lyrics-screen],
 263                              [Enable lyrics screen @<:@default=no@:>@]),
 264               [lyrics_screen="$enableval"],
 265               [lyrics_screen=no])
 266 if test "x$lyrics_screen" = "xyes" ; then
 267     AC_DEFINE(ENABLE_LYRICS_SCREEN, 1, [Enable lyrics screen])
 268 fi
 269
 270 AM_CONDITIONAL(ENABLE_LYRICS_SCREEN, test x$lyrics_screen = xyes)
 271
 272 AC_MSG_RESULT([$lyrics_screen])
 273
 274 AC_ARG_WITH([lyrics-plugin-dir],
 275         AC_HELP_STRING([[--with-lyrics-plugin-dir[=DIRECTORY]]],
 276                        [Directory where lyrics plugins are stored @<:@default=PREFIX/lib/ncmpc/lyrics@:>@]),
 277        [lyrics_plugin_dir=$withval],
 278        [lyrics_plugin_dir=""])
 279 if test "x${lyrics_plugin_dir}" = "x"; then
 280     if test "x${prefix}" = "xNONE"; then
 281         lyrics_plugin_dir="${ac_default_prefix}/lib/ncmpc/lyrics"
 282     else
 283         lyrics_plugin_dir="${prefix}/lib/ncmpc/lyrics"
 284     fi
 285 fi
 286 AC_DEFINE_UNQUOTED([LYRICS_PLUGIN_DIR], ["$lyrics_plugin_dir"],
 287                   [Directory to search for lyrics plugins])
 288 AC_SUBST(lyrics_plugin_dir)
 289
 290 dnl Default host
 291 AC_MSG_CHECKING([for default MPD host])
 292 AC_ARG_WITH([default-host],
 293             AC_HELP_STRING([--with-default-host=ARG],
 294                            [Default MPD host @<:@localhost@:>@]),
 295             [DEFAULT_HOST="$withval"],
 296             [DEFAULT_HOST="localhost"])
 297 AC_MSG_RESULT([$DEFAULT_HOST])
 298 AC_DEFINE_UNQUOTED([DEFAULT_HOST], ["$DEFAULT_HOST"], [Default MPD host])
 299
 300 dnl Default port
 301 AC_MSG_CHECKING([for default MPD port])
 302 AC_ARG_WITH([default-port],
 303             AC_HELP_STRING([--with-default-port=ARG],
 304                            [Default port @<:@6600@:>@]),
 305             [DEFAULT_PORT="$withval"],
 306             [DEFAULT_PORT="6600"])
 307 AC_MSG_RESULT([$DEFAULT_PORT])
 308 AC_DEFINE_UNQUOTED([DEFAULT_PORT],     [$DEFAULT_PORT],   [Default MPD port])
 309 AC_DEFINE_UNQUOTED([DEFAULT_PORT_STR], ["$DEFAULT_PORT"], [Default MPD port])
 310
 311 dnl Default timedisplay type
 312 AC_MSG_CHECKING([for default timedisplay type])
 313 AC_ARG_WITH([default-timedisplay_type],
 314             AC_HELP_STRING([--with-default-timedisplay_type=ARG],
 315                            [default_timedisplay]),
 316             [DEFAULT_TIMEDISPLAY_TYPE="$withval"],
 317             [DEFAULT_TIMEDISPLAY_TYPE="elapsed"])
 318 AC_MSG_RESULT([$DEFAULT_TIMEDISPLAY_TYPE])
 319 AC_DEFINE_UNQUOTED([DEFAULT_TIMEDISPLAY_TYPE], ["$DEFAULT_TIMEDISPLAY_TYPE"], [Default way to display time, either 'elapsed' or 'remaining'])
 320 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile po/Makefile.in po/Makefile])
 321 AC_OUTPUT