1 dnl RRDtool AutoConf script ...
2 dnl ---------------------------
3 dnl $Id$
4 dnl
5 dnl Created by Jeff Allen, Tobi Oetiker, Blair Zajac
6 dnl
7 dnl Inspiration from http://autoconf-archive.cryp.to
9 dnl tell automake the this script is for rrdtool
11 dnl Minimum Autoconf version required.
12 AC_PREREQ(2.59)
14 dnl the official version number is
15 dnl a.b.c
16 AC_INIT([rrdtool],[1.4.3])
18 dnl for testing a numberical version number comes handy
19 dnl the released version are
20 dnl a.bccc
21 dnl the devel versions will be something like
22 dnl a.b999yymmddhh
23 NUMVERS=1.4003
24 AC_SUBST(NUMVERS)
26 dnl for the linker to understand which versions the library are compatible with
27 dnl each other we must keep a separate library version cout of the format c:r:a.
28 dnl - if only implementation changed but all interfaces are kept, do r++
29 dnl - if only functionality was added do c++,r=0,a++
30 dnl - if any functionality was removed do c++,r=0,a=0.
31 dnl
32 dnl see http://sourceware.org/autobook/autobook/autobook_91.html
33 dnl
34 LIBVERS=5:3:1
35 AC_SUBST(LIBVERS)
37 AC_CANONICAL_TARGET
38 m4_version_prereq(2.60, [AC_USE_SYSTEM_EXTENSIONS], [#])
39 AM_INIT_AUTOMAKE
40 AM_MAINTAINER_MODE
41 # Enable silent build rules by default, requires at least
42 # Automake-1.11. Disable by either passing --disable-silent-rules to
43 # configure or passing V=1 to make
44 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
45 AC_CONFIG_HEADERS([rrd_config.h])
46 AC_CONFIG_MACRO_DIR([m4])
48 dnl all our local stuff like install scripts and include files
49 dnl is in there
52 dnl determine the type of system we are running on
54 AC_SUBST(VERSION)
56 AC_PREFIX_DEFAULT( /opt/rrdtool-$PACKAGE_VERSION )
58 dnl At the TOP of the HEADER
60 AH_TOP([
61 #ifndef RRD_CONFIG_H
62 #define RRD_CONFIG_H
64 /* IEEE can be prevented from raising signals with fpsetmask(0) */
65 #undef MUST_DISABLE_FPMASK
67 /* IEEE math only works if SIGFPE gets actively set to IGNORE */
68 #undef MUST_DISABLE_SIGFPE
70 /* realloc does not support NULL as argument */
71 #undef NO_NULL_REALLOC
73 /* lets enable madvise defines in NetBSD */
74 #if defined(__NetBSD__)
75 # if !defined(_NETBSD_SOURCE)
76 # define _NETBSD_SOURCE
77 # endif
78 #endif
80 ])
82 AH_BOTTOM([
84 #ifdef MUST_HAVE_MALLOC_MALLOC_H
85 # include <malloc/malloc.h>
86 #endif
88 #include "src/rrd_config_bottom.h"
90 #endif
91 ])
93 dnl Process Special Options
94 dnl -----------------------------------
96 dnl How the vertical axis label is printed
97 AC_ARG_VAR(RRDGRAPH_YLEGEND_ANGLE,
98 [Vertical label angle: -90.0 (default) or 90.0])
99 AC_DEFINE_UNQUOTED(RRDGRAPH_YLEGEND_ANGLE,${RRDGRAPH_YLEGEND_ANGLE:-90.0},
100 [Vertical label angle: -90.0 (default) or 90.0])
102 AC_ARG_ENABLE(rrdcgi,AS_HELP_STRING([--disable-rrdcgi],[disable building of rrdcgi]),
103 [],[enable_rrdcgi=yes])
105 dnl Check if we run on a system that has fonts
106 AC_ARG_WITH(rrd-default-font,
107 [ --with-rrd-default-font=[OPTIONS] set the full path to your default font.],
108 [RRD_DEFAULT_FONT=$withval],[
109 if test -d ${WINDIR:-nodir}/cour.ttf ; then
110 RRD_DEFAULT_FONT=`cd $WINDIR;pwd`/cour.ttf
111 else
112 RRD_DEFAULT_FONT='"DejaVu Sans Mono,Bitstream Vera Sans Mono,monospace,Courier"'
113 fi
114 ])
116 dnl Use mmap in rrd_update instead of seek+write
117 AC_ARG_ENABLE([mmap],
118 AS_HELP_STRING([--disable-mmap],[disable mmap in rrd_update, use seek+write instead]),
119 [],
120 [enable_mmap=yes])
122 AC_ARG_ENABLE(pthread,AS_HELP_STRING([--disable-pthread],[disable multithread support]),
123 [],[enable_pthread=yes])
125 AC_ARG_ENABLE(static-programs,
126 AS_HELP_STRING([--enable-static-programs],[Build static programs]),
127 [case "${enableval}" in
128 yes) staticprogs=yes ;;
129 no) staticprogs=no ;;
130 *) AC_MSG_ERROR(bad value ${enableval} for --enable-static-programs) ;;
131 esac],[staticprogs=no])
132 AM_CONDITIONAL(STATIC_PROGRAMS,[test "x$staticprogs" = "xyes"])
135 CONFIGURE_PART(Audit Compilation Environment)
138 dnl Check for the compiler and static/shared library creation.
139 AC_PROG_CPP
140 AC_PROG_CC
141 AM_PROG_CC_C_O
142 AC_PROG_LIBTOOL
144 dnl Try to detect/use GNU features
145 CFLAGS="$CFLAGS -D_GNU_SOURCE"
147 dnl check for -Werror separatly
148 dnl (quite a few autotool checks do not work with -Werror; also, the
149 dnl check for -Werror fails after checking and adding the other flags)
150 AC_CACHE_CHECK([if gcc likes the -Werror flag], rd_cv_gcc_flag__Werror,
151 [AC_COMPILE_IFELSE(
152 [AC_LANG_PROGRAM([[]], [[return 0 ]])],
153 [rd_cv_gcc_flag__Werror="yes"],
154 [rd_cv_gcc_flag__Werror="no"])])
155 if test "x$rd_cv_gcc_flag__Werror" = "xyes"; then
156 WERROR="-Werror"
157 else
158 WERROR=""
159 fi
160 AC_SUBST(WERROR)
162 dnl which flags does the compiler support?
163 if test "x$GCC" = "xyes"; then
164 for flag in -fno-strict-aliasing -Wall -std=c99 -pedantic -Wundef -Wshadow -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Winline -Wold-style-definition -W; do
165 oCFLAGS="$CFLAGS"
166 CFLAGS="$CFLAGS $flag"
167 cachename=rd_cv_gcc_flag_`echo $flag|sed 's/[[^A-Za-z]]/_/g'`
168 AC_CACHE_CHECK([if gcc likes the $flag flag], $cachename,
169 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[return 0 ]])],[eval $cachename=yes],[eval $cachename=no])])
170 if eval test \$$cachename = no; then
171 CFLAGS="$oCFLAGS"
172 fi
173 done
174 fi
178 AC_SUBST(RRD_DEFAULT_FONT)
180 CONFIGURE_PART(Checking for Header Files)
182 dnl Checks for header files.
183 AC_HEADER_STDC
184 AC_HEADER_DIRENT
185 AC_CHECK_HEADERS(langinfo.h stdint.h inttypes.h libgen.h features.h sys/stat.h sys/types.h fcntl.h fp_class.h malloc.h unistd.h ieeefp.h math.h sys/times.h sys/param.h sys/resource.h signal.h float.h stdio.h stdlib.h errno.h string.h ctype.h)
187 dnl Checks for typedefs, structures, and compiler characteristics.
188 AC_C_CONST
189 AC_HEADER_TIME
190 AC_STRUCT_TM
192 CONFIGURE_PART(Test Library Functions)
194 dnl Checks for libraries.
195 AC_CHECK_FUNC(acos, , AC_CHECK_LIB(m, acos))
196 AC_CHECK_FUNC(round, , AC_CHECK_LIB(m, round))
199 dnl add pic flag in any case this makes sure all our code is relocatable
200 eval `./libtool --config | grep pic_flag`
201 CFLAGS="$CFLAGS $pic_flag"
204 dnl Checks for library functions.
205 AC_FUNC_STRFTIME
206 AC_FUNC_VPRINTF
208 AC_C_BIGENDIAN
210 dnl for each function found we get a definition in config.h
211 dnl of the form HAVE_FUNCTION
213 AC_CHECK_FUNCS(nl_langinfo tzset fsync mbstowcs opendir readdir chdir chroot getuid strerror snprintf vsnprintf vasprintf fpclass class fp_class isnan memmove strchr mktime getrusage gettimeofday)
215 AC_FUNC_STRERROR_R
217 CONFIGURE_PART(Map/Fadvis/Madvise checking)
219 dnl Could use these to know if we need to provide a prototype
220 dnl AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
222 dnl check for fdatasync. Solaris has fdatasync in the librt
224 AC_CHECK_FUNCS(fdatasync, [], AC_CHECK_LIB(rt, fdatasync, [LIBS="${LIBS} -lrt"; AC_DEFINE(HAVE_FDATASYNC)],[]))
225 dnl if there is no fdatasync we may get lucky with fsync
226 AC_CHECK_FUNCS(fsync)
228 dnl check for socket and nsl solaris again ... we need this for the new rrd_daemon stuff
230 AC_CHECK_FUNCS(socket, [], AC_CHECK_LIB(socket, socket, [LIBS="${LIBS} -lsocket"; AC_DEFINE(HAVE_SOCKET)],[]))
231 AC_CHECK_FUNCS(getaddrinfo, [], AC_CHECK_LIB(nsl, getaddrinfo, [LIBS="${LIBS} -lnsl"; AC_DEFINE(HAVE_GETADDRINFO)],[]))
235 dnl XXX: dunno about windows.. add AC_CHECK_FUNCS(munmap) there too?
236 if test "x$enable_mmap" = "xyes"; then
237 case "$host" in
238 *cygwin*)
239 # the normal mmap test does not work in cygwin
240 AC_CHECK_FUNCS(mmap)
241 if test "x$ac_cv_func_mmap" = "xyes"; then
242 ac_cv_func_mmap_fixed_mapped=yes
243 fi
244 ;;
245 *)
246 AC_CHECK_HEADERS(sys/mman.h)
247 AC_FUNC_MMAP
248 AC_CHECK_FUNCS(mmap munmap msync)
249 AC_CHECK_DECLS(madvise, [], [], [#ifdef HAVE_SYS_MMAN_H
250 # include <sys/mman.h>
251 #endif])
252 if test "x$ac_cv_have_decl_madvise" = "xyes";
253 then
254 AC_CHECK_FUNCS(madvise)
255 else
256 AC_CHECK_FUNCS(posix_madvise)
257 if test "x$ac_cv_func_posix_madvise" != "xyes"; then
258 AC_MSG_WARN([madvise() nor posix_madvise() found.])
259 fi
260 fi
261 ;;
262 esac
263 if test "x$ac_cv_func_mmap" != "xyes";
264 then
265 AC_MSG_ERROR([--enable-mmap requested but mmap() was not detected])
266 dnl enable_mmap="no"
267 fi
268 fi
270 dnl can we use posix_fadvise
271 AC_CHECK_DECLS(posix_fadvise, [], [], [#define _XOPEN_SOURCE 600
272 #include <fcntl.h>])
273 AC_CHECK_FUNCS(posix_fadvise)
275 CONFIGURE_PART(Libintl Processing)
277 AM_GNU_GETTEXT_VERSION(0.17)
278 AM_GNU_GETTEXT()
280 CONFIGURE_PART(IEEE Math Checks)
283 dnl actual code to check if this works
284 AC_CHECK_FUNCS(fpclassify, ,
285 [AC_MSG_CHECKING(for fpclassify with <math.h>)
286 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
287 volatile int x;volatile float f; ]], [[x = fpclassify(f)]])],[AC_MSG_RESULT(yes)
288 AC_DEFINE(HAVE_FPCLASSIFY)],[AC_MSG_RESULT(no)])])
290 AC_CHECK_FUNCS(isinf, ,
291 [AC_MSG_CHECKING(for isinf with <math.h>)
292 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
293 volatile int x;volatile float f; ]], [[x = isinf(f)]])],[AC_MSG_RESULT(yes)
294 AC_DEFINE(HAVE_ISINF)],[AC_MSG_RESULT(no)])])
296 dnl finite is BSD, isfinite is C99, so prefer the latter
297 AC_CACHE_CHECK([whether isfinite is broken],[ac_cv_have_broken_isfinite],[
298 AC_TRY_RUN([
299 #ifdef HAVE_MATH_H
300 #include <math.h>
301 #endif
302 #ifdef HAVE_FLOAT_H
303 #include <float.h>
304 #endif
305 int main ()
306 {
307 #ifdef isfinite
308 #ifdef LDBL_MAX
309 if (!isfinite(LDBL_MAX)) return 1;
310 #endif
311 #ifdef DBL_MAX
312 if (!isfinite(DBL_MAX)) return 1;
313 #endif
314 #endif
315 return 0;
316 }],[ac_cv_have_broken_isfinite=no],[ac_cv_have_broken_isfinite=yes],[
317 case "${target}" in
318 hppa*-*-hpux*) ac_cv_have_broken_isfinite=yes ;;
319 *-solaris2.8) ac_cv_have_broken_isfinite=yes ;;
320 *-solaris2.9) ac_cv_have_broken_isfinite=yes ;;
321 *) ac_cv_have_broken_isfinite=no ;;
322 esac])
323 ])
325 dnl the test does not seem to work on solaris 2.8
326 dnl so lets fix this by hand
327 case "${target}" in
328 *-solaris2.8) ac_cv_have_broken_isfinite=yes ;;
329 *-solaris2.9) ac_cv_have_broken_isfinite=yes ;;
330 esac
332 if test "x$ac_cv_have_broken_isfinite" = "xno"; then
333 AC_DEFINE(HAVE_ISFINITE)
334 else
335 AC_CHECK_FUNCS(finite,[],
336 [AC_CHECK_FUNCS(isfinite,[],
337 [AC_MSG_CHECKING(for isfinite with <math.h>)
338 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
339 volatile int x;volatile float f; ]],[[x = isfinite(f)]])],[AC_MSG_RESULT(yes)
340 AC_DEFINE(HAVE_ISFINITE)],[AC_MSG_RESULT(no)])])])
341 fi
343 AC_FULL_IEEE
345 CONFIGURE_PART(Resolve Portability Issues)
347 CHECK_FOR_WORKING_MS_ASYNC
349 dnl do we have nl_langinfo(_NL_TIME_WEEK_1STDAY)
350 AC_CHECK_FUNCS(_NL_TIME_WEEK_1STDAY, ,
351 [AC_MSG_CHECKING([for nl_langinfo(_NL_TIME_WEEK_1STDAY) with langinfo.h])
352 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]], [[nl_langinfo(_NL_TIME_WEEK_1STDAY)]])],[AC_MSG_RESULT(yes)
353 AC_DEFINE(HAVE__NL_TIME_WEEK_1STDAY)],[AC_MSG_RESULT(no)])])
355 dnl Do we need getopt_long
357 dnl even when including our own getopt implementation
358 dnl we may want to make sure we use the external
359 dnl defined by libc to not run into linker resolve trouble
361 AC_CACHE_CHECK([for opterr], rd_cv_var_int_opterr,
362 [AC_TRY_LINK([#include <unistd.h>],
363 [extern int opterr; opterr = 1;],
364 [rd_cv_var_int_opterr=yes],
365 [rd_cv_var_int_opterr=no])])
366 if test x"$rd_cv_var_int_opterr" = x"yes"; then
367 AC_DEFINE(HAVE_INT_OPTERR, 1, [Define to 1 if you have the global variable 'int opterr'.])
368 fi
370 build_getopt=no
371 RRD_GETOPT_LONG="LIBC_HAS_GETOPT_LONG"
372 AC_CHECK_FUNC(getopt_long,[],[
373 RRD_GETOPT_LONG="getopt_long"
374 build_getopt=yes
375 ])
376 AC_SUBST(RRD_GETOPT_LONG)
377 AM_CONDITIONAL(BUILD_GETOPT,[test $build_getopt = yes])
379 dnl what does realloc do if it gets called with a NULL pointer
381 AC_CACHE_CHECK([if realloc can deal with NULL], rd_cv_null_realloc,
382 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
383 int main(void){
384 char *x = NULL;
385 x = realloc (x,10);
386 if (x==NULL) return 1;
387 return 0;
388 }]])],[rd_cv_null_realloc=yes],[rd_cv_null_realloc=nope],[:])])
390 if test x"$rd_cv_null_realloc" = xnope; then
391 AC_DEFINE(NO_NULL_REALLOC)
392 fi
394 AC_LANG_PUSH(C)
395 dnl solaris has some odd defines it needs in order to propperly compile ctime_r
396 AC_MSG_CHECKING([if ctime_r need special care to act posixly correct])
397 AC_LINK_IFELSE(
398 AC_LANG_PROGRAM(
399 [[#include <time.h>]],
400 [[ctime_r(NULL,NULL,0)]]
401 ),
402 [ CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
403 AC_LINK_IFELSE(
404 AC_LANG_PROGRAM(
405 [[#include <time.h>]],
406 [[ctime_r(NULL,NULL)]]
407 ),
408 [AC_MSG_RESULT([yes, this seems to be solaris style])],
409 [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
410 )
411 ],
412 [ AC_LINK_IFELSE(
413 AC_LANG_PROGRAM(
414 [[#include <time.h>]],
415 [[ctime_r(NULL,NULL)]]
416 ),
417 [AC_MSG_RESULT(no)],
418 [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
419 )
420 ]
421 )
422 AC_LANG_POP(C)
424 dnl Check for pthreads
425 dnl http://autoconf-archive.cryp.to/acx_pthread.m4
427 AC_SUBST(MULTITHREAD_CFLAGS)
428 AC_SUBST(MULTITHREAD_LDFLAGS)
430 if test $enable_pthread != no; then
431 ACX_PTHREAD([
432 MULTITHREAD_CFLAGS=$PTHREAD_CFLAGS
433 MULTITHREAD_LDFLAGS=$PTHREAD_LIBS
434 ],
435 [])
436 fi
438 dnl since we use lots of *_r functions all over the code we better
439 dnl make sure they are known
441 if test "x$x_rflag" != "xno"; then
442 CPPFLAGS="$CPPFLAGS $x_rflag"
443 fi
445 AM_CONDITIONAL(BUILD_MULTITHREAD,[test $enable_pthread != no])
447 AC_LANG_PUSH(C)
448 dnl see if we have to include malloc/malloc.h
449 AC_MSG_CHECKING([do we need malloc/malloc.h])
450 AC_LINK_IFELSE(
451 AC_LANG_PROGRAM(
452 [[#include <stdlib.h>]],
453 [[malloc(1)]]
454 ),
455 [ AC_MSG_RESULT([nope, works out of the box]) ],
456 [ AC_LINK_IFELSE(
457 AC_LANG_PROGRAM(
458 [[#include <stdlib.h>
459 #include <malloc/malloc.h>]],
460 [[malloc(1)]]
461 ),[
462 AC_DEFINE([MUST_HAVE_MALLOC_MALLOC_H])
463 AC_MSG_RESULT([yes we do])],
464 [AC_MSG_ERROR([Can not figure how to compile malloc])]
465 )
466 ]
467 )
469 dnl is time_t 32 of 64 bit ?
470 AC_DEFINE([TIME_T_IS_32BIT], [], [time_t is 32bit])
471 AC_DEFINE([TIME_T_IS_64BIT], [], [time_t is 64bit])
472 AC_MSG_CHECKING([the type of time_t])
473 AC_RUN_IFELSE(
474 AC_LANG_PROGRAM(
475 [[#include <time.h>]],
476 [[if (sizeof(time_t) != 4) return 1; ]]
477 ),
478 [ AC_MSG_RESULT([time_t is 32 bit])
479 AC_DEFINE([TIME_T_IS_32BIT])
480 ],
481 [ AC_RUN_IFELSE(
482 AC_LANG_PROGRAM(
483 [[#include <time.h>]],
484 [[if (sizeof(time_t) != 8) return 1; ]]
485 ),
486 [
487 AC_MSG_RESULT([time_t is 64 bit])
488 AC_DEFINE([TIME_T_IS_64BIT])
489 ],
490 [AC_MSG_ERROR([can not figure type of time_t])]
491 )
492 ]
493 )
495 AC_LANG_POP(C)
497 CONFIGURE_PART(Find 3rd-Party Libraries)
499 AC_ARG_ENABLE(libdbi,AS_HELP_STRING([--disable-libdbi],[do not build in support for libdbi]),[have_libdbi=no],[
500 XXX=$LIBS
501 LIBS="$LIBS -ldbi -ldl"
502 AC_MSG_CHECKING(for libdbi)
503 AC_LINK_IFELSE(
504 [AC_LANG_PROGRAM([[#include <dbi/dbi.h>]],
505 [[dbi_initialize(NULL)]]
506 )
507 ],[AC_DEFINE(HAVE_LIBDBI,[1],[have got libdbi installed])
508 AC_MSG_RESULT([yes])
509 have_libdbi=yes
510 ],[LIBS=$XXX
511 AC_MSG_RESULT([no])
512 have_libdbi=no
513 ]
514 )
515 ])
516 AM_CONDITIONAL(BUILD_LIBDBI,[test $have_libdbi != no])
518 AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
521 CORE_LIBS="$LIBS"
523 dnl EX_CHECK_ALL(z, zlibVersion, zlib.h, zlib, 1.2.3, http://www.gzip.org/zlib/, "")
524 dnl EX_CHECK_ALL(png, png_access_version_number, png.h, libpng, 1.2.10, http://prdownloads.sourceforge.net/libpng/, "")
525 dnl EX_CHECK_ALL(freetype, FT_Init_FreeType, ft2build.h, freetype2, 2.1.10, http://prdownloads.sourceforge.net/freetype/, /usr/include/freetype2)
526 dnl EX_CHECK_ALL(fontconfig, FcInit, fontconfig.h, fontconfig, 2.3.1, http://fontconfig.org/release/, /usr/include)
527 EX_CHECK_ALL(cairo, cairo_font_options_create, cairo.h, cairo-png, 1.4.6, http://cairographics.org/releases/, "")
528 EX_CHECK_ALL(cairo, cairo_svg_surface_create, cairo-svg.h, cairo-svg, 1.4.6, http://cairographics.org/releases/, "")
529 EX_CHECK_ALL(cairo, cairo_pdf_surface_create, cairo-pdf.h, cairo-pdf, 1.4.6, http://cairographics.org/releases/, "")
530 EX_CHECK_ALL(cairo, cairo_ps_surface_create, cairo-ps.h, cairo-ps, 1.4.6, http://cairographics.org/releases/, "")
531 EX_CHECK_ALL(glib-2.0, glib_check_version, glib.h, glib-2.0, 2.12.12, ftp://ftp.gtk.org/pub/glib/2.12/, "")
532 EX_CHECK_ALL(pangocairo-1.0, pango_cairo_context_set_font_options, pango/pango.h, pangocairo, 1.17, http://ftp.gnome.org/pub/GNOME/sources/pango/1.17, "")
533 EX_CHECK_ALL(xml2, xmlParseFile, libxml/parser.h, libxml-2.0, 2.6.31, http://xmlsoft.org/downloads.html, /usr/include/libxml2)
535 if test "$EX_CHECK_ALL_ERR" = "YES"; then
536 AC_MSG_ERROR([Please fix the library issues listed above and try again.])
537 fi
539 ALL_LIBS="$LIBS"
540 LIBS=
542 AC_SUBST(CORE_LIBS)
543 AC_SUBST(ALL_LIBS)
545 CONFIGURE_PART(Prep for Building Language Bindings)
547 dnl Check for Perl and friends
548 PATH=$PATH:/usr/perl5/bin
549 export PATH
550 AC_PATH_PROG(PERL, perl, no)
551 AC_PATH_PROG(POD2MAN, pod2man, no)
552 AC_PATH_PROG(POD2HTML, pod2html, no)
555 AC_ARG_ENABLE(perl,AS_HELP_STRING([--disable-perl],[do not build the perl modules]),
556 [],[enable_perl=yes])
559 AC_ARG_VAR(PERLCC, [C compiler for Perl modules])
560 AC_ARG_VAR(PERLCCFLAGS, [CC flags for Perl modules])
561 AC_ARG_VAR(PERLLD, [Linker for Perl modules])
562 AC_ARG_VAR(PERLLDFLAGS, [LD flags for Perl modules])
564 if test "x$PERL" = "xno" -o x$enable_perl = xno; then
565 COMP_PERL=
566 else
567 COMP_PERL="perl_piped perl_shared"
568 AC_MSG_CHECKING(for the perl version you are running)
569 PERL_VERSION=`$PERL -MConfig -e 'print $Config{version}'`
570 AC_MSG_RESULT($PERL_VERSION)
571 if test -z "$PERLCC"; then
572 AC_MSG_CHECKING(for the C compiler perl wants to use to build its modules)
573 perlcc=`$PERL -MConfig -e 'print $Config{cc}'`
574 AC_MSG_RESULT($perlcc)
575 if test ! -x "$perlcc"; then
576 AC_PATH_PROG(PERL_CC, ${perlcc}, no)
577 if test "$PERL_CC" = "no"; then
578 AC_MSG_WARN([
579 I would not find the Compiler ($perlcc) that was originally used to compile
580 your perl binary. You should either make sure that this compiler is
581 available on your system, pick an other compiler and set PERLCC
582 appropriately, or use a different perl setup that was compiled locally.
584 I will disable the compilation of the RRDs perl module for now.
585 ])
586 COMP_PERL="perl_piped"
587 fi
588 fi
589 fi
590 fi
592 AC_MSG_CHECKING(Perl Modules to build)
593 AC_MSG_RESULT(${COMP_PERL:-No Perl Modules will be built})
595 # Options to pass when configuring perl module
596 langpref=$prefix
597 test "$langpref" = '$(DESTDIR)NONE' && langpref='$(DESTDIR)'$ac_default_prefix
598 test "$langpref" = "NONE" && langpref=$ac_default_prefix
600 PERL_MAKE_OPTIONS="PREFIX=$langpref LIB=$langpref/lib/perl/$PERL_VERSION"
602 dnl pass additional perl options when generating Makefile from Makefile.PL
603 AC_ARG_ENABLE(perl-site-install,
604 AS_HELP_STRING([--enable-perl-site-install],[by default the rrdtool perl modules are installed together with rrdtool in $prefix/lib/perl. You have to put a 'use lib qw($prefix/lib/perl)' into your scripts when you want to use them. When you set this option the perl modules will get installed wherever your perl setup thinks it is best.]),
605 [PERL_MAKE_OPTIONS=],[])
607 if test ! -z "$PERLCC"; then
608 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CC=$PERLCC"
610 if test ! -z "$PERLCCFLAGS"; then
611 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CCFLAGS=$PERLCCFLAGS"
612 fi
614 if test -z "$PERLLD"; then
615 PERLLD=$PERLCC
616 fi
617 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LD=$PERLLD"
619 if test ! -z "$PERLLDFLAGS"; then
620 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LDFLAGS=$PERLLDFLAGS"
621 fi
622 fi
624 AC_ARG_WITH(perl-options,
625 [ --with-perl-options=[OPTIONS] options to pass on command-line when
626 generating Makefile from Makefile.PL. If you set this
627 option, interesting things may happen unless you know
628 what you are doing!],
629 [PERL_MAKE_OPTIONS=$withval])
631 AC_SUBST(PERL_MAKE_OPTIONS)
632 AC_SUBST(PERL)
633 AC_SUBST(COMP_PERL)
634 AC_SUBST(PERL_VERSION)
636 dnl Check for Ruby.
637 AC_PATH_PROG(RUBY, ruby, no)
639 AC_ARG_ENABLE(ruby,AS_HELP_STRING([--disable-ruby],[do not build the ruby modules]),
640 [],[enable_ruby=yes])
642 AC_MSG_CHECKING(if ruby modules can be built)
644 if test "x$RUBY" = "xno" -o x$enable_ruby = xno; then
645 COMP_RUBY=
646 AC_MSG_RESULT(No .. Ruby not found or disabled)
647 else
648 if $RUBY -e 'require "mkmf"' >/dev/null 2>&1; then
649 COMP_RUBY="ruby"
650 AC_MSG_RESULT(YES)
651 else
652 COMP_RUBY=
653 AC_MSG_RESULT(Ruby found but mkmf is missing! Install the -dev package)
654 fi
655 fi
657 dnl pass additional ruby options when generating Makefile from Makefile.PL
658 AC_ARG_ENABLE(ruby-site-install,
659 AS_HELP_STRING([--enable-ruby-site-install],[by default the rrdtool ruby modules are installed together with rrdtool in $prefix/lib/ruby. You have to add $prefix/lib/ruby/$ruby_version/$sitearch to your $: variable for ruby to find the RRD.so file.]),
660 [RUBY_MAKE_OPTIONS=],[RUBY_MAKE_OPTIONS="sitedir=$langpref/lib/ruby"])
663 AC_ARG_WITH(ruby-options,
664 [ --with-ruby-options=[OPTIONS] options to pass on command-line when
665 generating Makefile from extconf.rb. If you set this
666 option, interesting things may happen unless you know
667 what you are doing!],
668 [RUBY_MAKE_OPTIONS=$withval])
670 AC_SUBST(RUBY_MAKE_OPTIONS)
671 AC_SUBST(RUBY)
672 AC_SUBST(COMP_RUBY)
674 dnl Check for Lua.
675 AC_PATH_PROG(LUA, lua, no)
677 AC_ARG_ENABLE(lua,AS_HELP_STRING([--disable-lua],[do not build the lua modules]),
678 [],[enable_lua=yes])
680 COMP_LUA=
681 if test "$LUA" = "no" -o "$enable_lua" = "no"; then
682 enable_lua=no
683 else
684 AC_MSG_CHECKING(for lua >= 5.0)
685 read LUA_MAJOR LUA_MINOR LUA_POINT <<LUA_EOF
686 $($LUA -v 2>&1 | cut -f2 -d' ' | sed -e 's/\./ /g')
687 LUA_EOF
688 if test 0$LUA_MAJOR -lt 5; then
689 AC_MSG_RESULT([no, version found is $LUA_MAJOR.$LUA_MINOR])
690 else
691 AC_MSG_RESULT([$LUA_MAJOR.$LUA_MINOR found])
692 lua_vdot=$LUA_MAJOR.$LUA_MINOR
693 lua_vndot=$LUA_MAJOR$LUA_MINOR
694 lua_version=$LUA_MAJOR.$LUA_MINOR.$LUA_POINT
695 AC_CHECK_HEADERS(lua$lua_vndot/lua.h,
696 [AC_CHECK_HEADERS(lua$lua_vndot/lualib.h,
697 [AC_CHECK_HEADER(lua$lua_vndot/lauxlib.h,
698 [lua_headerdir=lua$lua_vndot],
699 [])],
700 [])],
701 [AC_CHECK_HEADERS(lua$lua_vdot/lua.h,
702 [AC_CHECK_HEADERS(lua$lua_vdot/lualib.h,
703 [AC_CHECK_HEADER(lua$lua_vdot/lauxlib.h,
704 [lua_headerdir=lua$lua_vdot],
705 [])],
706 [])],
707 [AC_CHECK_HEADERS(lua.h,
708 [AC_CHECK_HEADERS(lualib.h,
709 [AC_CHECK_HEADER(lauxlib.h,
710 [lua_headerdir=""],
711 [lua_headerdir="no"])],
712 [])],
713 [])])])
715 if test "$lua_headerdir" = "no"; then
716 enable_lua=no
717 else
718 COMP_LUA=lua
719 fi
721 if test "$COMP_LUA" != "lua"; then
722 enable_lua=no
723 AC_MSG_WARN([Lua $lua_vdot found but not lua.h, lualib.h and lauxlib.h! Please install the -dev packages for Lua $lua_vdot])
724 else
725 # OK, headers found, let's check the libraries (LIBS is not used)
726 LIBS=
727 lua_havelib=no
728 LUA_HAVE_COMPAT51=DONT_HAVE_COMPAT51
729 AC_SEARCH_LIBS(lua_call, lua$lua_vdot lua$lua_vndot lua,
730 [AC_SEARCH_LIBS(luaL_register, lua$lua_vdot lua$lua_vndot lua,
731 [lua_havelib=LUA$lua_vndot],
732 [AC_SEARCH_LIBS(luaL_module, lualib$lua_vndot lualib$lua_vdot lualib,
733 [lua_havelib=$lua_vndot; $LUA -l compat-5.1 2>/dev/null;
734 test "$?" = "0" && LUA_HAVE_COMPAT51=HAVE_COMPAT51],
735 [AC_SEARCH_LIBS(luaL_openlib, lualib$lua_vdot lualib$lua_vndot lualib,
736 [lua_havelib=$lua_vndot],
737 [COMP_LUA=], [-lm])], [-lm])], [-lm])],
738 [COMP_LUA=], [-lm])
739 lua_libs=$LIBS
740 LIBS=
742 # Options to pass when configuring Lua module
743 if test "$lua_havelib" != "no"; then
744 # OK, headers and libs found. Try to set lua flags
745 # and modules installation dirs with pkg-config
746 if test "$PKGCONFIG" != "no"; then
747 if test "$lua_vndot" = "50"; then
748 lua_pkg_prefix=lualib
749 else
750 lua_pkg_prefix=lua
751 fi
752 # try with dot, without dot and finally without version
753 for f in $lua_pkg_prefix$lua_vdot $lua_pkg_prefix$lua_vndot $lua_pkg_prefix; do
754 lua_exec_prefix=`$PKGCONFIG --variable=prefix $f 2>/dev/null`
755 # same binaries?
756 if test "$lua_exec_prefix/bin/lua" = "$LUA"; then
757 # OK, found CFLAGS. Get Lua LFLAGS and modules install dir
758 LUA_CFLAGS=`$PKGCONFIG --cflags $f 2>/dev/null`
759 LUA_LFLAGS=`$PKGCONFIG --libs $f 2>/dev/null`
760 LUA_INSTALL_CMOD=`$PKGCONFIG --variable=INSTALL_CMOD $f 2>/dev/null`
761 LUA_INSTALL_LMOD=`$PKGCONFIG --variable=INSTALL_LMOD $f 2>/dev/null`
762 break
763 fi
764 done
765 fi
767 LUA_RRD_LIBDIR="$langpref/lib/lua/$lua_vdot"
768 # if lua 5.0 can't find compat-5.1, force installation of
769 # compat-5.1.lua together with RRDtool.
770 if test "$lua_vdot" = "5.0" -a "$LUA_HAVE_COMPAT51" != "HAVE_COMPAT51"; then
771 lua_need_compat51=1
772 LUA_INSTALL_LMOD="$LUA_RRD_LIBDIR"
773 fi
775 # if not set with pkg-config, use default values in src packages compat-5.1, lua 5.1
776 if test "$LUA_CFLAGS" = ""; then
777 AC_MSG_WARN(Setting Lua include and lib flags to defaults in compat-5.1 and lua 5.1 sources)
778 LUA_CFLAGS="-I/usr/local/include -I/usr/local/include/lua -I/usr/local/include/lua/$lua_vdot"
779 LUA_LFLAGS="-L/usr/local/lib -L/usr/local/lib/lua -L/usr/local/lib/lua/$lua_vdot $lua_libs"
780 LUA_INSTALL_CMOD="/usr/local/lib/lua/$lua_vdot"
781 fi
783 dnl pass additional lua options
784 dnl if lua-site-install is not set, overwrite LUA_INSTALL_CMOD already
785 dnl found and install together with RRDtool, under $langpref.
786 AC_ARG_ENABLE(lua-site-install,
787 AS_HELP_STRING([--enable-lua-site-install],[by default the lua module is installed together with rrdtool in $prefix/lib/lua/$lua_version. You have to add $prefix/lib/lua/$lua_version/?.so to package.cpath for lua to find 'rrd.so'. For lua 5.0 you may also need to change LUA_PATH to the same dir, to require 'compat-5.1'. When you set this option the lua modules will get installed wherever your Lua setup thinks it is best. WARNING: if you set this option, system lua modules compat-5.1.lua and rrd.so, if any, may be overwritten.]),
788 [],
789 [LUA_INSTALL_CMOD="$LUA_RRD_LIBDIR"; LUA_INSTALL_LMOD="$LUA_RRD_LIBDIR"])
791 LUA_DEFINES="-DLUA$lua_vndot -D$LUA_HAVE_COMPAT51"
792 AC_SUBST(LUA)
793 AC_SUBST(COMP_LUA)
794 AC_SUBST(LUA_INSTALL_CMOD)
795 AC_SUBST(LUA_INSTALL_LMOD)
796 AC_SUBST(LUA_CFLAGS)
797 AC_SUBST(LUA_LFLAGS)
798 AC_SUBST(LUA_DEFINES)
799 else
800 enable_lua=no
801 AC_MSG_RESULT([Lua headers found but not the libraries! Please reinstall the dev packages for Lua $LUA_MAJOR.$LUA_MINOR])
802 fi
803 fi
804 fi
805 fi
806 dnl If Lua 5.0, we need compat-5.1. Add ours unless already
807 dnl integrated as in Debian/Ubuntu 5.0 -dev packages.
808 AM_CONDITIONAL(LUA_NEED_OUR_COMPAT51,
809 [test "$lua_vdot" = "5.0" -a "$LUA_HAVE_COMPAT51" != "HAVE_COMPAT51"])
810 AM_CONDITIONAL(LUA_SITE_CINSTALL, [test "$LUA_INSTALL_CMOD" != "$LUA_RRD_LIBDIR"])
811 AM_CONDITIONAL(LUA_SITE_LINSTALL, [test "$LUA_INSTALL_LMOD" != "$LUA_RRD_LIBDIR"])
812 AM_CONDITIONAL(LUA50, [test "$lua_vndot" = "50"])
813 AM_CONDITIONAL(BUILD_LUA, [test "$enable_lua" = "yes"])
815 enable_tcl_site=no
817 AC_ARG_ENABLE(tcl,AS_HELP_STRING([--disable-tcl],[do not build the tcl modules]),
818 [],[enable_tcl=yes])
820 if test "$enable_tcl" = "yes"; then
821 dnl Check for Tcl.
822 withval=""
823 AC_ARG_WITH(tcllib,[ --with-tcllib=DIR location of the tclConfig.sh])
824 enable_tcl=no
825 for dir in $withval /usr/lib /usr/local/lib /usr/lib/tcl8.4 /usr/lib/tcl8.3 ; do
826 AC_MSG_CHECKING(for tclConfig.sh in $dir)
827 if test -f "$dir/tclConfig.sh" ; then
828 tcl_config=$dir/tclConfig.sh
829 enable_tcl=yes
830 AC_MSG_RESULT(yes)
831 break
832 else
833 AC_MSG_RESULT(no)
834 fi
835 done
837 if test "$enable_tcl" = "no"; then
838 AC_MSG_WARN([tclConfig.sh not found - Tcl interface will not be built])
839 else
840 . $tcl_config
841 TCL_PACKAGE_DIR="$TCL_PACKAGE_PATH/tclrrd$VERSION"
842 if test -n "$TCL_INC_DIR"; then
843 TCL_INCLUDE_SPEC="$TCL_INCLUDE_SPEC -I$TCL_INC_DIR"
844 fi
845 fi
846 AC_ARG_ENABLE(tcl,AS_HELP_STRING([--enable-tcl-site],[install the tcl extension in the tcl tree]),
847 [],[enable_tcl_site=yes])
849 fi
851 AM_CONDITIONAL(BUILD_TCL, test "$enable_tcl" = "yes" )
852 AM_CONDITIONAL(BUILD_TCL_SITE, test "$enable_tcl_site" = "yes" )
855 AC_SUBST(TCL_PREFIX)
856 AC_SUBST(TCL_SHLIB_CFLAGS)
857 AC_SUBST(TCL_SHLIB_LD)
858 AC_SUBST(TCL_SHLIB_SUFFIX)
859 AC_SUBST(TCL_PACKAGE_PATH)
860 AC_SUBST(TCL_LD_SEARCH_FLAGS)
861 AC_SUBST(TCL_STUB_LIB_SPEC)
862 AC_SUBST(TCL_VERSION)
863 AC_SUBST(TCL_PACKAGE_DIR)
864 AC_SUBST(TCL_INCLUDE_SPEC)
866 AC_ARG_ENABLE(python,AS_HELP_STRING([--disable-python],[do not build the python modules]),
867 [],[enable_python=yes])
869 if test "$enable_python" = "yes"; then
870 dnl Check for python
871 AM_PATH_PYTHON(2.3,[],[enable_python=no])
872 AM_CHECK_PYTHON_HEADERS(,[enable_python=no;AC_MSG_WARN(could not find Python headers)])
873 fi
875 if test x$enable_python = xno; then
876 COMP_PYTHON=
877 else
878 COMP_PYTHON="python"
879 fi
881 AC_SUBST(COMP_PYTHON)
883 dnl Check for nroff
884 AC_PATH_PROGS(NROFF, gnroff nroff)
885 AC_PATH_PROGS(TROFF, groff troff)
887 AC_ARG_VAR(RRDDOCDIR, [[DATADIR/doc/PACKAGE-VERSION] Documentation directory])
888 if test -z "$RRDDOCDIR"; then
889 RRDDOCDIR='${datadir}/doc/${PACKAGE}-${VERSION}'; fi
892 CONFIGURE_PART(Apply Configuration Information)
894 AC_CONFIG_FILES([examples/shared-demo.pl])
895 AC_CONFIG_FILES([examples/piped-demo.pl])
896 AC_CONFIG_FILES([examples/stripes.pl])
897 AC_CONFIG_FILES([examples/bigtops.pl])
898 AC_CONFIG_FILES([examples/minmax.pl])
899 AC_CONFIG_FILES([examples/4charts.pl])
900 AC_CONFIG_FILES([examples/perftest.pl])
901 AC_CONFIG_FILES([examples/Makefile])
902 AC_CONFIG_FILES([examples/rrdcached/Makefile])
903 AC_CONFIG_FILES([doc/Makefile])
904 AC_CONFIG_FILES([po/Makefile.in])
905 AC_CONFIG_FILES([intl/Makefile])
906 AC_CONFIG_FILES([src/Makefile])
907 AC_CONFIG_FILES([src/librrd.sym.in])
908 AC_CONFIG_FILES([src/librrd.pc])
909 AC_CONFIG_FILES([bindings/Makefile])
910 AC_CONFIG_FILES([bindings/tcl/Makefile])
911 AC_CONFIG_FILES([bindings/tcl/ifOctets.tcl])
912 AC_CONFIG_FILES([Makefile])
913 AC_CONFIG_FILES([bindings/lua/Makefile])
915 AC_CONFIG_COMMANDS([default],[[ chmod +x examples/*.pl]],[[]])
917 dnl intl requires our config to be called config.h. indulge it.
918 AC_CONFIG_COMMANDS_POST([ test -f config.h || ln -s rrd_config.h config.h ])
920 AC_OUTPUT
922 AC_MSG_CHECKING(in)
923 AC_MSG_RESULT(and out again)
925 echo $ECHO_N "ordering CD from http://tobi.oetiker.ch/wish $ECHO_C" 1>&6
926 sleep 1
927 echo $ECHO_N ".$ECHO_C" 1>&6
928 sleep 1
929 echo $ECHO_N ".$ECHO_C" 1>&6
930 sleep 1
931 echo $ECHO_N ".$ECHO_C" 1>&6
932 sleep 1
933 echo $ECHO_N ".$ECHO_C" 1>&6
934 sleep 1
935 AC_MSG_RESULT([ just kidding ;-)])
936 echo
937 echo "----------------------------------------------------------------"
938 echo "Config is DONE!"
939 echo
940 echo " With MMAP IO: $enable_mmap"
941 echo " Build rrd_getopt: $build_getopt"
942 echo " Static programs: $staticprogs"
943 echo " Perl Modules: $COMP_PERL"
944 echo " Perl Binary: $PERL"
945 echo " Perl Version: $PERL_VERSION"
946 echo " Perl Options: $PERL_MAKE_OPTIONS"
947 echo " Ruby Modules: $COMP_RUBY"
948 echo " Ruby Binary: $RUBY"
949 echo " Ruby Options: $RUBY_MAKE_OPTIONS"
950 echo " Build Lua Bindings: $enable_lua"
951 if test "$enable_lua" = "yes"; then
952 echo " Lua Binary: $LUA"
953 echo " Lua Version: $lua_version"
954 echo " Lua C-modules dir: $LUA_INSTALL_CMOD"
955 if test "$lua_need_compat51" = "1"; then
956 echo " Lua Lua-modules dir: $LUA_INSTALL_LMOD"
957 fi
958 fi
959 echo " Build Tcl Bindings: $enable_tcl"
960 echo " Build Python Bindings: $enable_python"
961 echo " Build rrdcgi: $enable_rrdcgi"
962 echo " Build librrd MT: $enable_pthread"
963 echo " Use gettext: $USE_NLS"
964 echo " With libDBI: $have_libdbi"
965 echo
966 echo " Libraries: $ALL_LIBS"
967 echo
968 echo "Type 'make' to compile the software and use 'make install' to "
969 echo "install everything to: $prefix."
970 echo
971 echo " ... that wishlist is NO JOKE. If you find RRDtool useful"
972 echo "make me happy. Go to http://tobi.oetiker.ch/wish and"
973 echo "place an order."
974 echo
975 echo " -- Tobi Oetiker <tobi@oetiker.ch>"
976 echo "----------------------------------------------------------------"