configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.59)
   5 AC_INIT([git], [1.4.1], [git@vger.kernel.org])
   6
   7 AC_CONFIG_SRCDIR([git.c])
   8
   9 config_file=config.mak.autogen
  10 config_append=config.mak.append
  11 config_in=config.mak.in
  12
  13 echo "# ${config_append}.  Generated by configure." > "${config_append}"
  14
  15
  16 ## Definitions of macros
  17 # GIT_CONF_APPEND_LINE(LINE)
  18 # --------------------------
  19 # Append LINE to file ${config_append}
  20 AC_DEFUN([GIT_CONF_APPEND_LINE],
  21 [echo "$1" >> "${config_append}"])# GIT_CONF_APPEND_LINE
  22 #
  23 # GIT_ARG_SET_PATH(PROGRAM)
  24 # -------------------------
  25 # Provide --with-PROGRAM=PATH option to set PATH to PROGRAM
  26 AC_DEFUN([GIT_ARG_SET_PATH],
  27 [AC_ARG_WITH([$1],
  28  [AS_HELP_STRING([--with-$1=PATH],
  29                  [provide PATH to $1])],
  30  [GIT_CONF_APPEND_PATH($1)],[])
  31 ])# GIT_ARG_SET_PATH
  32 #
  33 # GIT_CONF_APPEND_PATH(PROGRAM)
  34 # ------------------------------
  35 # Parse --with-PROGRAM=PATH option to set PROGRAM_PATH=PATH
  36 # Used by GIT_ARG_SET_PATH(PROGRAM)
  37 AC_DEFUN([GIT_CONF_APPEND_PATH],
  38 [PROGRAM=m4_toupper($1); \
  39 if test "$withval" = "no"; then \
  40         AC_MSG_WARN([You cannot use git without $1]); \
  41 else \
  42         if test "$withval" = "yes"; then \
  43                 AC_MSG_WARN([You should provide path for --with-$1=PATH]); \
  44         else \
  45                 GIT_CONF_APPEND_LINE(${PROGRAM}_PATH=$withval); \
  46         fi; \
  47 fi; \
  48 ]) # GIT_CONF_APPEND_PATH
  49
  50
  51 ## Site configuration
  52 ## --with-PACKAGE[=ARG] and --without-PACKAGE
  53 #
  54 # Define NO_SVN_TESTS if you want to skip time-consuming SVN interopability
  55 # tests.  These tests take up a significant amount of the total test time
  56 # but are not needed unless you plan to talk to SVN repos.
  57 #
  58 # Define MOZILLA_SHA1 environment variable when running make to make use of
  59 # a bundled SHA1 routine coming from Mozilla. It is GPL'd and should be fast
  60 # on non-x86 architectures (e.g. PowerPC), while the OpenSSL version (default
  61 # choice) has very fast version optimized for i586.
  62 #
  63 # Define PPC_SHA1 environment variable when running make to make use of
  64 # a bundled SHA1 routine optimized for PowerPC.
  65 #
  66 # Define ARM_SHA1 environment variable when running make to make use of
  67 # a bundled SHA1 routine optimized for ARM.
  68 #
  69 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
  70 # This also implies MOZILLA_SHA1.
  71 #
  72 # Define NO_CURL if you do not have curl installed.  git-http-pull and
  73 # git-http-push are not built, and you cannot use http:// and https://
  74 # transports.
  75 #
  76 # Define CURLDIR=/foo/bar if your curl header and library files are in
  77 # /foo/bar/include and /foo/bar/lib directories.
  78 #
  79 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
  80 # not built, and you cannot push using http:// and https:// transports.
  81 #
  82 # Define NO_MMAP if you want to avoid mmap.
  83 #
  84 # Define NO_PYTHON if you want to loose all benefits of the recursive merge.
  85 #
  86 ## --enable-FEATURE[=ARG] and --disable-FEATURE
  87 # Define COLLISION_CHECK below if you believe that SHA1's
  88 # 1461501637330902918203684832716283019655932542976 hashes do not give you
  89 # sufficient guarantee that no collisions between objects will ever happen.
  90 #
  91 # Define USE_NSEC below if you want git to care about sub-second file mtimes
  92 # and ctimes. Note that you need recent glibc (at least 2.2.4) for this, and
  93 # it will BREAK YOUR LOCAL DIFFS! show-diff and anything using it will likely
  94 # randomly break unless your underlying filesystem supports those sub-second
  95 # times (my ext3 doesn't).
  96 #
  97 # Define USE_STDEV below if you want git to care about the underlying device
  98 # change being considered an inode change from the update-cache perspective.
  99
 100
 101 ## Checks for programs.
 102 AC_MSG_NOTICE([CHECKS for programs])
 103 #
 104 GIT_ARG_SET_PATH(shell)
 105 GIT_ARG_SET_PATH(perl)
 106 #
 107 # Define NO_PYTHON if you want to lose all benefits of the recursive merge.
 108 # Define PYTHON_PATH to provide path to Python.
 109 AC_PROG_CC
 110 #AC_PROG_INSTALL                # needs install-sh or install.sh in sources
 111 AC_CHECK_TOOL(AR, ar, :)
 112 AC_CHECK_PROGS(TAR, [gtar tar])
 113
 114
 115 ## Checks for libraries.
 116 AC_MSG_NOTICE([CHECKS for libraries])
 117 #
 118 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
 119 # Define NEEDS_SSL_WITH_CRYPTO if you need -lcrypto with -lssl (Darwin).
 120 AC_CHECK_LIB([ssl], [SHA1_Init],[],
 121 [AC_CHECK_LIB([crypto], [SHA1_INIT],
 122  [GIT_CONF_APPEND_LINE(NEEDS_SSL_WITH_CRYPTO=YesPlease)],
 123  [GIT_CONF_APPEND_LINE(NO_OPENSSL=YesPlease)])])
 124 #
 125 # Define NO_CURL if you do not have curl installed.  git-http-pull and
 126 # git-http-push are not built, and you cannot use http:// and https://
 127 # transports.
 128 AC_CHECK_LIB([curl], [curl_global_init],[],
 129 [GIT_CONF_APPEND_LINE(NO_CURL=YesPlease)])
 130 #
 131 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
 132 # not built, and you cannot push using http:// and https:// transports.
 133 AC_CHECK_LIB([expat], [XML_ParserCreate],[],
 134 [GIT_CONF_APPEND_LINE(NO_EXPAT=YesPlease)])
 135 #
 136 # Define NEEDS_LIBICONV if linking with libc is not enough (Darwin).
 137 AC_CHECK_LIB([c], [iconv],[],
 138 [AC_CHECK_LIB([iconv],[iconv],
 139  [GIT_CONF_APPEND_LINE(NEEDS_LIBICONV=YesPlease)],[])])
 140 #
 141 # Define NEEDS_SOCKET if linking with libc is not enough (SunOS,
 142 # Patrick Mauritz).
 143 AC_CHECK_LIB([c], [socket],[],
 144 [AC_CHECK_LIB([socket],[socket],
 145  [GIT_CONF_APPEND_LINE(NEEDS_SOCKET=YesPlease)],[])])
 146
 147
 148 ## Checks for header files.
 149
 150
 151 ## Checks for typedefs, structures, and compiler characteristics.
 152 AC_MSG_NOTICE([CHECKS for typedefs, structures, and compiler characteristics])
 153 #
 154 # Define NO_D_INO_IN_DIRENT if you don't have d_ino in your struct dirent.
 155 AC_CHECK_MEMBER(struct dirent.d_ino,[],
 156 [GIT_CONF_APPEND_LINE(NO_D_INO_IN_DIRENT=YesPlease)],
 157 [#include <dirent.h>])
 158 #
 159 # Define NO_D_TYPE_IN_DIRENT if your platform defines DT_UNKNOWN but lacks
 160 # d_type in struct dirent (latest Cygwin -- will be fixed soonish).
 161 AC_CHECK_MEMBER(struct dirent.d_type,[],
 162 [GIT_CONF_APPEND_LINE(NO_D_TYPE_IN_DIRENT=YesPlease)],
 163 [#include <dirent.h>])
 164 #
 165 # Define NO_SOCKADDR_STORAGE if your platform does not have struct
 166 # sockaddr_storage.
 167 AC_CHECK_TYPE(struct sockaddr_storage,[],
 168 [GIT_CONF_APPEND_LINE(NO_SOCKADDR_STORAGE=YesPlease)],
 169 [#include <netinet/in.h>])
 170
 171
 172 ## Checks for library functions.
 173 ## (in default C library and libraries checked by AC_CHECK_LIB)
 174 AC_MSG_NOTICE([CHECKS for library functions])
 175 #
 176 # Define NO_STRCASESTR if you don't have strcasestr.
 177 AC_CHECK_FUNC(strcasestr,[],
 178 [GIT_CONF_APPEND_LINE(NO_STRCASESTR=YesPlease)])
 179 #
 180 # Define NO_STRLCPY if you don't have strlcpy.
 181 AC_CHECK_FUNC(strlcpy,[],
 182 [GIT_CONF_APPEND_LINE(NO_STRLCPY=YesPlease)])
 183 #
 184 # Define NO_SETENV if you don't have setenv in the C library.
 185 AC_CHECK_FUNC(setenv,[],
 186 [GIT_CONF_APPEND_LINE(NO_SETENV=YesPlease)])
 187 #
 188 # Define NO_MMAP if you want to avoid mmap.
 189 #
 190 # Define NO_IPV6 if you lack IPv6 support and getaddrinfo().
 191 #
 192 # Define NO_ICONV if your libc does not properly support iconv.
 193
 194
 195 ## Other checks.
 196 # Define USE_PIC if you need the main git objects to be built with -fPIC
 197 # in order to build and link perl/Git.so.  x86-64 seems to need this.
 198 #
 199 # Define NO_SYMLINK_HEAD if you never want .git/HEAD to be a symbolic link.
 200 # Enable it on Windows.  By default, symrefs are still used.
 201 #
 202 # Define WITH_OWN_SUBPROCESS_PY if you want to use with python 2.3.
 203 #
 204 # Define NO_ACCURATE_DIFF if your diff program at least sometimes misses
 205 # a missing newline at the end of the file.
 206
 207
 208 ## Output files
 209 AC_CONFIG_FILES(["${config_file}":"${config_in}":"${config_append}"])
 210 AC_OUTPUT
 211
 212
 213 ## Cleanup
 214 rm -f "${config_append}"