1 dnl RRDtool AutoConf script ...
2 dnl ---------------------------
3 dnl
4 dnl Created by Jeff Allen, Tobi Oetiker, Blair Zajac
5 dnl
6 dnl Inspiration from http://autoconf-archive.cryp.to
8 dnl tell automake the this script is for rrdtool
10 dnl the official version number is
11 dnl a.b.c
12 AC_INIT([rrdtool],[1.3.6])
14 dnl for testing a numberical version number comes handy
15 dnl the released version are
16 dnl a.bccc
17 dnl the devel versions will be something like
18 dnl a.b999yymmddhh
19 NUMVERS=1.3006
20 AC_SUBST(NUMVERS)
22 dnl for the linker to understand which versions the library are compatible with
23 dnl each other we must keep a separate library version cout of the format c:r:a.
24 dnl - if only implementation changed but all interfaces are kept, do r++
25 dnl - if only functionality was added do c++,r=0,a++
26 dnl - if any functionality was removed do c++,r=0,a=0.
27 dnl
28 dnl see http://sourceware.org/autobook/autobook/autobook_91.html
29 dnl
30 LIBVERS=4:5:0
31 AC_SUBST(LIBVERS)
33 AC_CANONICAL_TARGET
34 AM_INIT_AUTOMAKE
35 AM_MAINTAINER_MODE
37 AC_CONFIG_MACRO_DIR([m4])
38 AC_CONFIG_HEADERS([rrd_config.h])
40 dnl all our local stuff like install scripts and include files
41 dnl is in there
44 dnl determine the type of system we are running on
46 AC_SUBST(VERSION)
48 AC_PREFIX_DEFAULT( /usr/local/rrdtool-$PACKAGE_VERSION )
50 dnl Minimum Autoconf version required.
51 AC_PREREQ(2.59)
53 dnl At the TOP of the HEADER
55 AH_TOP([
56 #ifndef RRD_CONFIG_H
57 #define RRD_CONFIG_H
59 /* IEEE can be prevented from raising signals with fpsetmask(0) */
60 #undef MUST_DISABLE_FPMASK
62 /* IEEE math only works if SIGFPE gets actively set to IGNORE */
63 #undef MUST_DISABLE_SIGFPE
65 /* realloc does not support NULL as argument */
66 #undef NO_NULL_REALLOC
68 /* lets enable madvise defines in NetBSD */
69 #if defined(__NetBSD__)
70 # if !defined(_NETBSD_SOURCE)
71 # define _NETBSD_SOURCE
72 # endif
73 #endif
75 ])
77 AH_BOTTOM([
79 #ifdef MUST_HAVE_MALLOC_MALLOC_H
80 # include <malloc/malloc.h>
81 #endif
83 #include <rrd_config_bottom.h>
85 #endif
86 ])
88 dnl Process Special Options
89 dnl -----------------------------------
91 dnl How the vertical axis label is printed
92 AC_ARG_VAR(RRDGRAPH_YLEGEND_ANGLE,
93 [Vertical label angle: -90.0 (default) or 90.0])
94 AC_DEFINE_UNQUOTED(RRDGRAPH_YLEGEND_ANGLE,${RRDGRAPH_YLEGEND_ANGLE:-90.0},
95 [Vertical label angle: -90.0 (default) or 90.0])
97 AC_ARG_ENABLE(rrdcgi,[ --disable-rrdcgi disable building of rrdcgi],
98 [],[enable_rrdcgi=yes])
100 dnl Check if we run on a system that has fonts
101 AC_ARG_WITH(rrd-default-font,
102 [ --with-rrd-default-font=[OPTIONS] set the full path to your default font.],
103 [RRD_DEFAULT_FONT=$withval],[
104 if test -d ${WINDIR:-nodir}/cour.ttf ; then
105 RRD_DEFAULT_FONT=`cd $WINDIR;pwd`/cour.ttf
106 else
107 RRD_DEFAULT_FONT='"DejaVu Sans Mono,Bitstream Vera Sans Mono,monospace,Courier"'
108 fi
109 ])
111 dnl Use mmap in rrd_update instead of seek+write
112 AC_ARG_ENABLE([mmap],
113 [ --disable-mmap disable mmap in rrd_update, use seek+write instead],
114 [],
115 [enable_mmap=yes])
117 AC_ARG_ENABLE(pthread,[ --disable-pthread disable multithread support],
118 [],[enable_pthread=yes])
120 AC_ARG_ENABLE(static-programs,
121 [ --enable-static-programs Build static programs],
122 [case "${enableval}" in
123 yes) staticprogs=yes ;;
124 no) staticprogs=no ;;
125 *) AC_MSG_ERROR(bad value ${enableval} for --enable-static-programs) ;;
126 esac],[staticprogs=no])
127 AM_CONDITIONAL(STATIC_PROGRAMS,[test "x$staticprogs" = "xyes"])
130 CONFIGURE_PART(Audit Compilation Environment)
133 dnl Check for the compiler and static/shared library creation.
134 AC_PROG_CC
135 AC_PROG_CPP
136 AC_PROG_LIBTOOL
138 dnl Try to detect/use GNU features
139 CFLAGS="$CFLAGS -D_GNU_SOURCE"
141 dnl which flags does the compiler support?
142 if test "x$GCC" = "xyes"; then
143 for flag in -fno-strict-aliasing -Wall -std=c99 -pedantic -Wundef -Wshadow -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Winline -Wold-style-definition -W; do
144 oCFLAGS="$CFLAGS"
145 CFLAGS="$CFLAGS $flag"
146 cachename=rd_cv_gcc_flag_`echo $flag|sed 's/[[^A-Za-z]]/_/g'`
147 AC_CACHE_CHECK([if gcc likes the $flag flag], $cachename,
148 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[return 0 ]])],[eval $cachename=yes],[eval $cachename=no])])
149 if eval test \$$cachename = no; then
150 CFLAGS="$oCFLAGS"
151 fi
152 done
153 fi
157 AC_SUBST(RRD_DEFAULT_FONT)
159 CONFIGURE_PART(Checking for Header Files)
161 dnl Checks for header files.
162 AC_HEADER_STDC
163 AC_HEADER_DIRENT
164 AC_CHECK_HEADERS(libgen.h features.h sys/stat.h sys/types.h fcntl.h locale.h fp_class.h malloc.h unistd.h ieeefp.h math.h sys/times.h sys/param.h sys/resource.h signal.h float.h stdio.h stdlib.h errno.h string.h ctype.h)
166 dnl Checks for typedefs, structures, and compiler characteristics.
167 AC_C_CONST
168 AC_HEADER_TIME
169 AC_STRUCT_TM
171 CONFIGURE_PART(Test Library Functions)
173 dnl Checks for libraries.
174 AC_CHECK_FUNC(acos, , AC_CHECK_LIB(m, acos))
177 dnl add pic flag in any case this makes sure all our code is relocatable
178 eval `./libtool --config | grep pic_flag`
179 CFLAGS="$CFLAGS $pic_flag"
182 dnl Checks for library functions.
183 AC_FUNC_STRFTIME
184 AC_FUNC_VPRINTF
186 AC_C_BIGENDIAN
188 dnl for each function found we get a definition in config.h
189 dnl of the form HAVE_FUNCTION
191 AC_CHECK_FUNCS(tzset fsync mbstowcs opendir readdir chdir chroot getuid setlocale strerror snprintf vsnprintf fpclass class fp_class isnan memmove strchr mktime getrusage gettimeofday)
193 AC_FUNC_STRERROR_R
195 CONFIGURE_PART(Map/Fadvis/Madvise checking)
197 dnl Could use these to know if we need to provide a prototype
198 dnl AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
200 dnl check for fdatasync. Solaris has fdatasync in the librt
202 AC_CHECK_FUNCS(fdatasync, [], AC_CHECK_LIB(rt, fdatasync, [LIBS="${LIBS} -lrt"; AC_DEFINE(HAVE_FDATASYNC)],[]))
203 dnl if there is no fdatasync we may get lucky with fsync
204 AC_CHECK_FUNCS(fsync)
207 dnl XXX: dunno about windows.. add AC_CHECK_FUNCS(munmap) there too?
208 if test "x$enable_mmap" = "xyes"; then
209 case "$host" in
210 *cygwin*)
211 # the normal mmap test does not work in cygwin
212 AC_CHECK_FUNCS(mmap)
213 if test "x$ac_cv_func_mmap" = "xyes"; then
214 ac_cv_func_mmap_fixed_mapped=yes
215 fi
216 ;;
217 *)
218 AC_CHECK_HEADERS(sys/mman.h)
219 AC_FUNC_MMAP
220 AC_CHECK_FUNCS(mmap munmap msync)
221 AC_CHECK_DECLS(madvise, [], [], [#ifdef HAVE_SYS_MMAN_H
222 # include <sys/mman.h>
223 #endif])
224 if test "x$ac_cv_have_decl_madvise" = "xyes";
225 then
226 AC_CHECK_FUNCS(madvise)
227 else
228 AC_CHECK_FUNCS(posix_madvise)
229 if test "x$ac_cv_func_posix_madvise" != "xyes"; then
230 AC_MSG_WARN([madvise() nor posix_madvise() found.])
231 fi
232 fi
233 ;;
234 esac
235 if test "x$ac_cv_func_mmap" != "xyes";
236 then
237 AC_MSG_ERROR([--enable-mmap requested but mmap() was not detected])
238 dnl enable_mmap="no"
239 fi
240 fi
242 dnl can we use posix_fadvise
243 AC_CHECK_DECLS(posix_fadvise, [], [], [#define _XOPEN_SOURCE 600
244 #include <fcntl.h>])
245 AC_CHECK_FUNCS(posix_fadvise)
247 CONFIGURE_PART(Libintl Processing)
250 dnl gettext
251 GETTEXT_PACKAGE=rrdtool
252 AC_SUBST(GETTEXT_PACKAGE)
253 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package])
255 AM_GLIB_GNU_GETTEXT()
257 AC_ARG_ENABLE(libintl,[ --disable-libintl i18n support (libintl)],
258 [],[enable_libintl=yes])
260 if test x$enable_libintl = xyes; then
261 IT_PROG_INTLTOOL([0.35.0],[no-xml])
262 fi
264 if test x$enable_libintl = xyes -a x$MSGFMT = xno; then
265 AC_MSG_WARN(I could not find msgfmt. Diabeling libintl build.)
266 enable_libintl=no
267 fi
269 if test x$enable_libintl = xyes; then
270 AC_CHECK_HEADERS(libintl.h,[],[AC_MSG_RESULT(disabeling libintl build); enable_libintl=no])
271 fi
273 if test x$enable_libintl = xyes ; then
274 dnl it seems bsd synstems need to link against libintl
275 dnl when compiling rrdupdate. lets check
276 AC_CHECK_LIB(intl, libintl_gettext,[LIB_LIBINTL="-lintl"])
277 fi
279 dnl use for linking rrdupdate
280 AC_SUBST(LIB_LIBINTL)
282 dnl do not touch the po stuff if we are not going to build intl
283 AM_CONDITIONAL(BUILD_LIBINTL,[test x$enable_libintl = xyes])
285 if test x$enable_libintl = xyes; then
286 AC_DEFINE([BUILD_LIBINTL], [], [Use this in code sections to mark them for libintl build])
287 fi
289 CONFIGURE_PART(IEEE Math Checks)
292 dnl actual code to check if this works
293 AC_CHECK_FUNCS(fpclassify, ,
294 [AC_MSG_CHECKING(for fpclassify with <math.h>)
295 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
296 volatile int x;volatile float f; ]], [[x = fpclassify(f)]])],[AC_MSG_RESULT(yes)
297 AC_DEFINE(HAVE_FPCLASSIFY)],[AC_MSG_RESULT(no)])])
299 AC_CHECK_FUNCS(isinf, ,
300 [AC_MSG_CHECKING(for isinf with <math.h>)
301 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
302 volatile int x;volatile float f; ]], [[x = isinf(f)]])],[AC_MSG_RESULT(yes)
303 AC_DEFINE(HAVE_ISINF)],[AC_MSG_RESULT(no)])])
305 dnl finite is BSD, isfinite is C99, so prefer the latter
306 AC_CACHE_CHECK([whether isfinite is broken],[ac_cv_have_broken_isfinite],[
307 AC_TRY_RUN([
308 #ifdef HAVE_MATH_H
309 #include <math.h>
310 #endif
311 #ifdef HAVE_FLOAT_H
312 #include <float.h>
313 #endif
314 int main ()
315 {
316 #ifdef isfinite
317 #ifdef LDBL_MAX
318 if (!isfinite(LDBL_MAX)) return 1;
319 #endif
320 #ifdef DBL_MAX
321 if (!isfinite(DBL_MAX)) return 1;
322 #endif
323 #endif
324 return 0;
325 }],[ac_cv_have_broken_isfinite=no],[ac_cv_have_broken_isfinite=yes],[
326 case "${target}" in
327 hppa*-*-hpux*) ac_cv_have_broken_isfinite=yes ;;
328 *-solaris2.8) ac_cv_have_broken_isfinite=yes ;;
329 *-solaris2.9) ac_cv_have_broken_isfinite=yes ;;
330 *) ac_cv_have_broken_isfinite=no ;;
331 esac])
332 ])
334 dnl the test does not seem to work on solaris 2.8/9
335 dnl so lets fix this by hand
336 case "${target}" in
337 *-solaris2.8) ac_cv_have_broken_isfinite=yes ;;
338 *-solaris2.9) ac_cv_have_broken_isfinite=yes ;;
339 esac
341 if test "x$ac_cv_have_broken_isfinite" = "xno"; then
342 AC_DEFINE(HAVE_ISFINITE)
343 else
344 AC_CHECK_FUNCS(finite,[],
345 [AC_CHECK_FUNCS(isfinite,[],
346 [AC_MSG_CHECKING(for isfinite with <math.h>)
347 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
348 volatile int x;volatile float f; ]],[[x = isfinite(f)]])],[AC_MSG_RESULT(yes)
349 AC_DEFINE(HAVE_ISFINITE)],[AC_MSG_RESULT(no)])])])
350 fi
352 AC_FULL_IEEE
354 CONFIGURE_PART(Resolve Portability Issues)
356 CHECK_FOR_WORKING_MS_ASYNC
358 dnl Do we need getopt_long
360 build_getopt=no
361 RRD_GETOPT_LONG="LIBC_HAS_GETOPT_LONG"
362 AC_CHECK_FUNC(getopt_long,[],[
363 RRD_GETOPT_LONG="getopt_long"
364 build_getopt=yes
365 ])
366 AC_SUBST(RRD_GETOPT_LONG)
367 AM_CONDITIONAL(BUILD_GETOPT,[test $build_getopt = yes])
369 dnl what does realloc do if it gets called with a NULL pointer
371 AC_CACHE_CHECK([if realloc can deal with NULL], rd_cv_null_realloc,
372 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
373 int main(void){
374 char *x = NULL;
375 x = realloc (x,10);
376 if (x==NULL) return 1;
377 return 0;
378 }]])],[rd_cv_null_realloc=yes],[rd_cv_null_realloc=nope],[:])])
380 if test x"$rd_cv_null_realloc" = xnope; then
381 AC_DEFINE(NO_NULL_REALLOC)
382 fi
384 AC_LANG_PUSH(C)
385 dnl solaris has some odd defines it needs in order to propperly compile ctime_r
386 AC_MSG_CHECKING([if ctime_r need special care to act posixly correct])
387 AC_LINK_IFELSE(
388 AC_LANG_PROGRAM(
389 [[#include <time.h>]],
390 [[ctime_r(NULL,NULL,0)]]
391 ),
392 [ CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
393 AC_LINK_IFELSE(
394 AC_LANG_PROGRAM(
395 [[#include <time.h>]],
396 [[ctime_r(NULL,NULL)]]
397 ),
398 [AC_MSG_RESULT([yes, this seems to be solaris style])],
399 [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
400 )
401 ],
402 [ AC_LINK_IFELSE(
403 AC_LANG_PROGRAM(
404 [[#include <time.h>]],
405 [[ctime_r(NULL,NULL)]]
406 ),
407 [AC_MSG_RESULT(no)],
408 [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
409 )
410 ]
411 )
412 AC_LANG_POP(C)
414 dnl Check for pthreads
415 dnl http://autoconf-archive.cryp.to/acx_pthread.m4
417 AC_SUBST(MULTITHREAD_CFLAGS)
418 AC_SUBST(MULTITHREAD_LDFLAGS)
420 if test $enable_pthread != no; then
421 ACX_PTHREAD([
422 MULTITHREAD_CFLAGS=$PTHREAD_CFLAGS
423 MULTITHREAD_LDFLAGS=$PTHREAD_LIBS
424 ],
425 [])
426 fi
428 dnl since we use lots of *_r functions all over the code we better
429 dnl make sure they are known
431 if test "x$x_rflag" != "xno"; then
432 CPPFLAGS="$CPPFLAGS $x_rflag"
433 fi
435 AM_CONDITIONAL(BUILD_MULTITHREAD,[test $enable_pthread != no])
437 AC_LANG_PUSH(C)
438 dnl see if we have to include malloc/malloc.h
439 AC_MSG_CHECKING([do we need malloc/malloc.h])
440 AC_LINK_IFELSE(
441 AC_LANG_PROGRAM(
442 [[#include <stdlib.h>]],
443 [[malloc(1)]]
444 ),
445 [ AC_MSG_RESULT([nope, works out of the box]) ],
446 [ AC_LINK_IFELSE(
447 AC_LANG_PROGRAM(
448 [[#include <stdlib.h>
449 #include <malloc/malloc.h>]],
450 [[malloc(1)]]
451 ),[
452 AC_DEFINE([MUST_HAVE_MALLOC_MALLOC_H])
453 AC_MSG_RESULT([yes we do])],
454 [AC_MSG_ERROR([Can not figure how to compile malloc])]
455 )
456 ]
457 )
458 AC_LANG_POP(C)
460 CONFIGURE_PART(Find 3rd-Party Libraries)
463 AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
466 CORE_LIBS="$LIBS"
468 dnl EX_CHECK_ALL(z, zlibVersion, zlib.h, zlib, 1.2.3, http://www.gzip.org/zlib/, "")
469 dnl EX_CHECK_ALL(png, png_access_version_number, png.h, libpng, 1.2.10, http://prdownloads.sourceforge.net/libpng/, "")
470 dnl EX_CHECK_ALL(freetype, FT_Init_FreeType, ft2build.h, freetype2, 2.1.10, http://prdownloads.sourceforge.net/freetype/, /usr/include/freetype2)
471 dnl EX_CHECK_ALL(fontconfig, FcInit, fontconfig.h, fontconfig, 2.3.1, http://fontconfig.org/release/, /usr/include)
472 EX_CHECK_ALL(cairo, cairo_font_options_create, cairo.h, cairo-png, 1.4.6, http://cairographics.org/releases/, "")
473 EX_CHECK_ALL(cairo, cairo_svg_surface_create, cairo-svg.h, cairo-svg, 1.4.6, http://cairographics.org/releases/, "")
474 EX_CHECK_ALL(cairo, cairo_pdf_surface_create, cairo-pdf.h, cairo-pdf, 1.4.6, http://cairographics.org/releases/, "")
475 EX_CHECK_ALL(cairo, cairo_ps_surface_create, cairo-ps.h, cairo-ps, 1.4.6, http://cairographics.org/releases/, "")
476 dnl EX_CHECK_ALL(glib-2.0, glib_check_version, glib.h, glib-2.0, 2.12.12, ftp://ftp.gtk.org/pub/glib/2.12/, "")
477 EX_CHECK_ALL(pango-1.0, pango_cairo_context_set_font_options, pango/pango.h, pangocairo, 1.17, http://ftp.gnome.org/pub/GNOME/sources/pango/1.17, "")
478 EX_CHECK_ALL(xml2, xmlParseFile, libxml/parser.h, libxml-2.0, 2.6.31, http://xmlsoft.org/downloads.html, /usr/include/libxml2)
480 if test "$EX_CHECK_ALL_ERR" = "YES"; then
481 AC_MSG_ERROR([Please fix the library issues listed above and try again.])
482 fi
484 ALL_LIBS="$LIBS"
485 LIBS=
487 AC_SUBST(CORE_LIBS)
488 AC_SUBST(ALL_LIBS)
490 CONFIGURE_PART(Prep for Building Language Bindings)
492 dnl Check for Perl and friends
493 PATH=$PATH:/usr/perl5/bin
494 export PATH
495 AC_PATH_PROG(PERL, perl, no)
496 AC_PATH_PROG(POD2MAN, pod2man, no)
497 AC_PATH_PROG(POD2HTML, pod2html, no)
500 AC_ARG_ENABLE(perl,[ --disable-perl do not build the perl modules],
501 [],[enable_perl=yes])
504 AC_ARG_VAR(PERLCC, [[] C compiler for Perl modules])
505 AC_ARG_VAR(PERLCCFLAGS, [[] CC flags for Perl modules])
506 AC_ARG_VAR(PERLLD, [[same as PERLCC] Linker for Perl modules])
507 AC_ARG_VAR(PERLLDFLAGS, [[] LD flags for Perl modules])
509 if test "x$PERL" = "xno" -o x$enable_perl = xno; then
510 COMP_PERL=
511 else
512 COMP_PERL="perl_piped perl_shared"
513 AC_MSG_CHECKING(for the perl version you are running)
514 PERL_VERSION=`$PERL -MConfig -e 'print $Config{version}'`
515 AC_MSG_RESULT($PERL_VERSION)
516 if test -z "$PERLCC"; then
517 AC_MSG_CHECKING(for the C compiler perl wants to use to build its modules)
518 perlcc=`$PERL -MConfig -e 'print $Config{cc}'`
519 AC_MSG_RESULT($perlcc)
520 if test ! -x "$perlcc"; then
521 AC_PATH_PROG(PERL_CC, ${perlcc}, no)
522 if test "$PERL_CC" = "no"; then
523 AC_MSG_WARN([
524 I would not find the Compiler ($perlcc) that was originally used to compile
525 your perl binary. You should either make sure that this compiler is
526 available on your system, pick an other compiler and set PERLCC
527 appropriately, or use a different perl setup that was compiled locally.
529 I will disable the compilation of the RRDs perl module for now.
530 ])
531 COMP_PERL="perl_piped"
532 fi
533 fi
534 fi
535 fi
537 AC_MSG_CHECKING(Perl Modules to build)
538 AC_MSG_RESULT(${COMP_PERL:-No Perl Modules will be built})
540 # Options to pass when configuring perl module
541 ppref=$prefix
542 test "$ppref" = 'NONE' && ppref=$ac_default_prefix
544 PERL_MAKE_OPTIONS="PREFIX="'$(DESTDIR)'"$ppref LIB="'$(DESTDIR)'"$ppref/lib/perl/$PERL_VERSION"
546 dnl pass additional perl options when generating Makefile from Makefile.PL
547 AC_ARG_ENABLE(perl-site-install,
548 [ --enable-perl-site-install by default the rrdtool perl modules are installed
549 together with rrdtool in $prefix/lib/perl. You have to
550 put a 'use lib qw($prefix/lib/perl)' into your scripts
551 when you want to use them. When you set this option
552 the perl modules will get installed wherever
553 your perl setup thinks it is best.],
554 [PERL_MAKE_OPTIONS=],[])
556 if test ! -z "$PERLCC"; then
557 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CC=$PERLCC"
559 if test ! -z "$PERLCCFLAGS"; then
560 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CCFLAGS=$PERLCCFLAGS"
561 fi
563 if test -z "$PERLLD"; then
564 PERLLD=$PERLCC
565 fi
566 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LD=$PERLLD"
568 if test ! -z "$PERLLDFLAGS"; then
569 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LDFLAGS=$PERLLDFLAGS"
570 fi
571 fi
573 AC_ARG_WITH(perl-options,
574 [ --with-perl-options=[OPTIONS] options to pass on command-line when
575 generating Makefile from Makefile.PL. If you set this
576 option, interesting things may happen unless you know
577 what you are doing!],
578 [PERL_MAKE_OPTIONS=$withval])
580 AC_SUBST(PERL_MAKE_OPTIONS)
581 AC_SUBST(PERL)
582 AC_SUBST(COMP_PERL)
583 AC_SUBST(PERL_VERSION)
585 dnl Check for Ruby.
586 AC_PATH_PROG(RUBY, ruby, no)
588 AC_ARG_ENABLE(ruby,[ --disable-ruby do not build the ruby modules],
589 [],[enable_ruby=yes])
591 AC_MSG_CHECKING(if ruby modules can be built)
593 if test "x$RUBY" = "xno" -o x$enable_ruby = xno; then
594 COMP_RUBY=
595 AC_MSG_RESULT(No .. Ruby not found or disabled)
596 else
597 if $RUBY -e 'require "mkmf"' >/dev/null 2>&1; then
598 COMP_RUBY="ruby"
599 AC_MSG_RESULT(YES)
600 else
601 COMP_RUBY=
602 AC_MSG_RESULT(Ruby found but mkmf is missing! Install the -dev package)
603 fi
604 fi
606 rpref=$prefix
607 test "$rpref" = 'NONE' && rpref=$ac_default_prefix
609 dnl pass additional ruby options when generating Makefile from Makefile.PL
610 AC_ARG_ENABLE(ruby-site-install,
611 [ --enable-ruby-site-install by default the rrdtool ruby modules are installed
612 together with rrdtool in $prefix/lib/ruby. You have to
613 add $prefix/lib/ruby/$ruby_version/$sitearch to you $: variable
614 for ruby to find the RRD.so file.],
615 [RUBY_MAKE_OPTIONS=],[RUBY_MAKE_OPTIONS="sitedir="'$(DESTDIR)'"$rpref/lib/ruby"])
618 AC_ARG_WITH(ruby-options,
619 [ --with-ruby-options=[OPTIONS] options to pass on command-line when
620 generating Makefile from extconf.rb. If you set this
621 option, interesting things may happen unless you know
622 what you are doing!],
623 [RUBY_MAKE_OPTIONS=$withval])
625 AC_SUBST(RUBY_MAKE_OPTIONS)
626 AC_SUBST(RUBY)
627 AC_SUBST(COMP_RUBY)
630 enable_tcl_site=no
632 AC_ARG_ENABLE(tcl,[ --disable-tcl do not build the tcl modules],
633 [],[enable_tcl=yes])
635 if test "$enable_tcl" = "yes"; then
636 dnl Check for Tcl.
637 withval=""
638 AC_ARG_WITH(tcllib,[ --with-tcllib=DIR location of the tclConfig.sh])
639 enable_tcl=no
640 for dir in $withval /usr/lib /usr/local/lib /usr/lib/tcl8.4 /usr/lib/tcl8.3 ; do
641 AC_MSG_CHECKING(for tclConfig.sh in $dir)
642 if test -f "$dir/tclConfig.sh" ; then
643 tcl_config=$dir/tclConfig.sh
644 enable_tcl=yes
645 AC_MSG_RESULT(yes)
646 break
647 else
648 AC_MSG_RESULT(no)
649 fi
650 done
652 if test "$enable_tcl" = "no"; then
653 AC_MSG_WARN([tclConfig.sh not found - Tcl interface will not be built])
654 else
655 . $tcl_config
656 TCL_PACKAGE_DIR="$TCL_PACKAGE_PATH/tclrrd$VERSION"
657 if test -n "$TCL_INC_DIR"; then
658 TCL_INCLUDE_SPEC="$TCL_INCLUDE_SPEC -I$TCL_INC_DIR"
659 fi
660 fi
661 AC_ARG_ENABLE(tcl,[ --enable-tcl-site install the tcl extension in the tcl tree],
662 [],[enable_tcl_site=yes])
664 fi
666 AM_CONDITIONAL(BUILD_TCL, test "$enable_tcl" = "yes" )
667 AM_CONDITIONAL(BUILD_TCL_SITE, test "$enable_tcl_site" = "yes" )
670 AC_SUBST(TCL_PREFIX)
671 AC_SUBST(TCL_SHLIB_CFLAGS)
672 AC_SUBST(TCL_SHLIB_LD)
673 AC_SUBST(TCL_SHLIB_SUFFIX)
674 AC_SUBST(TCL_PACKAGE_PATH)
675 AC_SUBST(TCL_LD_SEARCH_FLAGS)
676 AC_SUBST(TCL_STUB_LIB_SPEC)
677 AC_SUBST(TCL_VERSION)
678 AC_SUBST(TCL_PACKAGE_DIR)
679 AC_SUBST(TCL_INCLUDE_SPEC)
681 AC_ARG_ENABLE(python,[ --disable-python do not build the python modules],
682 [],[enable_python=yes])
684 if test "$enable_python" = "yes"; then
685 dnl Check for python
686 AM_PATH_PYTHON(2.3,[],[enable_python=no])
687 AM_CHECK_PYTHON_HEADERS(,[enable_python=no;AC_MSG_WARN(could not find Python headers)])
688 fi
690 if test x$enable_python = xno; then
691 COMP_PYTHON=
692 else
693 COMP_PYTHON="python"
694 fi
696 AC_SUBST(COMP_PYTHON)
698 dnl Check for nroff
699 AC_PATH_PROGS(NROFF, gnroff nroff)
700 AC_PATH_PROGS(TROFF, groff troff)
702 AC_ARG_VAR(RRDDOCDIR, [[DATADIR/doc/PACKAGE-VERSION] Documentation directory])
703 if test -z "$RRDDOCDIR"; then
704 RRDDOCDIR='${datadir}/doc/${PACKAGE}-${VERSION}'; fi
707 CONFIGURE_PART(Apply Configuration Information)
709 AC_CONFIG_FILES([examples/shared-demo.pl])
710 AC_CONFIG_FILES([examples/piped-demo.pl])
711 AC_CONFIG_FILES([examples/stripes.pl])
712 AC_CONFIG_FILES([examples/bigtops.pl])
713 AC_CONFIG_FILES([examples/minmax.pl])
714 AC_CONFIG_FILES([examples/4charts.pl])
715 AC_CONFIG_FILES([examples/perftest.pl])
716 AC_CONFIG_FILES([examples/Makefile])
717 AC_CONFIG_FILES([doc/Makefile])
718 AC_CONFIG_FILES([po/Makefile.in])
719 AC_CONFIG_FILES([src/Makefile])
720 AC_CONFIG_FILES([src/librrd.sym.in])
721 AC_CONFIG_FILES([src/librrd.pc])
722 AC_CONFIG_FILES([bindings/Makefile])
723 AC_CONFIG_FILES([bindings/tcl/Makefile])
724 AC_CONFIG_FILES([bindings/tcl/ifOctets.tcl])
725 AC_CONFIG_FILES([Makefile])
727 AC_CONFIG_COMMANDS([default],[[ chmod +x examples/*.pl]],[[]])
728 AC_OUTPUT
730 AC_MSG_CHECKING(in)
731 AC_MSG_RESULT(and out again)
733 echo $ECHO_N "ordering CD from http://tobi.oetiker.ch/wish $ECHO_C" 1>&6
734 sleep 1
735 echo $ECHO_N ".$ECHO_C" 1>&6
736 sleep 1
737 echo $ECHO_N ".$ECHO_C" 1>&6
738 sleep 1
739 echo $ECHO_N ".$ECHO_C" 1>&6
740 sleep 1
741 echo $ECHO_N ".$ECHO_C" 1>&6
742 sleep 1
743 AC_MSG_RESULT([ just kidding ;-)])
744 echo
745 echo "----------------------------------------------------------------"
746 echo "Config is DONE!"
747 echo
748 echo " With MMAP IO: $enable_mmap"
749 echo " Build rrd_getopt: $build_getopt"
750 echo " Static programs: $staticprogs"
751 echo " Perl Modules: $COMP_PERL"
752 echo " Perl Binary: $PERL"
753 echo " Perl Version: $PERL_VERSION"
754 echo " Perl Options: $PERL_MAKE_OPTIONS"
755 echo " Ruby Modules: $COMP_RUBY"
756 echo " Ruby Binary: $RUBY"
757 echo " Ruby Options: $RUBY_MAKE_OPTIONS"
758 echo " Build Tcl Bindings: $enable_tcl"
759 echo " Build Python Bindings: $enable_python"
760 echo " Build rrdcgi: $enable_rrdcgi"
761 echo " Build librrd MT: $enable_pthread"
762 echo " Link with libintl: $enable_libintl"
763 echo
764 echo " Libraries: $ALL_LIBS"
765 echo
766 echo "Type 'make' to compile the software and use 'make install' to "
767 echo "install everything to: $prefix."
768 echo
769 echo " ... that wishlist is NO JOKE. If you find RRDtool useful"
770 echo "make me happy. Go to http://tobi.oetiker.ch/wish and"
771 echo "place an order."
772 echo
773 echo " -- Tobi Oetiker <tobi@oetiker.ch>"
774 echo "----------------------------------------------------------------"