configure.ac

   1 dnl RRDtool AutoConf script ...
   2 dnl ---------------------------
   3 dnl
   4 dnl Created by Jeff Allen, Tobi Oetiker, Blair Zajac
   5 dnl
   6 dnl Inspiration from http://autoconf-archive.cryp.to
   7
   8 dnl tell automake the this script is for rrdtool
   9
  10 dnl the official version number is
  11 dnl a.b.c
  12 AC_INIT([rrdtool],[1.3.7])
  13
  14 dnl for testing a numberical version number comes handy
  15 dnl the released version are
  16 dnl a.bccc
  17 dnl the devel versions will be something like
  18 dnl a.b999yymmddhh
  19 NUMVERS=1.3007
  20 AC_SUBST(NUMVERS)
  21
  22 dnl for the linker to understand which versions the library are compatible with
  23 dnl each other we must keep a separate library version cout of the format c:r:a.
  24 dnl - if only implementation changed but all interfaces are kept, do r++
  25 dnl - if only functionality was added do c++,r=0,a++
  26 dnl - if any functionality was removed do c++,r=0,a=0.
  27 dnl
  28 dnl see http://sourceware.org/autobook/autobook/autobook_91.html
  29 dnl
  30 LIBVERS=4:6:0
  31 AC_SUBST(LIBVERS)
  32
  33 AC_CANONICAL_TARGET
  34 AM_INIT_AUTOMAKE
  35 AM_MAINTAINER_MODE
  36
  37 AC_CONFIG_MACRO_DIR([m4])
  38 AC_CONFIG_HEADERS([rrd_config.h])
  39
  40 dnl all our local stuff like install scripts and include files
  41 dnl is in there
  42
  43
  44 dnl determine the type of system we are running on
  45
  46 AC_SUBST(VERSION)
  47
  48 AC_PREFIX_DEFAULT( /usr/local/rrdtool-$PACKAGE_VERSION )
  49
  50 dnl Minimum Autoconf version required.
  51 AC_PREREQ(2.59)
  52
  53 dnl At the TOP of the HEADER
  54
  55 AH_TOP([
  56 #ifndef RRD_CONFIG_H
  57 #define RRD_CONFIG_H
  58
  59 /* IEEE can be prevented from raising signals with fpsetmask(0) */
  60 #undef MUST_DISABLE_FPMASK
  61
  62 /* IEEE math only works if SIGFPE gets actively set to IGNORE */
  63 #undef MUST_DISABLE_SIGFPE
  64
  65 /* realloc does not support NULL as argument */
  66 #undef NO_NULL_REALLOC
  67
  68 /* lets enable madvise defines in NetBSD */
  69 #if defined(__NetBSD__)
  70 # if !defined(_NETBSD_SOURCE)
  71 #  define _NETBSD_SOURCE
  72 # endif
  73 #endif
  74
  75 ])
  76
  77 AH_BOTTOM([
  78
  79 #ifdef MUST_HAVE_MALLOC_MALLOC_H
  80 #  include <malloc/malloc.h>
  81 #endif
  82
  83 #include <rrd_config_bottom.h>
  84
  85 #endif
  86 ])
  87
  88 dnl Process Special Options
  89 dnl -----------------------------------
  90
  91 dnl How the vertical axis label is printed
  92 AC_ARG_VAR(RRDGRAPH_YLEGEND_ANGLE,
  93  [Vertical label angle: -90.0 (default) or 90.0])
  94 AC_DEFINE_UNQUOTED(RRDGRAPH_YLEGEND_ANGLE,${RRDGRAPH_YLEGEND_ANGLE:-90.0},
  95  [Vertical label angle: -90.0 (default) or 90.0])
  96
  97 AC_ARG_ENABLE(rrdcgi,[  --disable-rrdcgi        disable building of rrdcgi],
  98 [],[enable_rrdcgi=yes])
  99
 100 dnl Check if we run on a system that has fonts
 101 AC_ARG_WITH(rrd-default-font,
 102 [  --with-rrd-default-font=[OPTIONS]  set the full path to your default font.],
 103 [RRD_DEFAULT_FONT=$withval],[
 104   if test -d ${WINDIR:-nodir}/cour.ttf ; then
 105         RRD_DEFAULT_FONT=`cd $WINDIR;pwd`/cour.ttf
 106   else
 107         RRD_DEFAULT_FONT='"DejaVu Sans Mono,Bitstream Vera Sans Mono,monospace,Courier"'
 108   fi
 109 ])
 110
 111 dnl Use mmap in rrd_update instead of seek+write
 112 AC_ARG_ENABLE([mmap],
 113 [  --disable-mmap          disable mmap in rrd_update, use seek+write instead],
 114 [],
 115 [enable_mmap=yes])
 116
 117 AC_ARG_ENABLE(pthread,[  --disable-pthread       disable multithread support],
 118 [],[enable_pthread=yes])
 119
 120 AC_ARG_ENABLE(static-programs,
 121      [  --enable-static-programs  Build static programs],
 122      [case "${enableval}" in
 123        yes) staticprogs=yes ;;
 124        no)  staticprogs=no ;;
 125        *) AC_MSG_ERROR(bad value ${enableval} for --enable-static-programs) ;;
 126      esac],[staticprogs=no])
 127 AM_CONDITIONAL(STATIC_PROGRAMS,[test "x$staticprogs" = "xyes"])
 128
 129
 130 CONFIGURE_PART(Audit Compilation Environment)
 131
 132
 133 dnl Check for the compiler and static/shared library creation.
 134 AC_PROG_CC
 135 AC_PROG_CPP
 136 AC_PROG_LIBTOOL
 137
 138 dnl Try to detect/use GNU features
 139 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 140
 141 dnl which flags does the compiler support?
 142 if test "x$GCC" = "xyes"; then
 143   for flag in -fno-strict-aliasing -Wall -std=c99 -pedantic -Wundef -Wshadow -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Winline -Wold-style-definition -W; do
 144     oCFLAGS="$CFLAGS"
 145     CFLAGS="$CFLAGS $flag"
 146     cachename=rd_cv_gcc_flag_`echo $flag|sed 's/[[^A-Za-z]]/_/g'`
 147     AC_CACHE_CHECK([if gcc likes the $flag flag], $cachename,
 148        [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[return 0 ]])],[eval $cachename=yes],[eval $cachename=no])])
 149     if eval test \$$cachename = no; then
 150          CFLAGS="$oCFLAGS"
 151     fi
 152   done
 153 fi
 154
 155
 156
 157 AC_SUBST(RRD_DEFAULT_FONT)
 158
 159 CONFIGURE_PART(Checking for Header Files)
 160
 161 dnl Checks for header files.
 162 AC_HEADER_STDC
 163 AC_HEADER_DIRENT
 164 AC_CHECK_HEADERS(libgen.h features.h sys/stat.h sys/types.h fcntl.h locale.h fp_class.h malloc.h unistd.h ieeefp.h math.h sys/times.h sys/param.h sys/resource.h signal.h float.h stdio.h stdlib.h errno.h string.h ctype.h)
 165
 166 dnl Checks for typedefs, structures, and compiler characteristics.
 167 AC_C_CONST
 168 AC_HEADER_TIME
 169 AC_STRUCT_TM
 170
 171 CONFIGURE_PART(Test Library Functions)
 172
 173 dnl Checks for libraries.
 174 AC_CHECK_FUNC(acos, , AC_CHECK_LIB(m, acos))
 175
 176
 177 dnl add pic flag in any case this makes sure all our code is relocatable
 178 eval `./libtool --config | grep pic_flag`
 179 CFLAGS="$CFLAGS $pic_flag"
 180
 181
 182 dnl Checks for library functions.
 183 AC_FUNC_STRFTIME
 184 AC_FUNC_VPRINTF
 185
 186 AC_C_BIGENDIAN
 187
 188 dnl for each function found we get a definition in config.h
 189 dnl of the form HAVE_FUNCTION
 190
 191 AC_CHECK_FUNCS(tzset fsync mbstowcs opendir readdir chdir chroot getuid setlocale strerror snprintf vsnprintf fpclass class fp_class isnan memmove strchr mktime getrusage gettimeofday)
 192
 193 AC_FUNC_STRERROR_R
 194
 195 CONFIGURE_PART(Map/Fadvis/Madvise checking)
 196
 197 dnl Could use these to know if we need to provide a prototype
 198 dnl AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 199
 200 dnl check for fdatasync. Solaris has fdatasync in the librt
 201
 202 AC_CHECK_FUNCS(fdatasync, [],  AC_CHECK_LIB(rt, fdatasync, [LIBS="${LIBS} -lrt"; AC_DEFINE(HAVE_FDATASYNC)],[]))
 203 dnl if there is no fdatasync we may get lucky with fsync
 204 AC_CHECK_FUNCS(fsync)
 205
 206
 207 dnl XXX: dunno about windows.. add AC_CHECK_FUNCS(munmap) there too?
 208 if test "x$enable_mmap" = "xyes"; then
 209   case "$host" in
 210   *cygwin*)
 211     # the normal mmap test does not work in cygwin
 212     AC_CHECK_FUNCS(mmap)
 213     if test "x$ac_cv_func_mmap" = "xyes"; then
 214       ac_cv_func_mmap_fixed_mapped=yes
 215     fi
 216   ;;
 217   *)
 218     AC_CHECK_HEADERS(sys/mman.h)
 219     AC_FUNC_MMAP
 220     AC_CHECK_FUNCS(mmap munmap msync)
 221     AC_CHECK_DECLS(madvise, [], [], [#ifdef HAVE_SYS_MMAN_H
 222                                      # include <sys/mman.h>
 223                                      #endif])
 224     if test "x$ac_cv_have_decl_madvise" = "xyes";
 225     then
 226       AC_CHECK_FUNCS(madvise)
 227     else
 228       AC_CHECK_FUNCS(posix_madvise)
 229       if test "x$ac_cv_func_posix_madvise" != "xyes"; then
 230         AC_MSG_WARN([madvise() nor posix_madvise() found.])
 231       fi
 232     fi
 233   ;;
 234   esac
 235   if test "x$ac_cv_func_mmap" != "xyes";
 236   then
 237     AC_MSG_ERROR([--enable-mmap requested but mmap() was not detected])
 238 dnl enable_mmap="no"
 239   fi
 240 fi
 241
 242 dnl can we use posix_fadvise
 243 AC_CHECK_DECLS(posix_fadvise, [], [], [#define _XOPEN_SOURCE 600
 244 #include <fcntl.h>])
 245 AC_CHECK_FUNCS(posix_fadvise)
 246
 247 CONFIGURE_PART(Libintl Processing)
 248
 249
 250 dnl gettext
 251 GETTEXT_PACKAGE=rrdtool
 252 AC_SUBST(GETTEXT_PACKAGE)
 253 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package])
 254
 255 AM_GLIB_GNU_GETTEXT()
 256
 257 AC_ARG_ENABLE(libintl,[  --disable-libintl        i18n support (libintl)],
 258 [],[enable_libintl=yes])
 259
 260 if test x$enable_libintl = xyes; then
 261   IT_PROG_INTLTOOL([0.35.0],[no-xml])
 262 fi
 263
 264 if test x$enable_libintl = xyes -a x$MSGFMT = xno; then
 265   AC_MSG_WARN(I could not find msgfmt. Diabeling libintl build.)
 266   enable_libintl=no
 267 fi
 268
 269 if test x$enable_libintl = xyes; then
 270   AC_CHECK_HEADERS(libintl.h,[],[AC_MSG_RESULT(disabeling libintl build); enable_libintl=no])
 271 fi
 272
 273 if test x$enable_libintl = xyes ; then
 274   dnl it seems bsd synstems need to link against libintl
 275   dnl when compiling rrdupdate. lets check
 276   AC_CHECK_LIB(intl, libintl_gettext,[LIB_LIBINTL="-lintl"])
 277 fi
 278
 279 dnl use for linking rrdupdate
 280 AC_SUBST(LIB_LIBINTL)
 281
 282 dnl do not touch the po stuff if we are not going to build intl
 283 AM_CONDITIONAL(BUILD_LIBINTL,[test x$enable_libintl = xyes])
 284
 285 if test x$enable_libintl = xyes; then
 286    AC_DEFINE([BUILD_LIBINTL], [], [Use this in code sections to mark them for libintl build])
 287 fi
 288
 289 CONFIGURE_PART(IEEE Math Checks)
 290
 291
 292 dnl actual code to check if this works
 293 AC_CHECK_FUNCS(fpclassify, ,
 294   [AC_MSG_CHECKING(for fpclassify with <math.h>)
 295     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 296 volatile int x;volatile float f; ]], [[x = fpclassify(f)]])],[AC_MSG_RESULT(yes)
 297       AC_DEFINE(HAVE_FPCLASSIFY)],[AC_MSG_RESULT(no)])])
 298
 299 AC_CHECK_FUNCS(isinf, ,
 300   [AC_MSG_CHECKING(for isinf with <math.h>)
 301     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 302 volatile int x;volatile float f;  ]], [[x = isinf(f)]])],[AC_MSG_RESULT(yes)
 303       AC_DEFINE(HAVE_ISINF)],[AC_MSG_RESULT(no)])])
 304
 305 dnl finite is BSD, isfinite is C99, so prefer the latter
 306 AC_CACHE_CHECK([whether isfinite is broken],[ac_cv_have_broken_isfinite],[
 307 AC_TRY_RUN([
 308 #ifdef HAVE_MATH_H
 309 #include <math.h>
 310 #endif
 311 #ifdef HAVE_FLOAT_H
 312 #include <float.h>
 313 #endif
 314 int main ()
 315 {
 316 #ifdef isfinite
 317 #ifdef LDBL_MAX
 318   if (!isfinite(LDBL_MAX)) return 1;
 319 #endif
 320 #ifdef DBL_MAX
 321   if (!isfinite(DBL_MAX)) return 1;
 322 #endif
 323 #endif
 324 return 0;
 325 }],[ac_cv_have_broken_isfinite=no],[ac_cv_have_broken_isfinite=yes],[
 326 case "${target}" in
 327   hppa*-*-hpux*) ac_cv_have_broken_isfinite=yes ;;
 328   *-solaris2.8) ac_cv_have_broken_isfinite=yes ;;
 329   *-solaris2.9) ac_cv_have_broken_isfinite=yes ;;
 330   *) ac_cv_have_broken_isfinite=no ;;
 331 esac])
 332 ])
 333
 334 dnl the test does not seem to work on solaris 2.8/9
 335 dnl so lets fix this by hand
 336 case "${target}" in
 337   *-solaris2.8) ac_cv_have_broken_isfinite=yes ;;
 338   *-solaris2.9) ac_cv_have_broken_isfinite=yes ;;
 339 esac
 340
 341 if test "x$ac_cv_have_broken_isfinite" = "xno"; then
 342   AC_DEFINE(HAVE_ISFINITE)
 343 else
 344   AC_CHECK_FUNCS(finite,[],
 345       [AC_CHECK_FUNCS(isfinite,[],
 346          [AC_MSG_CHECKING(for isfinite with <math.h>)
 347           AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 348 volatile int x;volatile float f;  ]],[[x = isfinite(f)]])],[AC_MSG_RESULT(yes)
 349                 AC_DEFINE(HAVE_ISFINITE)],[AC_MSG_RESULT(no)])])])
 350 fi
 351
 352 AC_FULL_IEEE
 353
 354 CONFIGURE_PART(Resolve Portability Issues)
 355
 356 CHECK_FOR_WORKING_MS_ASYNC
 357
 358 dnl Do we need getopt_long
 359
 360 dnl even when including our own getopt implementation
 361 dnl we may want to make sure we use the external
 362 dnl defined by libc to not run into linker resolve trouble
 363
 364 AC_CACHE_CHECK([for opterr], rd_cv_var_int_opterr,
 365 [AC_TRY_LINK([#include <unistd.h>],
 366   [extern int opterr; opterr = 1;],
 367   [rd_cv_var_int_opterr=yes],
 368   [rd_cv_var_int_opterr=no])])
 369 if test x"$rd_cv_var_int_opterr" = x"yes"; then
 370   AC_DEFINE(HAVE_INT_OPTERR, 1, [Define to 1 if you have the global variable 'int opterr'.])
 371 fi
 372
 373 build_getopt=no
 374 RRD_GETOPT_LONG="LIBC_HAS_GETOPT_LONG"
 375 AC_CHECK_FUNC(getopt_long,[],[
 376 RRD_GETOPT_LONG="getopt_long"
 377 build_getopt=yes
 378 ])
 379 AC_SUBST(RRD_GETOPT_LONG)
 380 AM_CONDITIONAL(BUILD_GETOPT,[test $build_getopt = yes])
 381
 382 dnl what does realloc do if it gets called with a NULL pointer
 383
 384 AC_CACHE_CHECK([if realloc can deal with NULL], rd_cv_null_realloc,
 385 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
 386               int main(void){
 387               char *x = NULL;
 388               x = realloc (x,10);
 389               if (x==NULL) return 1;
 390               return 0;
 391              }]])],[rd_cv_null_realloc=yes],[rd_cv_null_realloc=nope],[:])])
 392
 393 if test x"$rd_cv_null_realloc" = xnope; then
 394 AC_DEFINE(NO_NULL_REALLOC)
 395 fi
 396
 397 AC_LANG_PUSH(C)
 398 dnl solaris has some odd defines it needs in order to propperly compile ctime_r
 399 AC_MSG_CHECKING([if ctime_r need special care to act posixly correct])
 400 AC_LINK_IFELSE(
 401     AC_LANG_PROGRAM(
 402            [[#include <time.h>]],
 403            [[ctime_r(NULL,NULL,0)]]
 404                    ),
 405     [ CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
 406       AC_LINK_IFELSE(
 407           AC_LANG_PROGRAM(
 408                 [[#include <time.h>]],
 409                 [[ctime_r(NULL,NULL)]]
 410                          ),
 411           [AC_MSG_RESULT([yes, this seems to be solaris style])],
 412           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 413       )
 414     ],
 415     [ AC_LINK_IFELSE(
 416           AC_LANG_PROGRAM(
 417                 [[#include <time.h>]],
 418                 [[ctime_r(NULL,NULL)]]
 419                          ),
 420           [AC_MSG_RESULT(no)],
 421           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 422       )
 423     ]
 424 )
 425 AC_LANG_POP(C)
 426
 427 dnl Check for pthreads
 428 dnl http://autoconf-archive.cryp.to/acx_pthread.m4
 429
 430 AC_SUBST(MULTITHREAD_CFLAGS)
 431 AC_SUBST(MULTITHREAD_LDFLAGS)
 432
 433 if test $enable_pthread != no; then
 434  ACX_PTHREAD([
 435     MULTITHREAD_CFLAGS=$PTHREAD_CFLAGS
 436     MULTITHREAD_LDFLAGS=$PTHREAD_LIBS
 437              ],
 438              [])
 439 fi
 440
 441 dnl since we use lots of *_r functions all over the code we better
 442 dnl make sure they are known
 443
 444 if test  "x$x_rflag" != "xno"; then
 445    CPPFLAGS="$CPPFLAGS $x_rflag"
 446 fi
 447
 448 AM_CONDITIONAL(BUILD_MULTITHREAD,[test $enable_pthread != no])
 449
 450 AC_LANG_PUSH(C)
 451 dnl see if we have to include malloc/malloc.h
 452 AC_MSG_CHECKING([do we need malloc/malloc.h])
 453 AC_LINK_IFELSE(
 454     AC_LANG_PROGRAM(
 455            [[#include <stdlib.h>]],
 456            [[malloc(1)]]
 457                    ),
 458     [ AC_MSG_RESULT([nope, works out of the box]) ],
 459     [ AC_LINK_IFELSE(
 460           AC_LANG_PROGRAM(
 461                 [[#include <stdlib.h>
 462                   #include <malloc/malloc.h>]],
 463                 [[malloc(1)]]
 464                          ),[
 465            AC_DEFINE([MUST_HAVE_MALLOC_MALLOC_H])
 466            AC_MSG_RESULT([yes we do])],
 467           [AC_MSG_ERROR([Can not figure how to compile malloc])]
 468       )
 469     ]
 470 )
 471 AC_LANG_POP(C)
 472
 473 CONFIGURE_PART(Find 3rd-Party Libraries)
 474
 475
 476 AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
 477
 478
 479 CORE_LIBS="$LIBS"
 480
 481 dnl EX_CHECK_ALL(z,          zlibVersion,               zlib.h,                 zlib,        1.2.3,  http://www.gzip.org/zlib/, "")
 482 dnl EX_CHECK_ALL(png,        png_access_version_number, png.h,                  libpng,      1.2.10,  http://prdownloads.sourceforge.net/libpng/, "")
 483 dnl EX_CHECK_ALL(freetype,   FT_Init_FreeType,          ft2build.h,             freetype2,   2.1.10,  http://prdownloads.sourceforge.net/freetype/, /usr/include/freetype2)
 484 dnl EX_CHECK_ALL(fontconfig, FcInit,                    fontconfig.h,           fontconfig,  2.3.1,  http://fontconfig.org/release/, /usr/include)
 485 EX_CHECK_ALL(cairo,      cairo_font_options_create,     cairo.h,                cairo-png,   1.4.6,  http://cairographics.org/releases/, "")
 486 EX_CHECK_ALL(cairo,      cairo_svg_surface_create,      cairo-svg.h,            cairo-svg,   1.4.6,  http://cairographics.org/releases/, "")
 487 EX_CHECK_ALL(cairo,      cairo_pdf_surface_create,      cairo-pdf.h,            cairo-pdf,   1.4.6,  http://cairographics.org/releases/, "")
 488 EX_CHECK_ALL(cairo,      cairo_ps_surface_create,       cairo-ps.h,             cairo-ps,    1.4.6,  http://cairographics.org/releases/, "")
 489 dnl EX_CHECK_ALL(glib-2.0,   glib_check_version,        glib.h,                 glib-2.0,    2.12.12, ftp://ftp.gtk.org/pub/glib/2.12/, "")
 490 EX_CHECK_ALL(pango-1.0,  pango_cairo_context_set_font_options,  pango/pango.h,  pangocairo,  1.17,    http://ftp.gnome.org/pub/GNOME/sources/pango/1.17, "")
 491 EX_CHECK_ALL(xml2,       xmlParseFile,                  libxml/parser.h,        libxml-2.0,        2.6.31,  http://xmlsoft.org/downloads.html, /usr/include/libxml2)
 492
 493 if test "$EX_CHECK_ALL_ERR" = "YES"; then
 494   AC_MSG_ERROR([Please fix the library issues listed above and try again.])
 495 fi
 496
 497 ALL_LIBS="$LIBS"
 498 LIBS=
 499
 500 AC_SUBST(CORE_LIBS)
 501 AC_SUBST(ALL_LIBS)
 502
 503 CONFIGURE_PART(Prep for Building Language Bindings)
 504
 505 dnl Check for Perl and friends
 506 PATH=$PATH:/usr/perl5/bin
 507 export PATH
 508 AC_PATH_PROG(PERL, perl, no)
 509 AC_PATH_PROG(POD2MAN, pod2man, no)
 510 AC_PATH_PROG(POD2HTML, pod2html, no)
 511
 512
 513 AC_ARG_ENABLE(perl,[  --disable-perl          do not build the perl modules],
 514 [],[enable_perl=yes])
 515
 516
 517 AC_ARG_VAR(PERLCC, [[] C compiler for Perl modules])
 518 AC_ARG_VAR(PERLCCFLAGS, [[] CC flags for Perl modules])
 519 AC_ARG_VAR(PERLLD, [[same as PERLCC] Linker for Perl modules])
 520 AC_ARG_VAR(PERLLDFLAGS, [[] LD flags for Perl modules])
 521
 522 if test "x$PERL" = "xno" -o  x$enable_perl = xno; then
 523         COMP_PERL=
 524 else
 525         COMP_PERL="perl_piped perl_shared"
 526         AC_MSG_CHECKING(for the perl version you are running)
 527         PERL_VERSION=`$PERL -MConfig -e 'print $Config{version}'`
 528         AC_MSG_RESULT($PERL_VERSION)
 529         if test -z "$PERLCC"; then
 530             AC_MSG_CHECKING(for the C compiler perl wants to use to build its modules)
 531             perlcc=`$PERL -MConfig -e 'print $Config{cc}'`
 532             AC_MSG_RESULT($perlcc)
 533             if test ! -x "$perlcc"; then
 534                 AC_PATH_PROG(PERL_CC, ${perlcc}, no)
 535                 if test "$PERL_CC" = "no"; then
 536                     AC_MSG_WARN([
 537 I would not find the Compiler ($perlcc) that was originally used to compile
 538 your perl binary. You should either make sure that this compiler is
 539 available on your system, pick an other compiler and set PERLCC
 540 appropriately, or use a different perl setup that was compiled locally.
 541
 542 I will disable the compilation of the RRDs perl module for now.
 543 ])
 544                     COMP_PERL="perl_piped"
 545                 fi
 546             fi
 547         fi
 548 fi
 549
 550 AC_MSG_CHECKING(Perl Modules to build)
 551 AC_MSG_RESULT(${COMP_PERL:-No Perl Modules will be built})
 552
 553 # Options to pass when configuring perl module
 554 ppref=$prefix
 555 test "$ppref" = 'NONE' && ppref=$ac_default_prefix
 556
 557 PERL_MAKE_OPTIONS="PREFIX="'$(DESTDIR)'"$ppref LIB="'$(DESTDIR)'"$ppref/lib/perl/$PERL_VERSION"
 558
 559 dnl pass additional perl options when generating Makefile from Makefile.PL
 560 AC_ARG_ENABLE(perl-site-install,
 561 [  --enable-perl-site-install   by default the rrdtool perl modules are installed
 562                           together with rrdtool in $prefix/lib/perl. You have to
 563                           put a 'use lib qw($prefix/lib/perl)' into your scripts
 564                           when you want to use them. When you set this option
 565                           the perl modules will get installed wherever
 566                           your perl setup thinks it is best.],
 567 [PERL_MAKE_OPTIONS=],[])
 568
 569 if test ! -z "$PERLCC"; then
 570    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CC=$PERLCC"
 571
 572    if test ! -z "$PERLCCFLAGS"; then
 573        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CCFLAGS=$PERLCCFLAGS"
 574    fi
 575
 576    if test -z "$PERLLD"; then
 577        PERLLD=$PERLCC
 578    fi
 579    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LD=$PERLLD"
 580
 581    if test ! -z "$PERLLDFLAGS"; then
 582        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LDFLAGS=$PERLLDFLAGS"
 583    fi
 584 fi
 585
 586 AC_ARG_WITH(perl-options,
 587 [  --with-perl-options=[OPTIONS]  options to pass on command-line when
 588                           generating Makefile from Makefile.PL. If you set this
 589                           option, interesting things may happen unless you know
 590                           what you are doing!],
 591 [PERL_MAKE_OPTIONS=$withval])
 592
 593 AC_SUBST(PERL_MAKE_OPTIONS)
 594 AC_SUBST(PERL)
 595 AC_SUBST(COMP_PERL)
 596 AC_SUBST(PERL_VERSION)
 597
 598 dnl Check for Ruby.
 599 AC_PATH_PROG(RUBY, ruby, no)
 600
 601 AC_ARG_ENABLE(ruby,[  --disable-ruby          do not build the ruby modules],
 602 [],[enable_ruby=yes])
 603
 604 AC_MSG_CHECKING(if ruby modules can be built)
 605
 606 if test "x$RUBY" = "xno" -o  x$enable_ruby = xno; then
 607         COMP_RUBY=
 608         AC_MSG_RESULT(No .. Ruby not found or disabled)
 609 else
 610         if $RUBY -e 'require "mkmf"' >/dev/null 2>&1; then
 611                 COMP_RUBY="ruby"
 612                 AC_MSG_RESULT(YES)
 613         else
 614                 COMP_RUBY=
 615                 AC_MSG_RESULT(Ruby found but mkmf is missing! Install the -dev package)
 616         fi
 617 fi
 618
 619 rpref=$prefix
 620 test "$rpref" = 'NONE' && rpref=$ac_default_prefix
 621
 622 dnl pass additional ruby options when generating Makefile from Makefile.PL
 623 AC_ARG_ENABLE(ruby-site-install,
 624 [  --enable-ruby-site-install   by default the rrdtool ruby modules are installed
 625                           together with rrdtool in $prefix/lib/ruby. You have to
 626                           add $prefix/lib/ruby/$ruby_version/$sitearch to you $: variable
 627                           for ruby to find the RRD.so file.],
 628 [RUBY_MAKE_OPTIONS=],[RUBY_MAKE_OPTIONS="sitedir="'$(DESTDIR)'"$rpref/lib/ruby"])
 629
 630
 631 AC_ARG_WITH(ruby-options,
 632 [  --with-ruby-options=[OPTIONS]  options to pass on command-line when
 633                           generating Makefile from extconf.rb. If you set this
 634                           option, interesting things may happen unless you know
 635                           what you are doing!],
 636 [RUBY_MAKE_OPTIONS=$withval])
 637
 638 AC_SUBST(RUBY_MAKE_OPTIONS)
 639 AC_SUBST(RUBY)
 640 AC_SUBST(COMP_RUBY)
 641
 642
 643 enable_tcl_site=no
 644
 645 AC_ARG_ENABLE(tcl,[  --disable-tcl           do not build the tcl modules],
 646 [],[enable_tcl=yes])
 647
 648 if test  "$enable_tcl" = "yes"; then
 649   dnl Check for Tcl.
 650   withval=""
 651   AC_ARG_WITH(tcllib,[  --with-tcllib=DIR       location of the tclConfig.sh])
 652   enable_tcl=no
 653   for dir in $withval /usr/lib /usr/local/lib /usr/lib/tcl8.4 /usr/lib/tcl8.3 ; do
 654     AC_MSG_CHECKING(for tclConfig.sh in $dir)
 655     if test -f "$dir/tclConfig.sh" ; then
 656         tcl_config=$dir/tclConfig.sh
 657         enable_tcl=yes
 658         AC_MSG_RESULT(yes)
 659         break
 660     else
 661         AC_MSG_RESULT(no)
 662     fi
 663   done
 664
 665   if test "$enable_tcl" = "no"; then
 666         AC_MSG_WARN([tclConfig.sh not found - Tcl interface will not be built])
 667   else
 668         . $tcl_config
 669         TCL_PACKAGE_DIR="$TCL_PACKAGE_PATH/tclrrd$VERSION"
 670         if test -n "$TCL_INC_DIR"; then
 671           TCL_INCLUDE_SPEC="$TCL_INCLUDE_SPEC -I$TCL_INC_DIR"
 672         fi
 673   fi
 674   AC_ARG_ENABLE(tcl,[  --enable-tcl-site        install the tcl extension in the tcl tree],
 675   [],[enable_tcl_site=yes])
 676
 677 fi
 678
 679 AM_CONDITIONAL(BUILD_TCL, test "$enable_tcl" = "yes" )
 680 AM_CONDITIONAL(BUILD_TCL_SITE, test "$enable_tcl_site" = "yes" )
 681
 682
 683 AC_SUBST(TCL_PREFIX)
 684 AC_SUBST(TCL_SHLIB_CFLAGS)
 685 AC_SUBST(TCL_SHLIB_LD)
 686 AC_SUBST(TCL_SHLIB_SUFFIX)
 687 AC_SUBST(TCL_PACKAGE_PATH)
 688 AC_SUBST(TCL_LD_SEARCH_FLAGS)
 689 AC_SUBST(TCL_STUB_LIB_SPEC)
 690 AC_SUBST(TCL_VERSION)
 691 AC_SUBST(TCL_PACKAGE_DIR)
 692 AC_SUBST(TCL_INCLUDE_SPEC)
 693
 694 AC_ARG_ENABLE(python,[  --disable-python        do not build the python modules],
 695 [],[enable_python=yes])
 696
 697 if test  "$enable_python" = "yes"; then
 698 dnl Check for python
 699 AM_PATH_PYTHON(2.3,[],[enable_python=no])
 700 AM_CHECK_PYTHON_HEADERS(,[enable_python=no;AC_MSG_WARN(could not find Python headers)])
 701 fi
 702
 703 if test  x$enable_python = xno; then
 704         COMP_PYTHON=
 705 else
 706         COMP_PYTHON="python"
 707 fi
 708
 709 AC_SUBST(COMP_PYTHON)
 710
 711 dnl Check for nroff
 712 AC_PATH_PROGS(NROFF, gnroff nroff)
 713 AC_PATH_PROGS(TROFF, groff troff)
 714
 715 AC_ARG_VAR(RRDDOCDIR, [[DATADIR/doc/PACKAGE-VERSION] Documentation directory])
 716 if test -z "$RRDDOCDIR"; then
 717    RRDDOCDIR='${datadir}/doc/${PACKAGE}-${VERSION}'; fi
 718
 719
 720 CONFIGURE_PART(Apply Configuration Information)
 721
 722 AC_CONFIG_FILES([examples/shared-demo.pl])
 723 AC_CONFIG_FILES([examples/piped-demo.pl])
 724 AC_CONFIG_FILES([examples/stripes.pl])
 725 AC_CONFIG_FILES([examples/bigtops.pl])
 726 AC_CONFIG_FILES([examples/minmax.pl])
 727 AC_CONFIG_FILES([examples/4charts.pl])
 728 AC_CONFIG_FILES([examples/perftest.pl])
 729 AC_CONFIG_FILES([examples/Makefile])
 730 AC_CONFIG_FILES([doc/Makefile])
 731 AC_CONFIG_FILES([po/Makefile.in])
 732 AC_CONFIG_FILES([src/Makefile])
 733 AC_CONFIG_FILES([src/librrd.sym.in])
 734 AC_CONFIG_FILES([src/librrd.pc])
 735 AC_CONFIG_FILES([bindings/Makefile])
 736 AC_CONFIG_FILES([bindings/tcl/Makefile])
 737 AC_CONFIG_FILES([bindings/tcl/ifOctets.tcl])
 738 AC_CONFIG_FILES([Makefile])
 739
 740 AC_CONFIG_COMMANDS([default],[[ chmod +x examples/*.pl]],[[]])
 741 AC_OUTPUT
 742
 743 AC_MSG_CHECKING(in)
 744 AC_MSG_RESULT(and out again)
 745
 746 echo $ECHO_N "ordering CD from http://tobi.oetiker.ch/wish $ECHO_C" 1>&6
 747 sleep 1
 748 echo $ECHO_N ".$ECHO_C" 1>&6
 749 sleep 1
 750 echo $ECHO_N ".$ECHO_C" 1>&6
 751 sleep 1
 752 echo $ECHO_N ".$ECHO_C" 1>&6
 753 sleep 1
 754 echo $ECHO_N ".$ECHO_C" 1>&6
 755 sleep 1
 756 AC_MSG_RESULT([ just kidding ;-)])
 757 echo
 758 echo "----------------------------------------------------------------"
 759 echo "Config is DONE!"
 760 echo
 761 echo "          With MMAP IO: $enable_mmap"
 762 echo "      Build rrd_getopt: $build_getopt"
 763 echo "       Static programs: $staticprogs"
 764 echo "          Perl Modules: $COMP_PERL"
 765 echo "           Perl Binary: $PERL"
 766 echo "          Perl Version: $PERL_VERSION"
 767 echo "          Perl Options: $PERL_MAKE_OPTIONS"
 768 echo "          Ruby Modules: $COMP_RUBY"
 769 echo "           Ruby Binary: $RUBY"
 770 echo "          Ruby Options: $RUBY_MAKE_OPTIONS"
 771 echo "    Build Tcl Bindings: $enable_tcl"
 772 echo " Build Python Bindings: $enable_python"
 773 echo "          Build rrdcgi: $enable_rrdcgi"
 774 echo "       Build librrd MT: $enable_pthread"
 775 echo "     Link with libintl: $enable_libintl"
 776 echo
 777 echo "             Libraries: $ALL_LIBS"
 778 echo
 779 echo "Type 'make' to compile the software and use 'make install' to "
 780 echo "install everything to: $prefix."
 781 echo
 782 echo "       ... that wishlist is NO JOKE. If you find RRDtool useful"
 783 echo "make me happy. Go to http://tobi.oetiker.ch/wish and"
 784 echo "place an order."
 785 echo
 786 echo "                               -- Tobi Oetiker <tobi@oetiker.ch>"
 787 echo "----------------------------------------------------------------"