df219553ac8f746bb4dfe3d2976eed1681310fbe
1 dnl RRDtool AutoConf script ...
2 dnl ---------------------------
3 dnl
4 dnl Created by Jeff Allen, Tobi Oetiker, Blair Zajac
5 dnl
6 dnl Inspiration from http://autoconf-archive.cryp.to
8 dnl tell automake the this script is for rrdtool
9 dnl the official version number is
10 dnl a.b.c
11 AC_INIT([rrdtool],[1.2.23])
12 dnl for testing a numberical version number comes handy
13 dnl the released version are
14 dnl a.bccc
15 dnl the devl versions will be something like
16 dnl a.b999yymmddhh
17 NUMVERS=1.2023
18 AC_SUBST(NUMVERS)
19 AC_CANONICAL_TARGET
20 AM_INIT_AUTOMAKE
21 AC_CONFIG_HEADERS([rrd_config.h])
23 dnl all our local stuff like install scripts and include files
24 dnl is in there
27 dnl determine the type of system we are running on
29 AC_SUBST(VERSION)
31 AC_PREFIX_DEFAULT( /usr/local/rrdtool-$PACKAGE_VERSION )
33 dnl Minimum Autoconf version required.
34 AC_PREREQ(2.59)
36 dnl At the TOP of the HEADER
38 AH_TOP([
40 #ifndef RRD_CONFIG_H
41 #define RRD_CONFIG_H
42 /* IEEE can be prevented from raising signals with fpsetmask(0) */
43 #undef MUST_DISABLE_FPMASK
45 /* IEEE math only works if SIGFPE gets actively set to IGNORE */
47 #undef MUST_DISABLE_SIGFPE
49 /* realloc does not support NULL as argument */
50 #undef NO_NULL_REALLOC
52 ])
54 AH_BOTTOM([
56 /* define strrchr, strchr and memcpy, memmove in terms of bsd funcs
57 make sure you are NOT using bcopy, index or rindex in the code */
59 #ifdef STDC_HEADERS
60 # include <string.h>
61 #else
62 # ifndef HAVE_STRCHR
63 # define strchr index
64 # define strrchr rindex
65 # endif
66 char *strchr (), *strrchr ();
67 # ifndef HAVE_MEMMOVE
68 # define memcpy(d, s, n) bcopy ((s), (d), (n))
69 # define memmove(d, s, n) bcopy ((s), (d), (n))
70 # endif
71 #endif
73 /* enable posix_fadvise on linux */
74 #if defined(HAVE_POSIX_FADVISE) && defined(HAVE_FCNTL_H)
75 #define __USE_XOPEN2K 1
76 #include <fcntl.h>
77 #endif
79 #ifdef NO_NULL_REALLOC
80 # define rrd_realloc(a,b) ( (a) == NULL ? malloc( (b) ) : realloc( (a) , (b) ))
81 #else
82 # define rrd_realloc(a,b) realloc((a), (b))
83 #endif
85 #ifdef NEED_MALLOC_MALLOC_H
86 # include <malloc/malloc.h>
87 #endif
89 #ifdef HAVE_MATH_H
90 # include <math.h>
91 #endif
93 #ifdef HAVE_FLOAT_H
94 # include <float.h>
95 #endif
97 #ifdef HAVE_IEEEFP_H
98 # include <ieeefp.h>
99 #endif
101 #ifdef HAVE_FP_CLASS_H
102 # include <fp_class.h>
103 #endif
105 /* for Solaris */
106 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASS))
107 # define HAVE_ISINF 1
108 # define isinf(a) (fpclass(a) == FP_NINF || fpclass(a) == FP_PINF)
109 #endif
111 /* solaris 10 it defines isnan such that only forte can compile it ... bad bad */
112 #if (defined(HAVE_ISNAN) && defined(isnan) && defined(HAVE_FPCLASS))
113 # undef isnan
114 # define isnan(a) (fpclass(a) == FP_SNAN || fpclass(a) == FP_QNAN)
115 #endif
117 /* for OSF1 Digital Unix */
118 #if (! defined(HAVE_ISINF) && defined(HAVE_FP_CLASS) && defined(HAVE_FP_CLASS_H))
119 # define HAVE_ISINF 1
120 # define isinf(a) (fp_class(a) == FP_NEG_INF || fp_class(a) == FP_POS_INF)
121 #endif
123 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_PLUS_INF) && defined(FP_MINUS_INF))
124 # define HAVE_ISINF 1
125 # define isinf(a) (fpclassify(a) == FP_MINUS_INF || fpclassify(a) == FP_PLUS_INF)
126 #endif
128 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_INFINITE))
129 # define HAVE_ISINF 1
130 # define isinf(a) (fpclassify(a) == FP_INFINITE)
131 #endif
133 /* for AIX */
134 #if (! defined(HAVE_ISINF) && defined(HAVE_CLASS))
135 # define HAVE_ISINF 1
136 # define isinf(a) (class(a) == FP_MINUS_INF || class(a) == FP_PLUS_INF)
137 #endif
139 #if (! defined (HAVE_FINITE) && defined (HAVE_ISFINITE))
140 # define HAVE_FINITE 1
141 # define finite(a) isfinite(a)
142 #endif
144 #if (! defined(HAVE_FINITE) && defined(HAVE_ISNAN) && defined(HAVE_ISINF))
145 # define HAVE_FINITE 1
146 # define finite(a) (! isnan(a) && ! isinf(a))
147 #endif
149 #ifndef HAVE_FINITE
150 #error "Can't compile without finite function"
151 #endif
153 #ifndef HAVE_ISINF
154 #error "Can't compile without isinf function"
155 #endif
157 #endif /* RRD_CONFIG_H */
158 ])
160 dnl Process Special Options
161 dnl -----------------------------------
163 dnl How the vertical axis label is printed
164 AC_ARG_VAR(RRDGRAPH_YLEGEND_ANGLE,
165 [Vertical label angle: 90.0 (default) or 270.0])
166 AC_DEFINE_UNQUOTED(RRDGRAPH_YLEGEND_ANGLE,${RRDGRAPH_YLEGEND_ANGLE:-90.0},
167 [Vertical label angle: 90.0 (default) or 270.0])
169 AC_ARG_ENABLE(rrdcgi,[ --disable-rrdcgi disable building of rrdcgi],
170 [],[enable_rrdcgi=yes])
172 dnl Check if we run on a system that has fonts
173 AC_ARG_WITH(rrd-default-font,
174 [ --with-rrd-default-font=[OPTIONS] set the full path to your default font.],
175 [RRD_DEFAULT_FONT=$withval],[
176 if test -d ${WINDIR:-nodir}/cour.ttf ; then
177 RRD_DEFAULT_FONT=`cd $WINDIR;pwd`/cour.ttf
178 else
179 RRD_DEFAULT_FONT='$(fontsdir)/$(fonts_DATA)'
180 fi
181 ])
183 dnl Use mmap in rrd_update instead of seek+write
184 AC_ARG_ENABLE([mmap],
185 [ --disable-mmap disable mmap in rrd_update, use seek+write instead],
186 [],
187 [enable_mmap=yes])
190 AC_ARG_ENABLE(pthread,[ --disable-pthread disable multithread support],
191 [],[enable_pthread=yes])
195 CONFIGURE_PART(Audit Compilation Environment)
198 dnl Check for the compiler and static/shared library creation.
199 AC_PROG_CC
200 AC_PROG_CPP
201 AC_PROG_LIBTOOL
203 dnl which flags does the compile support?
204 if test "$GCC" = "yes"; then
205 for flag in -fno-strict-aliasing -Wall -std=gnu99 -pedantic -Wshadow -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Winline -W; do
206 oCFLAGS=$CFLAGS
207 CFLAGS="$CFLAGS $flag"
208 cachename=rd_cv_gcc_flag_`echo $flag|sed 's/[[^A-Za-z]]/_/g'`
209 AC_CACHE_CHECK([if gcc likes the $flag flag], $cachename,
210 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[return 0 ]])],[eval $cachename=yes],[eval $cachename=no])])
211 if eval test \$$cachename = no; then
212 CFLAGS=$oCFLAGS
213 fi
214 done
215 fi
219 AC_SUBST(RRD_DEFAULT_FONT)
221 CONFIGURE_PART(Checking for Header Files)
223 dnl Checks for header files.
224 AC_HEADER_STDC
225 AC_HEADER_DIRENT
226 AC_CHECK_HEADERS(sys/stat.h sys/types.h fcntl.h time.h locale.h fp_class.h malloc.h unistd.h ieeefp.h math.h sys/time.h sys/times.h sys/param.h sys/resource.h float.h)
228 dnl Checks for typedefs, structures, and compiler characteristics.
229 AC_C_CONST
230 AC_HEADER_TIME
231 AC_STRUCT_TM
233 dnl Checks for libraries.
234 AC_CHECK_FUNC(acos, , AC_CHECK_LIB(m, acos))
236 dnl add pic flag in any case this makes sure all our code is relocatable
237 eval `./libtool --config | grep pic_flag`
238 CFLAGS="$CFLAGS $pic_flag"
240 CONFIGURE_PART(Test Library Functions)
242 dnl Checks for library functions.
243 AC_FUNC_STRFTIME
244 AC_FUNC_VPRINTF
246 AC_C_BIGENDIAN
248 dnl for each function found we get a definition in config.h
249 dnl of the form HAVE_FUNCTION
251 AC_CHECK_FUNCS(tzset mbstowcs opendir readdir chdir chroot getuid setlocale strerror strerror_r snprintf vsnprintf fpclass class fp_class isnan memmove strchr mktime getrusage gettimeofday posix_fadvise madvise)
254 if test "x$enable_mmap" = xyes; then
255 case "$host" in
256 *cygwin*)
257 # the normal mmap test does not work in cygwin
258 AC_CHECK_FUNCS(mmap)
259 if [ "x${ac_cv_func_mmap}" = xyes ]; then
260 ac_cv_func_mmap_fixed_mapped=yes
261 fi
262 ;;
263 *)
264 AC_FUNC_MMAP
265 ;;
266 esac
267 fi
270 CONFIGURE_PART(IEEE Math Checks)
272 dnl HP-UX 11.00 does not have finite but does have isfinite as a macro so we need
273 dnl actual code to check if this works
274 AC_CHECK_FUNCS(fpclassify, ,
275 [AC_MSG_CHECKING(for fpclassify with <math.h>)
276 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
277 volatile int x;volatile float f; ]], [[x = fpclassify(f)]])],[AC_MSG_RESULT(yes)
278 AC_DEFINE(HAVE_FPCLASSIFY)],[AC_MSG_RESULT(no)])])
279 AC_CHECK_FUNCS(finite, ,
280 [AC_CHECK_FUNCS(isfinite, ,
281 [AC_MSG_CHECKING(for isfinite with <math.h>)
282 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
283 volatile int x;volatile float f; ]], [[x = isfinite(f)]])],[AC_MSG_RESULT(yes)
284 AC_DEFINE(HAVE_ISFINITE)],[AC_MSG_RESULT(no)])])])
285 AC_CHECK_FUNCS(isinf, ,
286 [AC_MSG_CHECKING(for isinf with <math.h>)
287 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
288 volatile int x;volatile float f; ]], [[x = isinf(f)]])],[AC_MSG_RESULT(yes)
289 AC_DEFINE(HAVE_ISINF)],[AC_MSG_RESULT(no)])])
291 AC_FULL_IEEE
293 CONFIGURE_PART(Resolve Portability Issues)
295 dnl what does realloc do if it gets called with a NULL pointer
297 AC_CACHE_CHECK([if realloc can deal with NULL], rd_cv_null_realloc,
298 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
299 int main(void){
300 char *x = NULL;
301 x = realloc (x,10);
302 if (x==NULL) return 1;
303 return 0;
304 }]])],[rd_cv_null_realloc=yes],[rd_cv_null_realloc=nope],[:])])
306 if test x"$rd_cv_null_realloc" = xnope; then
307 AC_DEFINE(NO_NULL_REALLOC)
308 fi
310 AC_LANG_PUSH(C)
311 dnl solaris has some odd defines it needs in order to propperly compile ctime_r
312 AC_MSG_CHECKING([if ctime_r need special care to act posixly correct])
313 AC_LINK_IFELSE(
314 AC_LANG_PROGRAM(
315 [[#include <time.h>]],
316 [[ctime_r(NULL,NULL,0)]]
317 ),
318 [ CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
319 AC_LINK_IFELSE(
320 AC_LANG_PROGRAM(
321 [[#include <time.h>]],
322 [[ctime_r(NULL,NULL)]]
323 ),
324 [AC_MSG_RESULT([yes, this seems to be solaris style])],
325 [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
326 )
327 ],
328 [ AC_LINK_IFELSE(
329 AC_LANG_PROGRAM(
330 [[#include <time.h>]],
331 [[ctime_r(NULL,NULL)]]
332 ),
333 [AC_MSG_RESULT(no)],
334 [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
335 )
336 ]
337 )
338 AC_LANG_POP(C)
340 dnl Check for pthreads
341 dnl http://autoconf-archive.cryp.to/acx_pthread.m4
343 AC_SUBST(MULTITHREAD_CFLAGS)
344 AC_SUBST(MULTITHREAD_LDFLAGS)
346 if test $enable_pthread != no; then
347 ACX_PTHREAD([
348 MULTITHREAD_CFLAGS=$PTHREAD_CFLAGS
349 MULTITHREAD_LDFLAGS=$PTHREAD_LIBS
350 ],
351 [])
352 fi
354 dnl since we use lots of *_r functions all over the code we better
355 dnl make sure they are known
357 if test "x$x_rflag" != "xno"; then
358 CPPFLAGS="$CPPFLAGS $x_rflag"
359 fi
361 AM_CONDITIONAL(BUILD_MULTITHREAD,[test $enable_pthread != no])
363 AC_LANG_PUSH(C)
364 dnl see if we have to include malloc/malloc.h
365 AC_MSG_CHECKING([do we need malloc/malloc.h])
366 AC_LINK_IFELSE(
367 AC_LANG_PROGRAM(
368 [[#include <stdlib.h>]],
369 [[malloc(1)]]
370 ),
371 [ AC_MSG_RESULT([nope, works out of the box]) ],
372 [ AC_LINK_IFELSE(
373 AC_LANG_PROGRAM(
374 [[#include <stdlib.h>
375 #include <malloc/malloc.h>]],
376 [[malloc(1)]]
377 ),
378 [AC_DEFINE(NEED_MALLOC_MALLOC_H)
379 AC_MSG_RESULT([yes we do])],
380 [AC_MSG_ERROR([Can not figure how to compile malloc])]
381 )
382 ]
383 )
384 AC_LANG_POP(C)
386 CONFIGURE_PART(Findr 3rd-Party Libraries)
389 AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
391 CORE_LIBS="$LIBS"
393 EX_CHECK_ALL(art_lgpl_2, art_vpath_add_point, libart_lgpl/libart.h, libart-2.0, 2.3.17, ftp://ftp.gnome.org/pub/GNOME/sources/libart_lgpl/2.3/, /usr/include/libart-2.0)
394 EX_CHECK_ALL(z, zlibVersion, zlib.h, zlib, 1.2.3, http://www.gzip.org/zlib/, "")
395 EX_CHECK_ALL(png, png_access_version_number, png.h, libpng, 1.2.10, http://prdownloads.sourceforge.net/libpng/, "")
396 EX_CHECK_ALL(freetype, FT_Init_FreeType, ft2build.h, freetype2, 2.1.10, http://prdownloads.sourceforge.net/freetype/, /usr/include/freetype2)
398 if test "$EX_CHECK_ALL_ERR" = "YES"; then
399 AC_MSG_ERROR([Please fix the library issues listed above and try again.])
400 fi
402 ALL_LIBS="$LIBS"
403 LIBS=
405 AC_SUBST(CORE_LIBS)
406 AC_SUBST(ALL_LIBS)
408 CONFIGURE_PART(Prep for Building Language Bindings)
410 dnl Check for Perl.
411 AC_PATH_PROG(PERL, perl, no)
413 AC_ARG_ENABLE(perl,[ --disable-perl do not build the perl modules],
414 [],[enable_perl=yes])
417 AC_ARG_VAR(PERLCC, [[] C compiler for Perl modules])
418 AC_ARG_VAR(PERLCCFLAGS, [[] CC flags for Perl modules])
419 AC_ARG_VAR(PERLLD, [[same as PERLCC] Linker for Perl modules])
420 AC_ARG_VAR(PERLLDFLAGS, [[] LD flags for Perl modules])
422 if test "x$PERL" = "xno" -o x$enable_perl = xno; then
423 COMP_PERL=
424 else
425 COMP_PERL="perl_piped perl_shared"
426 AC_MSG_CHECKING(for the perl version you are running)
427 PERL_VERSION=`$PERL -MConfig -e 'print $Config{version}'`
428 AC_MSG_RESULT($PERL_VERSION)
429 if test -z "$PERLCC"; then
430 AC_MSG_CHECKING(for the C compiler perl wants to use to build its modules)
431 perlcc=`$PERL -MConfig -e 'print $Config{cc}'`
432 AC_MSG_RESULT($perlcc)
433 if test ! -x "$perlcc"; then
434 AC_PATH_PROG(PERL_CC, ${perlcc}, no)
435 if test "$PERL_CC" = "no"; then
436 AC_MSG_WARN([
437 I would not find the Compiler ($perlcc) that was originally used to compile
438 your perl binary. You should either make sure that this compiler is
439 available on your system, pick an other compiler and set PERLCC
440 appropriately, or use a different perl setup that was compiled locally.
442 I will disable the compilation of the RRDs perl module for now.
443 ])
444 COMP_PERL="perl_piped"
445 fi
446 fi
447 fi
448 fi
450 AC_MSG_CHECKING(Perl Modules to build)
451 AC_MSG_RESULT(${COMP_PERL:-No Perl Modules will be built})
453 # Options to pass when configuring perl module
454 ppref=$prefix
455 test "$ppref" = "NONE" && ppref=$ac_default_prefix
457 PERL_MAKE_OPTIONS="PREFIX=$ppref LIB=$ppref/lib/perl/$PERL_VERSION"
459 dnl pass additional perl options when generating Makefile from Makefile.PL
460 AC_ARG_ENABLE(perl-site-install,
461 [ --enable-perl-site-install by default the rrdtool perl modules are installed
462 together with rrdtool in $prefix/lib/perl. You have to
463 put a 'use lib qw($prefix/lib/perl)' into your scripts
464 when you want to use them. When you set this option
465 the perl modules will get installed wherever
466 your perl setup thinks it is best.],
467 [PERL_MAKE_OPTIONS=],[])
469 if test ! -z "$PERLCC"; then
470 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CC=$PERLCC"
472 if test ! -z "$PERLCCFLAGS"; then
473 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CCFLAGS=$PERLCCFLAGS"
474 fi
476 if test -z "$PERLLD"; then
477 PERLLD=$PERLCC
478 fi
479 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LD=$PERLLD"
481 if test ! -z "$PERLLDFLAGS"; then
482 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LDFLAGS=$PERLLDFLAGS"
483 fi
484 fi
486 AC_ARG_WITH(perl-options,
487 [ --with-perl-options=[OPTIONS] options to pass on command-line when
488 generating Makefile from Makefile.PL. If you set this
489 option, interesting things may happen unless you know
490 what you are doing!],
491 [PERL_MAKE_OPTIONS=$withval])
493 AC_SUBST(PERL_MAKE_OPTIONS)
494 AC_SUBST(PERL)
495 AC_SUBST(COMP_PERL)
496 AC_SUBST(PERL_VERSION)
498 dnl Check for Ruby.
499 AC_PATH_PROG(RUBY, ruby, no)
501 AC_ARG_ENABLE(ruby,[ --disable-ruby do not build the ruby modules],
502 [],[enable_ruby=yes])
504 AC_MSG_CHECKING(if ruby modules can be built)
506 if test "x$RUBY" = "xno" -o x$enable_ruby = xno; then
507 COMP_RUBY=
508 AC_MSG_RESULT(No .. Ruby not found or disabled)
509 else
510 if $RUBY -e 'require "mkmf"' >/dev/null 2>&1; then
511 COMP_RUBY="ruby"
512 AC_MSG_RESULT(YES)
513 else
514 COMP_RUBY=
515 AC_MSG_RESULT(Ruby found but mkmf is missing! Install the -dev package)
516 fi
517 fi
520 dnl pass additional ruby options when generating Makefile from Makefile.PL
521 AC_ARG_ENABLE(ruby-site-install,
522 [ --enable-ruby-site-install by default the rrdtool ruby modules are installed
523 together with rrdtool in $prefix/lib/ruby. You have to
524 add $prefix/lib/ruby/$ruby_version/$sitearch to you $: variable
525 for ruby to find the RRD.so file.],
526 [RUBY_MAKE_OPTIONS=],[RUBY_MAKE_OPTIONS="sitedir=$prefix/lib/ruby"])
529 AC_ARG_WITH(ruby-options,
530 [ --with-ruby-options=[OPTIONS] options to pass on command-line when
531 generating Makefile from extconf.rb. If you set this
532 option, interesting things may happen unless you know
533 what you are doing!],
534 [RUBY_MAKE_OPTIONS=$withval])
536 AC_SUBST(RUBY_MAKE_OPTIONS)
537 AC_SUBST(RUBY)
538 AC_SUBST(COMP_RUBY)
541 enable_tcl_site=no
543 AC_ARG_ENABLE(tcl,[ --disable-tcl do not build the tcl modules],
544 [],[enable_tcl=yes])
546 if test "$enable_tcl" = "yes"; then
547 dnl Check for Tcl.
548 withval=""
549 AC_ARG_WITH(tcllib,[ --with-tcllib=DIR location of the tclConfig.sh])
550 enable_tcl=no
551 for dir in $withval /usr/lib /usr/local/lib; do
552 AC_MSG_CHECKING(for tclConfig.sh in $dir)
553 if test -f "$dir/tclConfig.sh" ; then
554 tcl_config=$dir/tclConfig.sh
555 enable_tcl=yes
556 AC_MSG_RESULT(yes)
557 break
558 else
559 AC_MSG_RESULT(no)
560 fi
561 done
563 if test "$enable_tcl" = "no"; then
564 AC_MSG_WARN([tclConfig.sh not found - Tcl interface won't be built])
565 else
566 . $tcl_config
567 TCL_PACKAGE_DIR="$TCL_PACKAGE_PATH/tclrrd$VERSION"
568 fi
569 AC_ARG_ENABLE(tcl,[ --enable-tcl-site install the tcl extension in the tcl tree],
570 [],[enable_tcl_site=yes])
572 fi
574 AM_CONDITIONAL(BUILD_TCL, test "$enable_tcl" = "yes" )
575 AM_CONDITIONAL(BUILD_TCL_SITE, test "$enable_tcl_site" = "yes" )
577 AC_SUBST(TCL_PREFIX)
578 AC_SUBST(TCL_SHLIB_CFLAGS)
579 AC_SUBST(TCL_SHLIB_LD)
580 AC_SUBST(TCL_SHLIB_SUFFIX)
581 AC_SUBST(TCL_PACKAGE_PATH)
582 AC_SUBST(TCL_LD_SEARCH_FLAGS)
583 AC_SUBST(TCL_STUB_LIB_SPEC)
584 AC_SUBST(TCL_VERSION)
585 AC_SUBST(TCL_PACKAGE_DIR)
587 AC_ARG_ENABLE(python,[ --disable-python do not build the python modules],
588 [],[enable_python=yes])
590 if test "$enable_python" = "yes"; then
591 dnl Check for python
592 AM_PATH_PYTHON(2.3,[],[enable_python=no])
593 AM_CHECK_PYTHON_HEADERS(,[enable_python=no;AC_MSG_WARN(could not find Python headers)])
594 fi
596 if test x$enable_python = xno; then
597 COMP_PYTHON=
598 else
599 COMP_PYTHON="python"
600 fi
602 AC_SUBST(COMP_PYTHON)
604 dnl Check for nroff
605 AC_PATH_PROGS(NROFF, gnroff nroff)
606 AC_PATH_PROGS(TROFF, groff troff)
608 AC_ARG_VAR(RRDDOCDIR, [[DATADIR/doc/PACKAGE-VERSION] Documentation directory])
609 if test -z "$RRDDOCDIR"; then
610 RRDDOCDIR='${datadir}/doc/${PACKAGE}-${VERSION}'; fi
613 CONFIGURE_PART(Apply Configuration Information)
615 AC_CONFIG_FILES([examples/shared-demo.pl])
616 AC_CONFIG_FILES([examples/piped-demo.pl])
617 AC_CONFIG_FILES([examples/stripes.pl])
618 AC_CONFIG_FILES([examples/bigtops.pl])
619 AC_CONFIG_FILES([examples/minmax.pl])
620 AC_CONFIG_FILES([examples/4charts.pl])
621 AC_CONFIG_FILES([examples/perftest.pl])
622 AC_CONFIG_FILES([examples/Makefile])
623 AC_CONFIG_FILES([doc/Makefile])
624 AC_CONFIG_FILES([src/Makefile])
625 AC_CONFIG_FILES([bindings/Makefile])
626 AC_CONFIG_FILES([bindings/tcl/Makefile])
627 AC_CONFIG_FILES([bindings/tcl/ifOctets.tcl])
628 AC_CONFIG_FILES([Makefile])
630 AC_CONFIG_COMMANDS([default],[[ chmod +x examples/*.pl]],[[]])
631 AC_OUTPUT
633 AC_MSG_CHECKING(in)
634 AC_MSG_RESULT(and out again)
636 echo $ECHO_N "ordering CD from http://tobi.oetiker.ch/wish $ECHO_C" 1>&6
637 sleep 1
638 echo $ECHO_N ".$ECHO_C" 1>&6
639 sleep 1
640 echo $ECHO_N ".$ECHO_C" 1>&6
641 sleep 1
642 echo $ECHO_N ".$ECHO_C" 1>&6
643 sleep 1
644 echo $ECHO_N ".$ECHO_C" 1>&6
645 sleep 1
646 AC_MSG_RESULT([ just kidding ;-)])
647 echo
648 echo "----------------------------------------------------------------"
649 echo "Config is DONE!"
650 echo
651 echo " With MMAP IO: $ac_cv_func_mmap_fixed_mapped"
652 echo " Perl Modules: $COMP_PERL"
653 echo " Perl Binary: $PERL"
654 echo " Perl Version: $PERL_VERSION"
655 echo " Perl Options: $PERL_MAKE_OPTIONS"
656 echo " Ruby Modules: $COMP_RUBY"
657 echo " Ruby Binary: $RUBY"
658 echo " Ruby Options: $RUBY_MAKE_OPTIONS"
659 echo " Build Tcl Bindings: $enable_tcl"
660 echo " Build Python Bindings: $enable_python"
661 echo " Build rrdcgi: $enable_rrdcgi"
662 echo " Build librrd MT: $enable_pthread"
663 echo
664 echo
665 echo "Type 'make' to compile the software and use 'make install' to "
666 echo "install everything to: $prefix."
667 echo
668 echo " ... that wishlist is NO JOKE. If you find RRDtool useful"
669 echo "make me happy. Go to http://tobi.oetiker.ch/wish and"
670 echo "place an order."
671 echo
672 echo " -- Tobi Oetiker <tobi@oetiker.ch>"
673 echo "----------------------------------------------------------------"