1 dnl
2 dnl $Id$
3 dnl
5 AC_INIT
6 AC_CONFIG_SRCDIR([src/main.c])
7 AM_INIT_AUTOMAKE(ncmpc, 0.11.0-svn)
8 AM_CONFIG_HEADER([config.h])
10 dnl Check for programs
11 AC_PROG_CC
12 AC_PROG_INSTALL
13 dnl AC_PROG_LIBTOOL
15 dnl =======================================================
16 dnl initialize variables
17 dnl =======================================================
19 set -- $CFLAGS
21 dnl
22 dnl Check for types
23 dnl
25 AC_SOCKLEN_T
28 dnl
29 dnl Check for headers
30 dnl
32 AC_CHECK_HEADER([libgen.h],
33 AC_DEFINE([HAVE_LIBGEN_H], [1], [glibc - libgen.h]),
34 ,)
36 AC_CHECK_HEADER([locale.h],
37 AC_DEFINE([HAVE_LOCALE_H], [1], [locale.h]),
38 ,)
41 dnl
42 dnl Check for functions
43 dnl
44 AC_CHECK_FUNCS([basename strcasestr])
47 dnl
48 dnl Check for libraries
49 dnl
51 dnl ncurses
52 AC_CHECK_LIB([ncurses], [initscr],,
53 [AC_MSG_ERROR(ncurses library is required)])
54 LIBS="$LIBS -lncurses"
56 dnl popt
57 AC_CHECK_LIB([popt],
58 [poptGetArg],
59 [LIBS="$LIBS -lpopt"],
60 AC_MSG_ERROR([Missing popt command line parsing library]))
63 dnl Check for glib-2.4
64 PKG_CHECK_MODULES([GLIB],
65 [glib-2.0 >= 2.4],
66 glib24=yes,
67 AC_MSG_WARN([glib-2.4 is required for NLS support!]))
68 if test "x$glib24" != "xyes"; then
69 PKG_CHECK_MODULES([GLIB],
70 [glib-2.0 >= 2.2],
71 nls=no,
72 AC_MSG_ERROR([glib-2.2 is required]))
73 fi
76 dnl i18n
77 ALL_LINGUAS="sv"
79 AM_NLS
80 if test "x$glib24" = "xyes"; then
81 nls=$USE_NLS
82 else
83 USE_NLS=no
84 AC_SUBST(USE_NLS)
85 fi
87 if test "x$nls" = "xyes"; then
88 AM_GLIB_GNU_GETTEXT
89 GETTEXT_PACKAGE=$PACKAGE
90 AC_SUBST(GETTEXT_PACKAGE)
91 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],
92 ["${GETTEXT_PACKAGE}"],
93 [gettext domain])
94 nls=$gt_cv_have_gettext
95 else
96 AM_PO_SUBDIRS
97 fi
100 dnl Debugging
101 AC_MSG_CHECKING([whether to build with debug support])
102 AC_ARG_ENABLE([debug],
103 AC_HELP_STRING([--enable-debug],
104 [Enable debugging @<:@default=no@:>@)]),
105 [enable_debug="$enableval"],
106 [enable_debug=no])
107 AC_MSG_RESULT([$enable_debug])
108 if test "x$enable_debug" = "xyes" ; then
109 CFLAGS="$CFLAGS -Wall -g -DDEBUG"
110 fi
112 dnl Optional screen - key editor
113 AC_MSG_CHECKING([whether to include the key editor screen])
114 AC_ARG_ENABLE([key-screen],
115 AC_HELP_STRING([--enable-key-screen],
116 [Enable key editor screen @<:@default=yes@:>@]),
117 [keydef_screen="$enableval"],
118 [keydef_screen=yes])
119 AC_MSG_RESULT([$keydef_screen])
120 if test "x$keydef_screen" = "xyes" ; then
121 AC_DEFINE(ENABLE_KEYDEF_SCREEN, 1, [Enable key editor screen])
122 fi
124 dnl Optional screen - clock
125 AC_MSG_CHECKING([whether to include the clock screen])
126 AC_ARG_ENABLE([clock-screen],
127 AC_HELP_STRING([--enable-clock-screen],
128 [Enable clock screen @<:@default=no@:>@]),
129 [clock_screen="$enableval"],
130 [clock_screen=no])
131 AC_MSG_RESULT([$clock_screen])
132 if test "x$clock_screen" = "xyes" ; then
133 AC_DEFINE(ENABLE_CLOCK_SCREEN, 1, [Enable clock screen])
134 fi
136 dnl Default host
137 AC_MSG_CHECKING([for default MPD host])
138 AC_ARG_WITH([default-host],
139 AC_HELP_STRING([--with-default-host=ARG],
140 [Default MPD host @<:@localhost@:>@]),
141 [DEFAULT_HOST="$withval"],
142 [DEFAULT_HOST="localhost"])
143 AC_MSG_RESULT([$DEFAULT_HOST])
144 AC_DEFINE_UNQUOTED([DEFAULT_HOST], ["$DEFAULT_HOST"], [Default MPD host])
146 dnl Default port
147 AC_MSG_CHECKING([for default MPD port])
148 AC_ARG_WITH([default-port],
149 AC_HELP_STRING([--with-default-port=ARG],
150 [Default port @<:@6600@:>@]),
151 [DEFAULT_PORT="$withval"],
152 [DEFAULT_PORT="6600"])
153 AC_MSG_RESULT([$DEFAULT_PORT])
154 AC_DEFINE_UNQUOTED([DEFAULT_PORT], [$DEFAULT_PORT], [Default MPD port])
155 AC_DEFINE_UNQUOTED([DEFAULT_PORT_STR], ["$DEFAULT_PORT"], [Default MPD port])
158 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile po/Makefile.in])
159 AC_OUTPUT