1 dnl RRDtool AutoConf script ...
2 dnl ---------------------------
3 dnl
4 dnl Created by Jeff Allen, Tobi Oetiker, Blair Zajac
5 dnl
6 dnl Inspiration from http://autoconf-archive.cryp.to
8 dnl tell automake the this script is for rrdtool
9 dnl the official version number is
10 dnl a.b.c
11 AC_INIT([rrdtool],[1.2.99908020600])
12 dnl for testing a numberical version number comes handy
13 dnl the released version are
14 dnl a.bccc
15 dnl the devel versions will be something like
16 dnl a.b999yymmddhh
17 NUMVERS=1.299908020600
18 AC_SUBST(NUMVERS)
19 AC_CANONICAL_TARGET
20 AM_INIT_AUTOMAKE
21 AC_CONFIG_HEADERS([rrd_config.h])
23 dnl all our local stuff like install scripts and include files
24 dnl is in there
27 dnl determine the type of system we are running on
29 AC_SUBST(VERSION)
31 AC_PREFIX_DEFAULT( /usr/local/rrdtool-$PACKAGE_VERSION )
33 dnl Minimum Autoconf version required.
34 AC_PREREQ(2.59)
36 dnl At the TOP of the HEADER
38 AH_TOP([
40 #ifndef RRD_CONFIG_H
41 #define RRD_CONFIG_H
42 /* IEEE can be prevented from raising signals with fpsetmask(0) */
43 #undef MUST_DISABLE_FPMASK
45 /* IEEE math only works if SIGFPE gets actively set to IGNORE */
47 #undef MUST_DISABLE_SIGFPE
49 /* realloc does not support NULL as argument */
50 #undef NO_NULL_REALLOC
52 /* lets enable madvise defines in NetBSD */
53 #if defined(__NetBSD__)
54 # if !defined(_NETBSD_SOURCE)
55 # define _NETBSD_SOURCE
56 # endif
57 #endif
59 ])
61 AH_BOTTOM([
62 /* make sure that we pickup the correct stuff from all headers */
63 #ifdef HAVE_FEATURES_H
64 #undef _XOPEN_SOURCE /* keep unmodified */
65 #undef _BSD_SOURCE /* keep unmodified */
66 #define _XOPEN_SOURCE 600
67 #define _BSD_SOURCE 1
68 # include <features.h>
69 #endif
71 #ifdef HAVE_SYS_TYPES_H
72 # include <sys/types.h>
73 #endif
75 #ifdef HAVE_SYS_PARAM_H
76 # include <sys/param.h>
77 #endif
78 #ifndef MAXPATH
79 # ifdef PATH_MAX
80 # define MAXPATH PATH_MAX
81 # endif
82 #endif
83 #ifndef MAXPATH
84 /* else try the BSD variant */
85 # ifdef MAXPATHLEN
86 # define MAXPATH MAXPATHLEN
87 # endif
88 #endif
90 #ifdef HAVE_ERRNO_H
91 # include <errno.h>
92 #endif
94 #ifdef HAVE_SYS_MMAN_H
95 # include <sys/mman.h>
96 #endif
98 #if !defined HAVE_MADVISE && defined HAVE_POSIX_MADVISE
99 /* use posix_madvise family */
100 # define madvise posix_madvise
101 # define MADV_NORMAL POSIX_MADV_NORMAL
102 # define MADV_RANDOM POSIX_MADV_RANDOM
103 # define MADV_SEQUENTIAL POSIX_MADV_SEQUENTIAL
104 # define MADV_WILLNEED POSIX_MADV_WILLNEED
105 # define MADV_DONTNEED POSIX_MADV_DONTNEED
106 #endif
107 #if defined HAVE_MADVISE || defined HAVE_POSIX_MADVISE
108 # define USE_MADVISE 1
109 #endif
111 #ifdef HAVE_SYS_STAT_H
112 # include <sys/stat.h>
113 #endif
115 #ifdef HAVE_FCNTL_H
116 #include <fcntl.h>
117 #endif
119 #ifdef HAVE_UNISTD_H
120 # include <unistd.h>
121 #endif
123 #ifdef TIME_WITH_SYS_TIME
124 # include <sys/time.h>
125 # include <time.h>
126 #else
127 # ifdef HAVE_SYS_TIME_H
128 # include <sys/time.h>
129 # else
130 # include <time.h>
131 # endif
132 #endif
134 #ifdef HAVE_SYS_TIMES_H
135 # include <sys/times.h>
136 #endif
138 #ifdef HAVE_SYS_RESOURCE_H
139 # include <sys/resource.h>
140 #if (defined(__svr4__) && defined(__sun__))
141 /* Solaris headers (pre 2.6) don't have a getrusage prototype.
142 Use this instead. */
143 extern int getrusage(int, struct rusage *);
144 #endif /* __svr4__ && __sun__ */
145 #endif
148 /* define strrchr, strchr and memcpy, memmove in terms of bsd funcs
149 make sure you are NOT using bcopy, index or rindex in the code */
151 #ifdef STDC_HEADERS
152 # include <string.h>
153 #else
154 # ifndef HAVE_STRCHR
155 # define strchr index
156 # define strrchr rindex
157 # endif
158 char *strchr (), *strrchr ();
159 # ifndef HAVE_MEMMOVE
160 # define memcpy(d, s, n) bcopy ((s), (d), (n))
161 # define memmove(d, s, n) bcopy ((s), (d), (n))
162 # endif
163 #endif
165 #ifdef NO_NULL_REALLOC
166 # define rrd_realloc(a,b) ( (a) == NULL ? malloc( (b) ) : realloc( (a) , (b) ))
167 #else
168 # define rrd_realloc(a,b) realloc((a), (b))
169 #endif
171 #ifdef NEED_MALLOC_MALLOC_H
172 # include <malloc/malloc.h>
173 #endif
175 #ifdef HAVE_STDIO_H
176 # include <stdio.h>
177 #endif
179 #ifdef HAVE_STDLIB_H
180 # include <stdlib.h>
181 #endif
183 #ifdef HAVE_CTYPE_H
184 # include <ctype.h>
185 #endif
187 #ifdef HAVE_DIRENT_H
188 # include <dirent.h>
189 # define NAMLEN(dirent) strlen((dirent)->d_name)
190 #else
191 # define dirent direct
192 # define NAMLEN(dirent) (dirent)->d_namlen
193 # ifdef HAVE_SYS_NDIR_H
194 # include <sys/ndir.h>
195 # endif
196 # ifdef HAVE_SYS_DIR_H
197 # include <sys/dir.h>
198 # endif
199 # ifdef HAVE_NDIR_H
200 # include <ndir.h>
201 # endif
202 #endif
204 #ifdef MUST_DISABLE_SIGFPE
205 # include <signal.h>
206 #endif
208 #ifdef MUST_DISABLE_FPMASK
209 # include <floatingpoint.h>
210 #endif
213 #ifdef HAVE_MATH_H
214 # include <math.h>
215 #endif
217 #ifdef HAVE_FLOAT_H
218 # include <float.h>
219 #endif
221 #ifdef HAVE_IEEEFP_H
222 # include <ieeefp.h>
223 #endif
225 #ifdef HAVE_FP_CLASS_H
226 # include <fp_class.h>
227 #endif
229 /* for Solaris */
230 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASS))
231 # define HAVE_ISINF 1
232 # ifdef isinf
233 # undef isinf /* confuse autoconf */
234 # endif
235 # define isinf(a) (fpclass(a) == FP_NINF || fpclass(a) == FP_PINF)
236 #endif
238 /* solaris 10 it defines isnan such that only forte can compile it ... bad bad */
239 #if (defined(HAVE_ISNAN) && defined(isnan) && defined(HAVE_FPCLASS))
240 # undef isnan /* confuse autoconf to NOT remove this */
241 # define isnan(a) (fpclass(a) == FP_SNAN || fpclass(a) == FP_QNAN)
242 #endif
244 /* for OSF1 Digital Unix */
245 #if (! defined(HAVE_ISINF) && defined(HAVE_FP_CLASS) && defined(HAVE_FP_CLASS_H))
246 # define HAVE_ISINF 1
247 # define isinf(a) (fp_class(a) == FP_NEG_INF || fp_class(a) == FP_POS_INF)
248 #endif
250 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_PLUS_INF) && defined(FP_MINUS_INF))
251 # define HAVE_ISINF 1
252 # define isinf(a) (fpclassify(a) == FP_MINUS_INF || fpclassify(a) == FP_PLUS_INF)
253 #endif
255 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_INFINITE))
256 # define HAVE_ISINF 1
257 # define isinf(a) (fpclassify(a) == FP_INFINITE)
258 #endif
260 /* for AIX */
261 #if (! defined(HAVE_ISINF) && defined(HAVE_CLASS))
262 # define HAVE_ISINF 1
263 # define isinf(a) (class(a) == FP_MINUS_INF || class(a) == FP_PLUS_INF)
264 #endif
266 #if (! defined (HAVE_FINITE) && defined (HAVE_ISFINITE))
267 # define HAVE_FINITE 1
268 # define finite(a) isfinite(a)
269 #endif
271 #if (! defined(HAVE_FINITE) && defined(HAVE_ISNAN) && defined(HAVE_ISINF))
272 # define HAVE_FINITE 1
273 # define finite(a) (! isnan(a) && ! isinf(a))
274 #endif
276 #ifndef HAVE_FINITE
277 #error "Can't compile without finite function"
278 #endif
280 #ifndef HAVE_ISINF
281 #error "Can't compile without isinf function"
282 #endif
284 #endif /* RRD_CONFIG_H */
285 ])
287 dnl Process Special Options
288 dnl -----------------------------------
290 dnl gettext
291 GETTEXT_PACKAGE=rrdtool
292 AC_SUBST(GETTEXT_PACKAGE)
293 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package])
294 IT_PROG_INTLTOOL([0.35.0],[no-xml])
295 AM_GLIB_GNU_GETTEXT
297 dnl How the vertical axis label is printed
298 AC_ARG_VAR(RRDGRAPH_YLEGEND_ANGLE,
299 [Vertical label angle: -90.0 (default) or 90.0])
300 AC_DEFINE_UNQUOTED(RRDGRAPH_YLEGEND_ANGLE,${RRDGRAPH_YLEGEND_ANGLE:-90.0},
301 [Vertical label angle: -90.0 (default) or 90.0])
303 AC_ARG_ENABLE(rrdcgi,[ --disable-rrdcgi disable building of rrdcgi],
304 [],[enable_rrdcgi=yes])
306 dnl Check if we run on a system that has fonts
307 AC_ARG_WITH(rrd-default-font,
308 [ --with-rrd-default-font=[OPTIONS] set the full path to your default font.],
309 [RRD_DEFAULT_FONT=$withval],[
310 if test -d ${WINDIR:-nodir}/cour.ttf ; then
311 RRD_DEFAULT_FONT=`cd $WINDIR;pwd`/cour.ttf
312 else
313 RRD_DEFAULT_FONT='"DejaVu Sans Mono,Bitstream Vera Sans Mono,monospace,Courier"'
314 fi
315 ])
317 dnl Use mmap in rrd_update instead of seek+write
318 AC_ARG_ENABLE([mmap],
319 [ --disable-mmap disable mmap in rrd_update, use seek+write instead],
320 [],
321 [enable_mmap=yes])
323 AC_ARG_ENABLE(pthread,[ --disable-pthread disable multithread support],
324 [],[enable_pthread=yes])
326 AC_ARG_ENABLE(static-programs,
327 [ --enable-static-programs Build static programs],
328 [case "${enableval}" in
329 yes) staticprogs=yes ;;
330 no) staticprogs=no ;;
331 *) AC_MSG_ERROR(bad value ${enableval} for --enable-static-programs) ;;
332 esac],[staticprogs=no])
333 AM_CONDITIONAL(STATIC_PROGRAMS,[test "x$staticprogs" = "xyes"])
336 CONFIGURE_PART(Audit Compilation Environment)
339 dnl Check for the compiler and static/shared library creation.
340 AC_PROG_CC
341 AC_PROG_CPP
342 AC_PROG_LIBTOOL
344 dnl Try to detect/use GNU features
345 CFLAGS="$CFLAGS -D_GNU_SOURCE"
347 dnl which flags does the compiler support?
348 if test "x$GCC" = "xyes"; then
349 for flag in -fno-strict-aliasing -Wall -std=c99 -pedantic -Wundef -Wshadow -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Winline -Wold-style-definition -W; do
350 oCFLAGS="$CFLAGS"
351 CFLAGS="$CFLAGS $flag"
352 cachename=rd_cv_gcc_flag_`echo $flag|sed 's/[[^A-Za-z]]/_/g'`
353 AC_CACHE_CHECK([if gcc likes the $flag flag], $cachename,
354 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[return 0 ]])],[eval $cachename=yes],[eval $cachename=no])])
355 if eval test \$$cachename = no; then
356 CFLAGS="$oCFLAGS"
357 fi
358 done
359 fi
363 AC_SUBST(RRD_DEFAULT_FONT)
365 CONFIGURE_PART(Checking for Header Files)
367 dnl Checks for header files.
368 AC_HEADER_STDC
369 AC_HEADER_DIRENT
370 AC_CHECK_HEADERS(features.h sys/stat.h sys/types.h fcntl.h libintl.h locale.h fp_class.h malloc.h unistd.h ieeefp.h math.h sys/times.h sys/param.h sys/resource.h signal.h float.h stdio.h stdlib.h errno.h string.h ctype.h)
372 dnl Checks for typedefs, structures, and compiler characteristics.
373 AC_C_CONST
374 AC_HEADER_TIME
375 AC_STRUCT_TM
377 dnl Checks for libraries.
378 AC_CHECK_FUNC(acos, , AC_CHECK_LIB(m, acos))
381 dnl add pic flag in any case this makes sure all our code is relocatable
382 eval `./libtool --config | grep pic_flag`
383 CFLAGS="$CFLAGS $pic_flag"
385 CONFIGURE_PART(Test Library Functions)
387 dnl Checks for library functions.
388 AC_FUNC_STRFTIME
389 AC_FUNC_VPRINTF
391 AC_C_BIGENDIAN
393 dnl for each function found we get a definition in config.h
394 dnl of the form HAVE_FUNCTION
396 AC_CHECK_FUNCS(tzset mbstowcs opendir readdir chdir chroot getuid setlocale strerror strerror_r snprintf vsnprintf fpclass class fp_class isnan memmove strchr mktime getrusage gettimeofday)
399 dnl XXX: dunno about windows.. add AC_CHECK_FUNCS(munmap) there too?
400 if test "x$enable_mmap" = "xyes"; then
401 case "$host" in
402 *cygwin*)
403 # the normal mmap test does not work in cygwin
404 AC_CHECK_FUNCS(mmap)
405 if test "x$ac_cv_func_mmap" = "xyes"; then
406 ac_cv_func_mmap_fixed_mapped=yes
407 fi
408 ;;
409 *)
410 AC_CHECK_HEADERS(sys/mman.h)
411 AC_FUNC_MMAP
412 AC_CHECK_FUNCS(mmap munmap msync)
413 AC_CHECK_DECLS(madvise, [], [], [#ifdef HAVE_SYS_MMAN_H
414 # include <sys/mman.h>
415 #endif])
416 if test "x$ac_cv_have_decl_madvise" = "xyes";
417 then
418 AC_CHECK_FUNCS(madvise)
419 else
420 AC_CHECK_FUNCS(posix_madvise)
421 if test "x$ac_cv_func_posix_madvise" != "xyes"; then
422 AC_MSG_WARN([madvise() nor posix_madvise() found.])
423 fi
424 fi
425 ;;
426 esac
427 if test "x$ac_cv_func_mmap" != "xyes";
428 then
429 AC_MSG_ERROR([--enable-mmap requested but mmap() was not detected])
430 dnl enable_mmap="no"
431 fi
432 fi
434 dnl can we use posix_fadvise
435 AC_CHECK_DECLS(posix_fadvise, [], [], [#define _XOPEN_SOURCE 600
436 #include <fcntl.h>])
437 AC_CHECK_FUNCS(posix_fadvise)
441 CONFIGURE_PART(IEEE Math Checks)
444 dnl actual code to check if this works
445 AC_CHECK_FUNCS(fpclassify, ,
446 [AC_MSG_CHECKING(for fpclassify with <math.h>)
447 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
448 volatile int x;volatile float f; ]], [[x = fpclassify(f)]])],[AC_MSG_RESULT(yes)
449 AC_DEFINE(HAVE_FPCLASSIFY)],[AC_MSG_RESULT(no)])])
451 AC_CHECK_FUNCS(isinf, ,
452 [AC_MSG_CHECKING(for isinf with <math.h>)
453 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
454 volatile int x;volatile float f; ]], [[x = isinf(f)]])],[AC_MSG_RESULT(yes)
455 AC_DEFINE(HAVE_ISINF)],[AC_MSG_RESULT(no)])])
457 dnl finite is BSD, isfinite is C99, so prefer the latter
458 AC_CACHE_CHECK([whether isfinite is broken],[have_broken_isfinite],[
459 AC_TRY_RUN([
460 #ifdef HAVE_MATH_H
461 #include <math.h>
462 #endif
463 #ifdef HAVE_FLOAT_H
464 #include <float.h>
465 #endif
466 int main ()
467 {
468 #ifdef isfinite
469 #ifdef LDBL_MAX
470 if (!isfinite(LDBL_MAX)) return 1;
471 #endif
472 #ifdef DBL_MAX
473 if (!isfinite(DBL_MAX)) return 1;
474 #endif
475 #endif
476 return 0;
477 }],[
478 have_broken_isfinite=no],have_broken_isfinite=yes,[
479 case "${target}" in
480 hppa*-*-hpux*) have_broken_isfinite=yes ;;
481 *) have_broken_isfinite=no ;;
482 esac])
483 ])
484 if test "x$have_broken_isfinite" = "xno"; then
485 AC_DEFINE(HAVE_ISFINITE)
486 else
487 AC_CHECK_FUNCS(finite,[],
488 [AC_CHECK_FUNCS(isfinite,[],
489 [AC_MSG_CHECKING(for isfinite with <math.h>)
490 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
491 volatile int x;volatile float f; ]],[[x = isfinite(f)]])],[AC_MSG_RESULT(yes)
492 AC_DEFINE(HAVE_ISFINITE)],[AC_MSG_RESULT(no)])])])
493 fi
495 AC_FULL_IEEE
497 CONFIGURE_PART(Resolve Portability Issues)
499 dnl what does realloc do if it gets called with a NULL pointer
501 AC_CACHE_CHECK([if realloc can deal with NULL], rd_cv_null_realloc,
502 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
503 int main(void){
504 char *x = NULL;
505 x = realloc (x,10);
506 if (x==NULL) return 1;
507 return 0;
508 }]])],[rd_cv_null_realloc=yes],[rd_cv_null_realloc=nope],[:])])
510 if test x"$rd_cv_null_realloc" = xnope; then
511 AC_DEFINE(NO_NULL_REALLOC)
512 fi
514 AC_LANG_PUSH(C)
515 dnl solaris has some odd defines it needs in order to propperly compile ctime_r
516 AC_MSG_CHECKING([if ctime_r need special care to act posixly correct])
517 AC_LINK_IFELSE(
518 AC_LANG_PROGRAM(
519 [[#include <time.h>]],
520 [[ctime_r(NULL,NULL,0)]]
521 ),
522 [ CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
523 AC_LINK_IFELSE(
524 AC_LANG_PROGRAM(
525 [[#include <time.h>]],
526 [[ctime_r(NULL,NULL)]]
527 ),
528 [AC_MSG_RESULT([yes, this seems to be solaris style])],
529 [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
530 )
531 ],
532 [ AC_LINK_IFELSE(
533 AC_LANG_PROGRAM(
534 [[#include <time.h>]],
535 [[ctime_r(NULL,NULL)]]
536 ),
537 [AC_MSG_RESULT(no)],
538 [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
539 )
540 ]
541 )
542 AC_LANG_POP(C)
544 dnl Check for pthreads
545 dnl http://autoconf-archive.cryp.to/acx_pthread.m4
547 AC_SUBST(MULTITHREAD_CFLAGS)
548 AC_SUBST(MULTITHREAD_LDFLAGS)
550 if test $enable_pthread != no; then
551 ACX_PTHREAD([
552 MULTITHREAD_CFLAGS=$PTHREAD_CFLAGS
553 MULTITHREAD_LDFLAGS=$PTHREAD_LIBS
554 ],
555 [])
556 fi
558 dnl since we use lots of *_r functions all over the code we better
559 dnl make sure they are known
561 if test "x$x_rflag" != "xno"; then
562 CPPFLAGS="$CPPFLAGS $x_rflag"
563 fi
565 AM_CONDITIONAL(BUILD_MULTITHREAD,[test $enable_pthread != no])
567 AC_LANG_PUSH(C)
568 dnl see if we have to include malloc/malloc.h
569 AC_MSG_CHECKING([do we need malloc/malloc.h])
570 AC_LINK_IFELSE(
571 AC_LANG_PROGRAM(
572 [[#include <stdlib.h>]],
573 [[malloc(1)]]
574 ),
575 [ AC_MSG_RESULT([nope, works out of the box]) ],
576 [ AC_LINK_IFELSE(
577 AC_LANG_PROGRAM(
578 [[#include <stdlib.h>
579 #include <malloc/malloc.h>]],
580 [[malloc(1)]]
581 ),
582 [AC_DEFINE(NEED_MALLOC_MALLOC_H)
583 AC_MSG_RESULT([yes we do])],
584 [AC_MSG_ERROR([Can not figure how to compile malloc])]
585 )
586 ]
587 )
588 AC_LANG_POP(C)
590 dnl Could use these to know if we need to provide a prototype
591 dnl AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
593 dnl solaris has fdatasync in the librt
595 AC_CHECK_FUNC(fdatasync, [], AC_CHECK_LIB(rt, fdatasync, [LIBS="${LIBS} -lrt"],[]))
598 CONFIGURE_PART(Find 3rd-Party Libraries)
601 AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
603 CORE_LIBS="$LIBS"
605 dnl EX_CHECK_ALL(z, zlibVersion, zlib.h, zlib, 1.2.3, http://www.gzip.org/zlib/, "")
606 dnl EX_CHECK_ALL(png, png_access_version_number, png.h, libpng, 1.2.10, http://prdownloads.sourceforge.net/libpng/, "")
607 dnl EX_CHECK_ALL(freetype, FT_Init_FreeType, ft2build.h, freetype2, 2.1.10, http://prdownloads.sourceforge.net/freetype/, /usr/include/freetype2)
608 dnl EX_CHECK_ALL(fontconfig, FcInit, fontconfig.h, fontconfig, 2.3.1, http://fontconfig.org/release/, /usr/include)
609 EX_CHECK_ALL(cairo, cairo_font_options_create, cairo.h, cairo-png, 1.4.6, http://cairographics.org/releases/, "")
610 EX_CHECK_ALL(cairo, cairo_svg_surface_create, cairo-svg.h, cairo-svg, 1.4.6, http://cairographics.org/releases/, "")
611 EX_CHECK_ALL(cairo, cairo_pdf_surface_create, cairo-pdf.h, cairo-pdf, 1.4.6, http://cairographics.org/releases/, "")
612 EX_CHECK_ALL(cairo, cairo_ps_surface_create, cairo-ps.h, cairo-ps, 1.4.6, http://cairographics.org/releases/, "")
613 dnl EX_CHECK_ALL(glib-2.0, glib_check_version, glib.h, glib-2.0, 2.12.12, ftp://ftp.gtk.org/pub/glib/2.12/, "")
614 EX_CHECK_ALL(pango-1.0, pango_cairo_context_set_font_options, pango/pango.h, pangocairo, 1.17, http://ftp.gnome.org/pub/GNOME/sources/pango/1.17, "")
615 EX_CHECK_ALL(xml2, xmlParseFile, libxml/parser.h, xml2, 2.6.31, http://xmlsoft.org/downloads.html, /usr/include/libxml2)
617 if test "$EX_CHECK_ALL_ERR" = "YES"; then
618 AC_MSG_ERROR([Please fix the library issues listed above and try again.])
619 fi
621 ALL_LIBS="$LIBS"
622 LIBS=
624 AC_SUBST(CORE_LIBS)
625 AC_SUBST(ALL_LIBS)
627 CONFIGURE_PART(Prep for Building Language Bindings)
629 dnl Check for Perl.
630 AC_PATH_PROG(PERL, perl, no)
632 AC_ARG_ENABLE(perl,[ --disable-perl do not build the perl modules],
633 [],[enable_perl=yes])
636 AC_ARG_VAR(PERLCC, [[] C compiler for Perl modules])
637 AC_ARG_VAR(PERLCCFLAGS, [[] CC flags for Perl modules])
638 AC_ARG_VAR(PERLLD, [[same as PERLCC] Linker for Perl modules])
639 AC_ARG_VAR(PERLLDFLAGS, [[] LD flags for Perl modules])
641 if test "x$PERL" = "xno" -o x$enable_perl = xno; then
642 COMP_PERL=
643 else
644 COMP_PERL="perl_piped perl_shared"
645 AC_MSG_CHECKING(for the perl version you are running)
646 PERL_VERSION=`$PERL -MConfig -e 'print $Config{version}'`
647 AC_MSG_RESULT($PERL_VERSION)
648 if test -z "$PERLCC"; then
649 AC_MSG_CHECKING(for the C compiler perl wants to use to build its modules)
650 perlcc=`$PERL -MConfig -e 'print $Config{cc}'`
651 AC_MSG_RESULT($perlcc)
652 if test ! -x "$perlcc"; then
653 AC_PATH_PROG(PERL_CC, ${perlcc}, no)
654 if test "$PERL_CC" = "no"; then
655 AC_MSG_WARN([
656 I would not find the Compiler ($perlcc) that was originally used to compile
657 your perl binary. You should either make sure that this compiler is
658 available on your system, pick an other compiler and set PERLCC
659 appropriately, or use a different perl setup that was compiled locally.
661 I will disable the compilation of the RRDs perl module for now.
662 ])
663 COMP_PERL="perl_piped"
664 fi
665 fi
666 fi
667 fi
669 AC_MSG_CHECKING(Perl Modules to build)
670 AC_MSG_RESULT(${COMP_PERL:-No Perl Modules will be built})
672 # Options to pass when configuring perl module
673 ppref=$prefix
674 test "$ppref" = "NONE" && ppref=$ac_default_prefix
676 PERL_MAKE_OPTIONS="PREFIX=$ppref LIB=$ppref/lib/perl/$PERL_VERSION"
678 dnl pass additional perl options when generating Makefile from Makefile.PL
679 AC_ARG_ENABLE(perl-site-install,
680 [ --enable-perl-site-install by default the rrdtool perl modules are installed
681 together with rrdtool in $prefix/lib/perl. You have to
682 put a 'use lib qw($prefix/lib/perl)' into your scripts
683 when you want to use them. When you set this option
684 the perl modules will get installed wherever
685 your perl setup thinks it is best.],
686 [PERL_MAKE_OPTIONS=],[])
688 if test ! -z "$PERLCC"; then
689 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CC=$PERLCC"
691 if test ! -z "$PERLCCFLAGS"; then
692 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CCFLAGS=$PERLCCFLAGS"
693 fi
695 if test -z "$PERLLD"; then
696 PERLLD=$PERLCC
697 fi
698 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LD=$PERLLD"
700 if test ! -z "$PERLLDFLAGS"; then
701 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LDFLAGS=$PERLLDFLAGS"
702 fi
703 fi
705 AC_ARG_WITH(perl-options,
706 [ --with-perl-options=[OPTIONS] options to pass on command-line when
707 generating Makefile from Makefile.PL. If you set this
708 option, interesting things may happen unless you know
709 what you are doing!],
710 [PERL_MAKE_OPTIONS=$withval])
712 AC_SUBST(PERL_MAKE_OPTIONS)
713 AC_SUBST(PERL)
714 AC_SUBST(COMP_PERL)
715 AC_SUBST(PERL_VERSION)
717 dnl Check for Ruby.
718 AC_PATH_PROG(RUBY, ruby, no)
720 AC_ARG_ENABLE(ruby,[ --disable-ruby do not build the ruby modules],
721 [],[enable_ruby=yes])
723 AC_MSG_CHECKING(if ruby modules can be built)
725 if test "x$RUBY" = "xno" -o x$enable_ruby = xno; then
726 COMP_RUBY=
727 AC_MSG_RESULT(No .. Ruby not found or disabled)
728 else
729 if $RUBY -e 'require "mkmf"' >/dev/null 2>&1; then
730 COMP_RUBY="ruby"
731 AC_MSG_RESULT(YES)
732 else
733 COMP_RUBY=
734 AC_MSG_RESULT(Ruby found but mkmf is missing! Install the -dev package)
735 fi
736 fi
739 dnl pass additional ruby options when generating Makefile from Makefile.PL
740 AC_ARG_ENABLE(ruby-site-install,
741 [ --enable-ruby-site-install by default the rrdtool ruby modules are installed
742 together with rrdtool in $prefix/lib/ruby. You have to
743 add $prefix/lib/ruby/$ruby_version/$sitearch to you $: variable
744 for ruby to find the RRD.so file.],
745 [RUBY_MAKE_OPTIONS=],[RUBY_MAKE_OPTIONS="sitedir="'$(DESTDIR)'"$prefix/lib/ruby"])
748 AC_ARG_WITH(ruby-options,
749 [ --with-ruby-options=[OPTIONS] options to pass on command-line when
750 generating Makefile from extconf.rb. If you set this
751 option, interesting things may happen unless you know
752 what you are doing!],
753 [RUBY_MAKE_OPTIONS=$withval])
755 AC_SUBST(RUBY_MAKE_OPTIONS)
756 AC_SUBST(RUBY)
757 AC_SUBST(COMP_RUBY)
760 enable_tcl_site=no
762 AC_ARG_ENABLE(tcl,[ --disable-tcl do not build the tcl modules],
763 [],[enable_tcl=yes])
765 if test "$enable_tcl" = "yes"; then
766 dnl Check for Tcl.
767 withval=""
768 AC_ARG_WITH(tcllib,[ --with-tcllib=DIR location of the tclConfig.sh])
769 enable_tcl=no
770 for dir in $withval /usr/lib /usr/local/lib /usr/lib/tcl8.4 /usr/lib/tcl8.3 ; do
771 AC_MSG_CHECKING(for tclConfig.sh in $dir)
772 if test -f "$dir/tclConfig.sh" ; then
773 tcl_config=$dir/tclConfig.sh
774 enable_tcl=yes
775 AC_MSG_RESULT(yes)
776 break
777 else
778 AC_MSG_RESULT(no)
779 fi
780 done
782 if test "$enable_tcl" = "no"; then
783 AC_MSG_WARN([tclConfig.sh not found - Tcl interface won't be built])
784 else
785 . $tcl_config
786 TCL_PACKAGE_DIR="$TCL_PACKAGE_PATH/tclrrd$VERSION"
787 fi
788 AC_ARG_ENABLE(tcl,[ --enable-tcl-site install the tcl extension in the tcl tree],
789 [],[enable_tcl_site=yes])
791 fi
793 AM_CONDITIONAL(BUILD_TCL, test "$enable_tcl" = "yes" )
794 AM_CONDITIONAL(BUILD_TCL_SITE, test "$enable_tcl_site" = "yes" )
796 AC_SUBST(TCL_PREFIX)
797 AC_SUBST(TCL_SHLIB_CFLAGS)
798 AC_SUBST(TCL_SHLIB_LD)
799 AC_SUBST(TCL_SHLIB_SUFFIX)
800 AC_SUBST(TCL_PACKAGE_PATH)
801 AC_SUBST(TCL_LD_SEARCH_FLAGS)
802 AC_SUBST(TCL_STUB_LIB_SPEC)
803 AC_SUBST(TCL_VERSION)
804 AC_SUBST(TCL_PACKAGE_DIR)
805 AC_SUBST(TCL_INC_DIR)
807 AC_ARG_ENABLE(python,[ --disable-python do not build the python modules],
808 [],[enable_python=yes])
810 if test "$enable_python" = "yes"; then
811 dnl Check for python
812 AM_PATH_PYTHON(2.3,[],[enable_python=no])
813 AM_CHECK_PYTHON_HEADERS(,[enable_python=no;AC_MSG_WARN(could not find Python headers)])
814 fi
816 if test x$enable_python = xno; then
817 COMP_PYTHON=
818 else
819 COMP_PYTHON="python"
820 fi
822 AC_SUBST(COMP_PYTHON)
824 dnl Check for nroff
825 AC_PATH_PROGS(NROFF, gnroff nroff)
826 AC_PATH_PROGS(TROFF, groff troff)
828 AC_ARG_VAR(RRDDOCDIR, [[DATADIR/doc/PACKAGE-VERSION] Documentation directory])
829 if test -z "$RRDDOCDIR"; then
830 RRDDOCDIR='${datadir}/doc/${PACKAGE}-${VERSION}'; fi
833 CONFIGURE_PART(Apply Configuration Information)
835 AC_CONFIG_FILES([examples/shared-demo.pl])
836 AC_CONFIG_FILES([examples/piped-demo.pl])
837 AC_CONFIG_FILES([examples/stripes.pl])
838 AC_CONFIG_FILES([examples/bigtops.pl])
839 AC_CONFIG_FILES([examples/minmax.pl])
840 AC_CONFIG_FILES([examples/4charts.pl])
841 AC_CONFIG_FILES([examples/perftest.pl])
842 AC_CONFIG_FILES([examples/Makefile])
843 AC_CONFIG_FILES([doc/Makefile])
844 AC_CONFIG_FILES([po/Makefile.in])
845 AC_CONFIG_FILES([src/Makefile])
846 AC_CONFIG_FILES([bindings/Makefile])
847 AC_CONFIG_FILES([bindings/tcl/Makefile])
848 AC_CONFIG_FILES([bindings/tcl/ifOctets.tcl])
849 AC_CONFIG_FILES([Makefile])
851 AC_CONFIG_COMMANDS([default],[[ chmod +x examples/*.pl]],[[]])
852 AC_OUTPUT
854 AC_MSG_CHECKING(in)
855 AC_MSG_RESULT(and out again)
857 echo $ECHO_N "ordering CD from http://tobi.oetiker.ch/wish $ECHO_C" 1>&6
858 sleep 1
859 echo $ECHO_N ".$ECHO_C" 1>&6
860 sleep 1
861 echo $ECHO_N ".$ECHO_C" 1>&6
862 sleep 1
863 echo $ECHO_N ".$ECHO_C" 1>&6
864 sleep 1
865 echo $ECHO_N ".$ECHO_C" 1>&6
866 sleep 1
867 AC_MSG_RESULT([ just kidding ;-)])
868 echo
869 echo "----------------------------------------------------------------"
870 echo "Config is DONE!"
871 echo
872 echo " With MMAP IO: $enable_mmap"
873 echo " Static programs: $staticprogs"
874 echo " Perl Modules: $COMP_PERL"
875 echo " Perl Binary: $PERL"
876 echo " Perl Version: $PERL_VERSION"
877 echo " Perl Options: $PERL_MAKE_OPTIONS"
878 echo " Ruby Modules: $COMP_RUBY"
879 echo " Ruby Binary: $RUBY"
880 echo " Ruby Options: $RUBY_MAKE_OPTIONS"
881 echo " Build Tcl Bindings: $enable_tcl"
882 echo " Build Python Bindings: $enable_python"
883 echo " Build rrdcgi: $enable_rrdcgi"
884 echo " Build librrd MT: $enable_pthread"
885 echo
886 echo
887 echo "Type 'make' to compile the software and use 'make install' to "
888 echo "install everything to: $prefix."
889 echo
890 echo " ... that wishlist is NO JOKE. If you find RRDtool useful"
891 echo "make me happy. Go to http://tobi.oetiker.ch/wish and"
892 echo "place an order."
893 echo
894 echo " -- Tobi Oetiker <tobi@oetiker.ch>"
895 echo "----------------------------------------------------------------"