1 dnl RRDtool AutoConf script ...
2 dnl ---------------------------
3 dnl $Id$
4 dnl
5 dnl Created by Jeff Allen, Tobi Oetiker, Blair Zajac
6 dnl
7 dnl Inspiration from http://autoconf-archive.cryp.to
9 dnl tell automake the this script is for rrdtool
11 dnl Minimum Autoconf version required.
12 AC_PREREQ(2.59)
14 dnl the official version number is
15 dnl a.b.c
16 AC_INIT([rrdtool],[1.4.3])
18 dnl for testing a numberical version number comes handy
19 dnl the released version are
20 dnl a.bccc
21 dnl the devel versions will be something like
22 dnl a.b999yymmddhh
23 NUMVERS=1.4003
24 AC_SUBST(NUMVERS)
26 dnl for the linker to understand which versions the library are compatible with
27 dnl each other we must keep a separate library version cout of the format c:r:a.
28 dnl - if only implementation changed but all interfaces are kept, do r++
29 dnl - if only functionality was added do c++,r=0,a++
30 dnl - if any functionality was removed do c++,r=0,a=0.
31 dnl
32 dnl see http://sourceware.org/autobook/autobook/autobook_91.html
33 dnl
34 LIBVERS=5:3:1
35 AC_SUBST(LIBVERS)
37 AC_CANONICAL_TARGET
38 m4_version_prereq(2.60, [AC_USE_SYSTEM_EXTENSIONS], [#])
39 AM_INIT_AUTOMAKE
40 AM_MAINTAINER_MODE
41 # Enable silent build rules by default, requires at least
42 # Automake-1.11. Disable by either passing --disable-silent-rules to
43 # configure or passing V=1 to make
44 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
45 AC_CONFIG_HEADERS([rrd_config.h])
46 AC_CONFIG_MACRO_DIR([m4])
48 dnl all our local stuff like install scripts and include files
49 dnl is in there
52 dnl determine the type of system we are running on
54 AC_SUBST(VERSION)
56 AC_PREFIX_DEFAULT( /opt/rrdtool-$PACKAGE_VERSION )
58 dnl At the TOP of the HEADER
60 AH_TOP([
61 #ifndef RRD_CONFIG_H
62 #define RRD_CONFIG_H
64 /* IEEE can be prevented from raising signals with fpsetmask(0) */
65 #undef MUST_DISABLE_FPMASK
67 /* IEEE math only works if SIGFPE gets actively set to IGNORE */
68 #undef MUST_DISABLE_SIGFPE
70 /* realloc does not support NULL as argument */
71 #undef NO_NULL_REALLOC
73 /* lets enable madvise defines in NetBSD */
74 #if defined(__NetBSD__)
75 # if !defined(_NETBSD_SOURCE)
76 # define _NETBSD_SOURCE
77 # endif
78 #endif
80 ])
82 AH_BOTTOM([
84 #ifdef MUST_HAVE_MALLOC_MALLOC_H
85 # include <malloc/malloc.h>
86 #endif
88 #include "src/rrd_config_bottom.h"
90 #endif
91 ])
93 dnl Process Special Options
94 dnl -----------------------------------
96 dnl How the vertical axis label is printed
97 AC_ARG_VAR(RRDGRAPH_YLEGEND_ANGLE,
98 [Vertical label angle: -90.0 (default) or 90.0])
99 AC_DEFINE_UNQUOTED(RRDGRAPH_YLEGEND_ANGLE,${RRDGRAPH_YLEGEND_ANGLE:-90.0},
100 [Vertical label angle: -90.0 (default) or 90.0])
102 AC_ARG_ENABLE(rrdcgi,AS_HELP_STRING([--disable-rrdcgi],[disable building of rrdcgi]),
103 [],[enable_rrdcgi=yes])
105 AC_ARG_ENABLE(libwrap,
106 AS_HELP_STRING([--disable-libwrap],
107 [do not build in support for libwrap (tcp wrapper)]),
108 [have_libwrap=no],[
109 XXX=$LIBS
110 LIBS="$LIBS -lwrap"
111 AC_MSG_CHECKING(for libwrap)
112 AC_LINK_IFELSE(
113 [AC_LANG_PROGRAM([[#include "tcpd.h"]], [[hosts_access(NULL)]])
114 ],[AC_DEFINE(HAVE_LIBWRAP,[1],[have got libwrap installed])
115 AC_MSG_RESULT([yes])
116 have_libwrap=yes
117 ],[LIBS=$XXX
118 AC_MSG_RESULT([no])
119 have_libwrap=no
120 ]
121 )
122 ])
123 AM_CONDITIONAL(BUILD_LIBWRAP,[test $have_libwrap != no])
125 AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
127 dnl Check if we run on a system that has fonts
128 AC_ARG_WITH(rrd-default-font,
129 [ --with-rrd-default-font=[OPTIONS] set the full path to your default font.],
130 [RRD_DEFAULT_FONT=$withval],[
131 if test -d ${WINDIR:-nodir}/cour.ttf ; then
132 RRD_DEFAULT_FONT=`cd $WINDIR;pwd`/cour.ttf
133 else
134 RRD_DEFAULT_FONT='"DejaVu Sans Mono,Bitstream Vera Sans Mono,monospace,Courier"'
135 fi
136 ])
138 dnl Use mmap in rrd_update instead of seek+write
139 AC_ARG_ENABLE([mmap],
140 AS_HELP_STRING([--disable-mmap],[disable mmap in rrd_update, use seek+write instead]),
141 [],
142 [enable_mmap=yes])
144 AC_ARG_ENABLE(pthread,AS_HELP_STRING([--disable-pthread],[disable multithread support]),
145 [],[enable_pthread=yes])
147 AC_ARG_ENABLE(static-programs,
148 AS_HELP_STRING([--enable-static-programs],[Build static programs]),
149 [case "${enableval}" in
150 yes) staticprogs=yes ;;
151 no) staticprogs=no ;;
152 *) AC_MSG_ERROR(bad value ${enableval} for --enable-static-programs) ;;
153 esac],[staticprogs=no])
154 AM_CONDITIONAL(STATIC_PROGRAMS,[test "x$staticprogs" = "xyes"])
157 CONFIGURE_PART(Audit Compilation Environment)
160 dnl Check for the compiler and static/shared library creation.
161 AC_PROG_CPP
162 AC_PROG_CC
163 AM_PROG_CC_C_O
164 AC_PROG_LIBTOOL
166 dnl Try to detect/use GNU features
167 CFLAGS="$CFLAGS -D_GNU_SOURCE"
169 dnl check for -Werror separatly
170 dnl (quite a few autotool checks do not work with -Werror; also, the
171 dnl check for -Werror fails after checking and adding the other flags)
172 AC_CACHE_CHECK([if gcc likes the -Werror flag], rd_cv_gcc_flag__Werror,
173 [AC_COMPILE_IFELSE(
174 [AC_LANG_PROGRAM([[]], [[return 0 ]])],
175 [rd_cv_gcc_flag__Werror="yes"],
176 [rd_cv_gcc_flag__Werror="no"])])
177 if test "x$rd_cv_gcc_flag__Werror" = "xyes"; then
178 WERROR="-Werror"
179 else
180 WERROR=""
181 fi
182 AC_SUBST(WERROR)
184 dnl which flags does the compiler support?
185 if test "x$GCC" = "xyes"; then
186 for flag in -fno-strict-aliasing -Wall -std=gnu99 -pedantic -Wundef -Wshadow -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Winline -Wold-style-definition -W; do
187 oCFLAGS="$CFLAGS"
188 CFLAGS="$CFLAGS $flag"
189 cachename=rd_cv_gcc_flag_`echo $flag|sed 's/[[^A-Za-z]]/_/g'`
190 AC_CACHE_CHECK([if gcc likes the $flag flag], $cachename,
191 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[return 0 ]])],[eval $cachename=yes],[eval $cachename=no])])
192 if eval test \$$cachename = no; then
193 CFLAGS="$oCFLAGS"
194 fi
195 done
196 fi
200 AC_SUBST(RRD_DEFAULT_FONT)
202 CONFIGURE_PART(Checking for Header Files)
204 dnl Checks for header files.
205 AC_HEADER_STDC
206 AC_HEADER_DIRENT
207 AC_CHECK_HEADERS(langinfo.h stdint.h inttypes.h libgen.h features.h sys/stat.h sys/types.h fcntl.h fp_class.h malloc.h unistd.h ieeefp.h math.h sys/times.h sys/param.h sys/resource.h signal.h float.h stdio.h stdlib.h errno.h string.h ctype.h)
209 dnl Checks for typedefs, structures, and compiler characteristics.
210 AC_C_CONST
211 AC_HEADER_TIME
212 AC_STRUCT_TM
214 CONFIGURE_PART(Test Library Functions)
216 dnl Checks for libraries.
217 AC_CHECK_FUNC(acos, , AC_CHECK_LIB(m, acos))
218 AC_CHECK_FUNC(round, , AC_CHECK_LIB(m, round))
221 dnl add pic flag in any case this makes sure all our code is relocatable
222 eval `./libtool --config | grep pic_flag`
223 CFLAGS="$CFLAGS $pic_flag"
226 dnl Checks for library functions.
227 AC_FUNC_STRFTIME
228 AC_FUNC_VPRINTF
230 AC_C_BIGENDIAN
232 dnl for each function found we get a definition in config.h
233 dnl of the form HAVE_FUNCTION
235 AC_CHECK_FUNCS(nl_langinfo tzset fsync mbstowcs opendir readdir chdir chroot getuid strerror snprintf vsnprintf vasprintf fpclass class fp_class isnan memmove strchr mktime getrusage gettimeofday)
237 AC_FUNC_STRERROR_R
239 CONFIGURE_PART(Map/Fadvis/Madvise checking)
241 dnl Could use these to know if we need to provide a prototype
242 dnl AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
244 dnl check for fdatasync. Solaris has fdatasync in the librt
246 AC_CHECK_FUNCS(fdatasync, [], AC_CHECK_LIB(rt, fdatasync, [LIBS="${LIBS} -lrt"; AC_DEFINE(HAVE_FDATASYNC)],[]))
247 dnl if there is no fdatasync we may get lucky with fsync
248 AC_CHECK_FUNCS(fsync)
250 dnl check for socket and nsl solaris again ... we need this for the new rrd_daemon stuff
252 AC_CHECK_FUNCS(socket, [], AC_CHECK_LIB(socket, socket, [LIBS="${LIBS} -lsocket"; AC_DEFINE(HAVE_SOCKET)],[]))
253 AC_CHECK_FUNCS(getaddrinfo, [], AC_CHECK_LIB(nsl, getaddrinfo, [LIBS="${LIBS} -lnsl"; AC_DEFINE(HAVE_GETADDRINFO)],[]))
257 dnl XXX: dunno about windows.. add AC_CHECK_FUNCS(munmap) there too?
258 if test "x$enable_mmap" = "xyes"; then
259 case "$host" in
260 *cygwin*)
261 # the normal mmap test does not work in cygwin
262 AC_CHECK_FUNCS(mmap)
263 if test "x$ac_cv_func_mmap" = "xyes"; then
264 ac_cv_func_mmap_fixed_mapped=yes
265 fi
266 ;;
267 *)
268 AC_CHECK_HEADERS(sys/mman.h)
269 AC_FUNC_MMAP
270 AC_CHECK_FUNCS(mmap munmap msync)
271 AC_CHECK_DECLS(madvise, [], [], [#ifdef HAVE_SYS_MMAN_H
272 # include <sys/mman.h>
273 #endif])
274 if test "x$ac_cv_have_decl_madvise" = "xyes";
275 then
276 AC_CHECK_FUNCS(madvise)
277 else
278 AC_CHECK_FUNCS(posix_madvise)
279 if test "x$ac_cv_func_posix_madvise" != "xyes"; then
280 AC_MSG_WARN([madvise() nor posix_madvise() found.])
281 fi
282 fi
283 ;;
284 esac
285 if test "x$ac_cv_func_mmap" != "xyes";
286 then
287 AC_MSG_ERROR([--enable-mmap requested but mmap() was not detected])
288 dnl enable_mmap="no"
289 fi
290 fi
292 dnl can we use posix_fadvise
293 AC_CHECK_DECLS(posix_fadvise, [], [], [#define _XOPEN_SOURCE 600
294 #include <fcntl.h>])
295 AC_CHECK_FUNCS(posix_fadvise)
297 CONFIGURE_PART(Libintl Processing)
299 AM_GNU_GETTEXT_VERSION(0.18)
300 AM_GNU_GETTEXT(external)
302 CONFIGURE_PART(IEEE Math Checks)
305 dnl actual code to check if this works
306 AC_CHECK_FUNCS(fpclassify, ,
307 [AC_MSG_CHECKING(for fpclassify with <math.h>)
308 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
309 volatile int x;volatile float f; ]], [[x = fpclassify(f)]])],[AC_MSG_RESULT(yes)
310 AC_DEFINE(HAVE_FPCLASSIFY)],[AC_MSG_RESULT(no)])])
312 AC_CHECK_FUNCS(isinf, ,
313 [AC_MSG_CHECKING(for isinf with <math.h>)
314 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
315 volatile int x;volatile float f; ]], [[x = isinf(f)]])],[AC_MSG_RESULT(yes)
316 AC_DEFINE(HAVE_ISINF)],[AC_MSG_RESULT(no)])])
318 dnl finite is BSD, isfinite is C99, so prefer the latter
319 AC_CACHE_CHECK([whether isfinite is broken],[ac_cv_have_broken_isfinite],[
320 AC_TRY_RUN([
321 #ifdef HAVE_MATH_H
322 #include <math.h>
323 #endif
324 #ifdef HAVE_FLOAT_H
325 #include <float.h>
326 #endif
327 int main ()
328 {
329 #ifdef isfinite
330 #ifdef LDBL_MAX
331 if (!isfinite(LDBL_MAX)) return 1;
332 #endif
333 #ifdef DBL_MAX
334 if (!isfinite(DBL_MAX)) return 1;
335 #endif
336 #endif
337 return 0;
338 }],[ac_cv_have_broken_isfinite=no],[ac_cv_have_broken_isfinite=yes],[
339 case "${target}" in
340 hppa*-*-hpux*) ac_cv_have_broken_isfinite=yes ;;
341 *-solaris2.8) ac_cv_have_broken_isfinite=yes ;;
342 *-solaris2.9) ac_cv_have_broken_isfinite=yes ;;
343 *) ac_cv_have_broken_isfinite=no ;;
344 esac])
345 ])
347 dnl the test does not seem to work on solaris 2.8
348 dnl so lets fix this by hand
349 case "${target}" in
350 *-solaris2.8) ac_cv_have_broken_isfinite=yes ;;
351 *-solaris2.9) ac_cv_have_broken_isfinite=yes ;;
352 esac
354 if test "x$ac_cv_have_broken_isfinite" = "xno"; then
355 AC_DEFINE(HAVE_ISFINITE)
356 else
357 AC_CHECK_FUNCS(finite,[],
358 [AC_CHECK_FUNCS(isfinite,[],
359 [AC_MSG_CHECKING(for isfinite with <math.h>)
360 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
361 volatile int x;volatile float f; ]],[[x = isfinite(f)]])],[AC_MSG_RESULT(yes)
362 AC_DEFINE(HAVE_ISFINITE)],[AC_MSG_RESULT(no)])])])
363 fi
365 AC_FULL_IEEE
367 CONFIGURE_PART(Resolve Portability Issues)
369 CHECK_FOR_WORKING_MS_ASYNC
371 dnl do we have nl_langinfo(_NL_TIME_WEEK_1STDAY)
372 AC_CHECK_FUNCS(_NL_TIME_WEEK_1STDAY, ,
373 [AC_MSG_CHECKING([for nl_langinfo(_NL_TIME_WEEK_1STDAY) with langinfo.h])
374 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]], [[nl_langinfo(_NL_TIME_WEEK_1STDAY)]])],[AC_MSG_RESULT(yes)
375 AC_DEFINE(HAVE__NL_TIME_WEEK_1STDAY)],[AC_MSG_RESULT(no)])])
377 dnl Do we need getopt_long
379 dnl even when including our own getopt implementation
380 dnl we may want to make sure we use the external
381 dnl defined by libc to not run into linker resolve trouble
383 AC_CACHE_CHECK([for opterr], rd_cv_var_int_opterr,
384 [AC_TRY_LINK([#include <unistd.h>],
385 [extern int opterr; opterr = 1;],
386 [rd_cv_var_int_opterr=yes],
387 [rd_cv_var_int_opterr=no])])
388 if test x"$rd_cv_var_int_opterr" = x"yes"; then
389 AC_DEFINE(HAVE_INT_OPTERR, 1, [Define to 1 if you have the global variable 'int opterr'.])
390 fi
392 build_getopt=no
393 RRD_GETOPT_LONG="LIBC_HAS_GETOPT_LONG"
394 AC_CHECK_FUNC(getopt_long,[],[
395 RRD_GETOPT_LONG="getopt_long"
396 build_getopt=yes
397 ])
398 AC_SUBST(RRD_GETOPT_LONG)
399 AM_CONDITIONAL(BUILD_GETOPT,[test $build_getopt = yes])
401 dnl what does realloc do if it gets called with a NULL pointer
403 AC_CACHE_CHECK([if realloc can deal with NULL], rd_cv_null_realloc,
404 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
405 int main(void){
406 char *x = NULL;
407 x = realloc (x,10);
408 if (x==NULL) return 1;
409 return 0;
410 }]])],[rd_cv_null_realloc=yes],[rd_cv_null_realloc=nope],[:])])
412 if test x"$rd_cv_null_realloc" = xnope; then
413 AC_DEFINE(NO_NULL_REALLOC)
414 fi
416 AC_LANG_PUSH(C)
417 dnl solaris has some odd defines it needs in order to propperly compile ctime_r
418 AC_MSG_CHECKING([if ctime_r need special care to act posixly correct])
419 AC_LINK_IFELSE(
420 AC_LANG_PROGRAM(
421 [[#include <time.h>]],
422 [[ctime_r(NULL,NULL,0)]]
423 ),
424 [ CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
425 AC_LINK_IFELSE(
426 AC_LANG_PROGRAM(
427 [[#include <time.h>]],
428 [[ctime_r(NULL,NULL)]]
429 ),
430 [AC_MSG_RESULT([yes, this seems to be solaris style])],
431 [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
432 )
433 ],
434 [ AC_LINK_IFELSE(
435 AC_LANG_PROGRAM(
436 [[#include <time.h>]],
437 [[ctime_r(NULL,NULL)]]
438 ),
439 [AC_MSG_RESULT(no)],
440 [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
441 )
442 ]
443 )
444 AC_LANG_POP(C)
446 dnl Check for pthreads
447 dnl http://autoconf-archive.cryp.to/acx_pthread.m4
449 AC_SUBST(MULTITHREAD_CFLAGS)
450 AC_SUBST(MULTITHREAD_LDFLAGS)
452 if test $enable_pthread != no; then
453 ACX_PTHREAD([
454 MULTITHREAD_CFLAGS=$PTHREAD_CFLAGS
455 MULTITHREAD_LDFLAGS=$PTHREAD_LIBS
456 ],
457 [])
458 fi
460 dnl since we use lots of *_r functions all over the code we better
461 dnl make sure they are known
463 if test "x$x_rflag" != "xno"; then
464 CPPFLAGS="$CPPFLAGS $x_rflag"
465 fi
467 AM_CONDITIONAL(BUILD_MULTITHREAD,[test $enable_pthread != no])
469 AC_LANG_PUSH(C)
470 dnl see if we have to include malloc/malloc.h
471 AC_MSG_CHECKING([do we need malloc/malloc.h])
472 AC_LINK_IFELSE(
473 AC_LANG_PROGRAM(
474 [[#include <stdlib.h>]],
475 [[malloc(1)]]
476 ),
477 [ AC_MSG_RESULT([nope, works out of the box]) ],
478 [ AC_LINK_IFELSE(
479 AC_LANG_PROGRAM(
480 [[#include <stdlib.h>
481 #include <malloc/malloc.h>]],
482 [[malloc(1)]]
483 ),[
484 AC_DEFINE([MUST_HAVE_MALLOC_MALLOC_H])
485 AC_MSG_RESULT([yes we do])],
486 [AC_MSG_ERROR([Can not figure how to compile malloc])]
487 )
488 ]
489 )
491 dnl is time_t 32 of 64 bit ?
492 AC_DEFINE([TIME_T_IS_32BIT], [], [time_t is 32bit])
493 AC_DEFINE([TIME_T_IS_64BIT], [], [time_t is 64bit])
494 AC_MSG_CHECKING([the type of time_t])
495 AC_RUN_IFELSE(
496 AC_LANG_PROGRAM(
497 [[#include <time.h>]],
498 [[if (sizeof(time_t) != 4) return 1; ]]
499 ),
500 [ AC_MSG_RESULT([time_t is 32 bit])
501 AC_DEFINE([TIME_T_IS_32BIT])
502 ],
503 [ AC_RUN_IFELSE(
504 AC_LANG_PROGRAM(
505 [[#include <time.h>]],
506 [[if (sizeof(time_t) != 8) return 1; ]]
507 ),
508 [
509 AC_MSG_RESULT([time_t is 64 bit])
510 AC_DEFINE([TIME_T_IS_64BIT])
511 ],
512 [AC_MSG_ERROR([can not figure type of time_t])]
513 )
514 ]
515 )
517 AC_LANG_POP(C)
519 CONFIGURE_PART(Find 3rd-Party Libraries)
521 AC_ARG_ENABLE(libdbi,AS_HELP_STRING([--disable-libdbi],[do not build in support for libdbi]),[have_libdbi=no],[
522 XXX=$LIBS
523 LIBS="$LIBS -ldbi -ldl"
524 AC_MSG_CHECKING(for libdbi)
525 AC_LINK_IFELSE(
526 [AC_LANG_PROGRAM([[#include <dbi/dbi.h>]],
527 [[dbi_initialize(NULL)]]
528 )
529 ],[AC_DEFINE(HAVE_LIBDBI,[1],[have got libdbi installed])
530 AC_MSG_RESULT([yes])
531 have_libdbi=yes
532 ],[LIBS=$XXX
533 AC_MSG_RESULT([no])
534 have_libdbi=no
535 ]
536 )
537 ])
538 AM_CONDITIONAL(BUILD_LIBDBI,[test $have_libdbi != no])
542 CORE_LIBS="$LIBS"
544 dnl EX_CHECK_ALL(z, zlibVersion, zlib.h, zlib, 1.2.3, http://www.gzip.org/zlib/, "")
545 dnl EX_CHECK_ALL(png, png_access_version_number, png.h, libpng, 1.2.10, http://prdownloads.sourceforge.net/libpng/, "")
546 dnl EX_CHECK_ALL(freetype, FT_Init_FreeType, ft2build.h, freetype2, 2.1.10, http://prdownloads.sourceforge.net/freetype/, /usr/include/freetype2)
547 dnl EX_CHECK_ALL(fontconfig, FcInit, fontconfig.h, fontconfig, 2.3.1, http://fontconfig.org/release/, /usr/include)
548 EX_CHECK_ALL(cairo, cairo_font_options_create, cairo.h, cairo-png, 1.4.6, http://cairographics.org/releases/, "")
549 EX_CHECK_ALL(cairo, cairo_svg_surface_create, cairo-svg.h, cairo-svg, 1.4.6, http://cairographics.org/releases/, "")
550 EX_CHECK_ALL(cairo, cairo_pdf_surface_create, cairo-pdf.h, cairo-pdf, 1.4.6, http://cairographics.org/releases/, "")
551 EX_CHECK_ALL(cairo, cairo_ps_surface_create, cairo-ps.h, cairo-ps, 1.4.6, http://cairographics.org/releases/, "")
552 EX_CHECK_ALL(glib-2.0, glib_check_version, glib.h, glib-2.0, 2.12.12, ftp://ftp.gtk.org/pub/glib/2.12/, "")
553 EX_CHECK_ALL(pangocairo-1.0, pango_cairo_context_set_font_options, pango/pango.h, pangocairo, 1.17, http://ftp.gnome.org/pub/GNOME/sources/pango/1.17, "")
554 EX_CHECK_ALL(xml2, xmlParseFile, libxml/parser.h, libxml-2.0, 2.6.31, http://xmlsoft.org/downloads.html, /usr/include/libxml2)
556 if test "$EX_CHECK_ALL_ERR" = "YES"; then
557 AC_MSG_ERROR([Please fix the library issues listed above and try again.])
558 fi
560 ALL_LIBS="$LIBS"
561 LIBS=
563 AC_SUBST(CORE_LIBS)
564 AC_SUBST(ALL_LIBS)
566 CONFIGURE_PART(Prep for Building Language Bindings)
568 dnl Check for Perl and friends
569 PATH=$PATH:/usr/perl5/bin
570 export PATH
571 AC_PATH_PROG(PERL, perl, no)
572 AC_PATH_PROG(POD2MAN, pod2man, no)
573 AC_PATH_PROG(POD2HTML, pod2html, no)
576 AC_ARG_ENABLE(perl,AS_HELP_STRING([--disable-perl],[do not build the perl modules]),
577 [],[enable_perl=yes])
580 AC_ARG_VAR(PERLCC, [C compiler for Perl modules])
581 AC_ARG_VAR(PERLCCFLAGS, [CC flags for Perl modules])
582 AC_ARG_VAR(PERLLD, [Linker for Perl modules])
583 AC_ARG_VAR(PERLLDFLAGS, [LD flags for Perl modules])
585 if test "x$PERL" = "xno" -o x$enable_perl = xno; then
586 COMP_PERL=
587 else
588 COMP_PERL="perl_piped perl_shared"
589 AC_MSG_CHECKING(for the perl version you are running)
590 PERL_VERSION=`$PERL -MConfig -e 'print $Config{version}'`
591 AC_MSG_RESULT($PERL_VERSION)
592 if test -z "$PERLCC"; then
593 AC_MSG_CHECKING(for the C compiler perl wants to use to build its modules)
594 perlcc=`$PERL -MConfig -e 'print $Config{cc}'`
595 AC_MSG_RESULT($perlcc)
596 if test ! -x "$perlcc"; then
597 AC_PATH_PROG(PERL_CC, ${perlcc}, no)
598 if test "$PERL_CC" = "no"; then
599 AC_MSG_WARN([
600 I would not find the Compiler ($perlcc) that was originally used to compile
601 your perl binary. You should either make sure that this compiler is
602 available on your system, pick an other compiler and set PERLCC
603 appropriately, or use a different perl setup that was compiled locally.
605 I will disable the compilation of the RRDs perl module for now.
606 ])
607 COMP_PERL="perl_piped"
608 fi
609 fi
610 fi
611 fi
613 AC_MSG_CHECKING(Perl Modules to build)
614 AC_MSG_RESULT(${COMP_PERL:-No Perl Modules will be built})
616 # Options to pass when configuring perl module
617 langpref=$prefix
618 test "$langpref" = '$(DESTDIR)NONE' && langpref='$(DESTDIR)'$ac_default_prefix
619 test "$langpref" = "NONE" && langpref=$ac_default_prefix
621 PERL_MAKE_OPTIONS="PREFIX=$langpref LIB=$langpref/lib/perl/$PERL_VERSION"
623 dnl pass additional perl options when generating Makefile from Makefile.PL
624 AC_ARG_ENABLE(perl-site-install,
625 AS_HELP_STRING([--enable-perl-site-install],[by default the rrdtool perl modules are installed together with rrdtool in $prefix/lib/perl. You have to put a 'use lib qw($prefix/lib/perl)' into your scripts when you want to use them. When you set this option the perl modules will get installed wherever your perl setup thinks it is best.]),
626 [PERL_MAKE_OPTIONS=],[])
628 if test ! -z "$PERLCC"; then
629 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CC=$PERLCC"
631 if test ! -z "$PERLCCFLAGS"; then
632 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CCFLAGS=$PERLCCFLAGS"
633 fi
635 if test -z "$PERLLD"; then
636 PERLLD=$PERLCC
637 fi
638 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LD=$PERLLD"
640 if test ! -z "$PERLLDFLAGS"; then
641 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LDFLAGS=$PERLLDFLAGS"
642 fi
643 fi
645 AC_ARG_WITH(perl-options,
646 [ --with-perl-options=[OPTIONS] options to pass on command-line when
647 generating Makefile from Makefile.PL. If you set this
648 option, interesting things may happen unless you know
649 what you are doing!],
650 [PERL_MAKE_OPTIONS=$withval])
652 AC_SUBST(PERL_MAKE_OPTIONS)
653 AC_SUBST(PERL)
654 AC_SUBST(COMP_PERL)
655 AC_SUBST(PERL_VERSION)
657 dnl Check for Ruby.
658 AC_PATH_PROG(RUBY, ruby, no)
660 AC_ARG_ENABLE(ruby,AS_HELP_STRING([--disable-ruby],[do not build the ruby modules]),
661 [],[enable_ruby=yes])
663 AC_MSG_CHECKING(if ruby modules can be built)
665 if test "x$RUBY" = "xno" -o x$enable_ruby = xno; then
666 COMP_RUBY=
667 AC_MSG_RESULT(No .. Ruby not found or disabled)
668 else
669 if $RUBY -e 'require "mkmf"' >/dev/null 2>&1; then
670 COMP_RUBY="ruby"
671 AC_MSG_RESULT(YES)
672 else
673 COMP_RUBY=
674 AC_MSG_RESULT(Ruby found but mkmf is missing! Install the -dev package)
675 fi
676 fi
678 dnl pass additional ruby options when generating Makefile from Makefile.PL
679 AC_ARG_ENABLE(ruby-site-install,
680 AS_HELP_STRING([--enable-ruby-site-install],[by default the rrdtool ruby modules are installed together with rrdtool in $prefix/lib/ruby. You have to add $prefix/lib/ruby/$ruby_version/$sitearch to your $: variable for ruby to find the RRD.so file.]),
681 [RUBY_MAKE_OPTIONS=],[RUBY_MAKE_OPTIONS="sitedir=$langpref/lib/ruby"])
684 AC_ARG_WITH(ruby-options,
685 [ --with-ruby-options=[OPTIONS] options to pass on command-line when
686 generating Makefile from extconf.rb. If you set this
687 option, interesting things may happen unless you know
688 what you are doing!],
689 [RUBY_MAKE_OPTIONS=$withval])
691 AC_SUBST(RUBY_MAKE_OPTIONS)
692 AC_SUBST(RUBY)
693 AC_SUBST(COMP_RUBY)
695 dnl Check for Lua.
696 AC_PATH_PROG(LUA, lua, no)
698 AC_ARG_ENABLE(lua,AS_HELP_STRING([--disable-lua],[do not build the lua modules]),
699 [],[enable_lua=yes])
701 COMP_LUA=
702 if test "$LUA" = "no" -o "$enable_lua" = "no"; then
703 enable_lua=no
704 else
705 AC_MSG_CHECKING(for lua >= 5.0)
706 read LUA_MAJOR LUA_MINOR LUA_POINT <<LUA_EOF
707 $($LUA -v 2>&1 | cut -f2 -d' ' | sed -e 's/\./ /g')
708 LUA_EOF
709 if test 0$LUA_MAJOR -lt 5; then
710 AC_MSG_RESULT([no, version found is $LUA_MAJOR.$LUA_MINOR])
711 else
712 AC_MSG_RESULT([$LUA_MAJOR.$LUA_MINOR found])
713 lua_vdot=$LUA_MAJOR.$LUA_MINOR
714 lua_vndot=$LUA_MAJOR$LUA_MINOR
715 lua_version=$LUA_MAJOR.$LUA_MINOR.$LUA_POINT
716 AC_CHECK_HEADERS(lua$lua_vndot/lua.h,
717 [AC_CHECK_HEADERS(lua$lua_vndot/lualib.h,
718 [AC_CHECK_HEADER(lua$lua_vndot/lauxlib.h,
719 [lua_headerdir=lua$lua_vndot],
720 [])],
721 [])],
722 [AC_CHECK_HEADERS(lua$lua_vdot/lua.h,
723 [AC_CHECK_HEADERS(lua$lua_vdot/lualib.h,
724 [AC_CHECK_HEADER(lua$lua_vdot/lauxlib.h,
725 [lua_headerdir=lua$lua_vdot],
726 [])],
727 [])],
728 [AC_CHECK_HEADERS(lua.h,
729 [AC_CHECK_HEADERS(lualib.h,
730 [AC_CHECK_HEADER(lauxlib.h,
731 [lua_headerdir=""],
732 [lua_headerdir="no"])],
733 [])],
734 [])])])
736 if test "$lua_headerdir" = "no"; then
737 enable_lua=no
738 else
739 COMP_LUA=lua
740 fi
742 if test "$COMP_LUA" != "lua"; then
743 enable_lua=no
744 AC_MSG_WARN([Lua $lua_vdot found but not lua.h, lualib.h and lauxlib.h! Please install the -dev packages for Lua $lua_vdot])
745 else
746 # OK, headers found, let's check the libraries (LIBS is not used)
747 LIBS=
748 lua_havelib=no
749 LUA_HAVE_COMPAT51=DONT_HAVE_COMPAT51
750 AC_SEARCH_LIBS(lua_call, lua$lua_vdot lua$lua_vndot lua,
751 [AC_SEARCH_LIBS(luaL_register, lua$lua_vdot lua$lua_vndot lua,
752 [lua_havelib=LUA$lua_vndot],
753 [AC_SEARCH_LIBS(luaL_module, lualib$lua_vndot lualib$lua_vdot lualib,
754 [lua_havelib=$lua_vndot; $LUA -l compat-5.1 2>/dev/null;
755 test "$?" = "0" && LUA_HAVE_COMPAT51=HAVE_COMPAT51],
756 [AC_SEARCH_LIBS(luaL_openlib, lualib$lua_vdot lualib$lua_vndot lualib,
757 [lua_havelib=$lua_vndot],
758 [COMP_LUA=], [-lm])], [-lm])], [-lm])],
759 [COMP_LUA=], [-lm])
760 lua_libs=$LIBS
761 LIBS=
763 # Options to pass when configuring Lua module
764 if test "$lua_havelib" != "no"; then
765 # OK, headers and libs found. Try to set lua flags
766 # and modules installation dirs with pkg-config
767 if test "$PKGCONFIG" != "no"; then
768 if test "$lua_vndot" = "50"; then
769 lua_pkg_prefix=lualib
770 else
771 lua_pkg_prefix=lua
772 fi
773 # try with dot, without dot and finally without version
774 for f in $lua_pkg_prefix$lua_vdot $lua_pkg_prefix$lua_vndot $lua_pkg_prefix; do
775 lua_exec_prefix=`$PKGCONFIG --variable=prefix $f 2>/dev/null`
776 # same binaries?
777 if test "$lua_exec_prefix/bin/lua" = "$LUA"; then
778 # OK, found CFLAGS. Get Lua LFLAGS and modules install dir
779 LUA_CFLAGS=`$PKGCONFIG --cflags $f 2>/dev/null`
780 LUA_LFLAGS=`$PKGCONFIG --libs $f 2>/dev/null`
781 LUA_INSTALL_CMOD=`$PKGCONFIG --variable=INSTALL_CMOD $f 2>/dev/null`
782 LUA_INSTALL_LMOD=`$PKGCONFIG --variable=INSTALL_LMOD $f 2>/dev/null`
783 break
784 fi
785 done
786 fi
788 LUA_RRD_LIBDIR="$langpref/lib/lua/$lua_vdot"
789 # if lua 5.0 can't find compat-5.1, force installation of
790 # compat-5.1.lua together with RRDtool.
791 if test "$lua_vdot" = "5.0" -a "$LUA_HAVE_COMPAT51" != "HAVE_COMPAT51"; then
792 lua_need_compat51=1
793 LUA_INSTALL_LMOD="$LUA_RRD_LIBDIR"
794 fi
796 # if not set with pkg-config, use default values in src packages compat-5.1, lua 5.1
797 if test "$LUA_CFLAGS" = ""; then
798 AC_MSG_WARN(Setting Lua include and lib flags to defaults in compat-5.1 and lua 5.1 sources)
799 LUA_CFLAGS="-I/usr/local/include -I/usr/local/include/lua -I/usr/local/include/lua/$lua_vdot"
800 LUA_LFLAGS="-L/usr/local/lib -L/usr/local/lib/lua -L/usr/local/lib/lua/$lua_vdot $lua_libs"
801 LUA_INSTALL_CMOD="/usr/local/lib/lua/$lua_vdot"
802 fi
804 dnl pass additional lua options
805 dnl if lua-site-install is not set, overwrite LUA_INSTALL_CMOD already
806 dnl found and install together with RRDtool, under $langpref.
807 AC_ARG_ENABLE(lua-site-install,
808 AS_HELP_STRING([--enable-lua-site-install],[by default the lua module is installed together with rrdtool in $prefix/lib/lua/$lua_version. You have to add $prefix/lib/lua/$lua_version/?.so to package.cpath for lua to find 'rrd.so'. For lua 5.0 you may also need to change LUA_PATH to the same dir, to require 'compat-5.1'. When you set this option the lua modules will get installed wherever your Lua setup thinks it is best. WARNING: if you set this option, system lua modules compat-5.1.lua and rrd.so, if any, may be overwritten.]),
809 [],
810 [LUA_INSTALL_CMOD="$LUA_RRD_LIBDIR"; LUA_INSTALL_LMOD="$LUA_RRD_LIBDIR"])
812 LUA_DEFINES="-DLUA$lua_vndot -D$LUA_HAVE_COMPAT51"
813 AC_SUBST(LUA)
814 AC_SUBST(COMP_LUA)
815 AC_SUBST(LUA_INSTALL_CMOD)
816 AC_SUBST(LUA_INSTALL_LMOD)
817 AC_SUBST(LUA_CFLAGS)
818 AC_SUBST(LUA_LFLAGS)
819 AC_SUBST(LUA_DEFINES)
820 else
821 enable_lua=no
822 AC_MSG_RESULT([Lua headers found but not the libraries! Please reinstall the dev packages for Lua $LUA_MAJOR.$LUA_MINOR])
823 fi
824 fi
825 fi
826 fi
827 dnl If Lua 5.0, we need compat-5.1. Add ours unless already
828 dnl integrated as in Debian/Ubuntu 5.0 -dev packages.
829 AM_CONDITIONAL(LUA_NEED_OUR_COMPAT51,
830 [test "$lua_vdot" = "5.0" -a "$LUA_HAVE_COMPAT51" != "HAVE_COMPAT51"])
831 AM_CONDITIONAL(LUA_SITE_CINSTALL, [test "$LUA_INSTALL_CMOD" != "$LUA_RRD_LIBDIR"])
832 AM_CONDITIONAL(LUA_SITE_LINSTALL, [test "$LUA_INSTALL_LMOD" != "$LUA_RRD_LIBDIR"])
833 AM_CONDITIONAL(LUA50, [test "$lua_vndot" = "50"])
834 AM_CONDITIONAL(BUILD_LUA, [test "$enable_lua" = "yes"])
836 enable_tcl_site=no
838 AC_ARG_ENABLE(tcl,AS_HELP_STRING([--disable-tcl],[do not build the tcl modules]),
839 [],[enable_tcl=yes])
841 if test "$enable_tcl" = "yes"; then
842 dnl Check for Tcl.
843 withval=""
844 AC_ARG_WITH(tcllib,[ --with-tcllib=DIR location of the tclConfig.sh])
845 enable_tcl=no
846 for dir in $withval /usr/lib /usr/local/lib /usr/lib/tcl8.4 /usr/lib/tcl8.3 ; do
847 AC_MSG_CHECKING(for tclConfig.sh in $dir)
848 if test -f "$dir/tclConfig.sh" ; then
849 tcl_config=$dir/tclConfig.sh
850 enable_tcl=yes
851 AC_MSG_RESULT(yes)
852 break
853 else
854 AC_MSG_RESULT(no)
855 fi
856 done
858 if test "$enable_tcl" = "no"; then
859 AC_MSG_WARN([tclConfig.sh not found - Tcl interface will not be built])
860 else
861 . $tcl_config
862 TCL_PACKAGE_DIR="$TCL_PACKAGE_PATH/tclrrd$VERSION"
863 if test -n "$TCL_INC_DIR"; then
864 TCL_INCLUDE_SPEC="$TCL_INCLUDE_SPEC -I$TCL_INC_DIR"
865 fi
866 fi
867 AC_ARG_ENABLE(tcl,AS_HELP_STRING([--enable-tcl-site],[install the tcl extension in the tcl tree]),
868 [],[enable_tcl_site=yes])
870 fi
872 AM_CONDITIONAL(BUILD_TCL, test "$enable_tcl" = "yes" )
873 AM_CONDITIONAL(BUILD_TCL_SITE, test "$enable_tcl_site" = "yes" )
876 AC_SUBST(TCL_PREFIX)
877 AC_SUBST(TCL_SHLIB_CFLAGS)
878 AC_SUBST(TCL_SHLIB_LD)
879 AC_SUBST(TCL_SHLIB_SUFFIX)
880 AC_SUBST(TCL_PACKAGE_PATH)
881 AC_SUBST(TCL_LD_SEARCH_FLAGS)
882 AC_SUBST(TCL_STUB_LIB_SPEC)
883 AC_SUBST(TCL_VERSION)
884 AC_SUBST(TCL_PACKAGE_DIR)
885 AC_SUBST(TCL_INCLUDE_SPEC)
887 AC_ARG_ENABLE(python,AS_HELP_STRING([--disable-python],[do not build the python modules]),
888 [],[enable_python=yes])
890 if test "$enable_python" = "yes"; then
891 dnl Check for python
892 AM_PATH_PYTHON(2.3,[],[enable_python=no])
893 AM_CHECK_PYTHON_HEADERS(,[enable_python=no;AC_MSG_WARN(could not find Python headers)])
894 fi
896 if test x$enable_python = xno; then
897 COMP_PYTHON=
898 else
899 COMP_PYTHON="python"
900 fi
902 AC_SUBST(COMP_PYTHON)
904 dnl Check for nroff
905 AC_PATH_PROGS(NROFF, gnroff nroff)
906 AC_PATH_PROGS(TROFF, groff troff)
908 AC_ARG_VAR(RRDDOCDIR, [[DATADIR/doc/PACKAGE-VERSION] Documentation directory])
909 if test -z "$RRDDOCDIR"; then
910 RRDDOCDIR='${datadir}/doc/${PACKAGE}-${VERSION}'; fi
913 CONFIGURE_PART(Apply Configuration Information)
915 AC_CONFIG_FILES([examples/shared-demo.pl])
916 AC_CONFIG_FILES([examples/piped-demo.pl])
917 AC_CONFIG_FILES([examples/stripes.pl])
918 AC_CONFIG_FILES([examples/bigtops.pl])
919 AC_CONFIG_FILES([examples/minmax.pl])
920 AC_CONFIG_FILES([examples/4charts.pl])
921 AC_CONFIG_FILES([examples/perftest.pl])
922 AC_CONFIG_FILES([examples/Makefile])
923 AC_CONFIG_FILES([examples/rrdcached/Makefile])
924 AC_CONFIG_FILES([doc/Makefile])
925 AC_CONFIG_FILES([po/Makefile.in])
926 AC_CONFIG_FILES([src/Makefile])
927 AC_CONFIG_FILES([src/librrd.sym.in])
928 AC_CONFIG_FILES([src/librrd.pc])
929 AC_CONFIG_FILES([bindings/Makefile])
930 AC_CONFIG_FILES([bindings/tcl/Makefile])
931 AC_CONFIG_FILES([bindings/tcl/ifOctets.tcl])
932 AC_CONFIG_FILES([Makefile])
933 AC_CONFIG_FILES([bindings/lua/Makefile])
935 AC_CONFIG_COMMANDS([default],[[ chmod +x examples/*.pl]],[[]])
937 dnl intl requires our config to be called config.h. indulge it.
938 AC_CONFIG_COMMANDS_POST([ test -f config.h || ln -s rrd_config.h config.h ])
940 AC_OUTPUT
942 AC_MSG_CHECKING(in)
943 AC_MSG_RESULT(and out again)
945 echo $ECHO_N "ordering CD from http://tobi.oetiker.ch/wish $ECHO_C" 1>&6
946 sleep 1
947 echo $ECHO_N ".$ECHO_C" 1>&6
948 sleep 1
949 echo $ECHO_N ".$ECHO_C" 1>&6
950 sleep 1
951 echo $ECHO_N ".$ECHO_C" 1>&6
952 sleep 1
953 echo $ECHO_N ".$ECHO_C" 1>&6
954 sleep 1
955 AC_MSG_RESULT([ just kidding ;-)])
956 echo
957 echo "----------------------------------------------------------------"
958 echo "Config is DONE!"
959 echo
960 echo " With MMAP IO: $enable_mmap"
961 echo " Build rrd_getopt: $build_getopt"
962 echo " Static programs: $staticprogs"
963 echo " Perl Modules: $COMP_PERL"
964 echo " Perl Binary: $PERL"
965 echo " Perl Version: $PERL_VERSION"
966 echo " Perl Options: $PERL_MAKE_OPTIONS"
967 echo " Ruby Modules: $COMP_RUBY"
968 echo " Ruby Binary: $RUBY"
969 echo " Ruby Options: $RUBY_MAKE_OPTIONS"
970 echo " Build Lua Bindings: $enable_lua"
971 if test "$enable_lua" = "yes"; then
972 echo " Lua Binary: $LUA"
973 echo " Lua Version: $lua_version"
974 echo " Lua C-modules dir: $LUA_INSTALL_CMOD"
975 if test "$lua_need_compat51" = "1"; then
976 echo " Lua Lua-modules dir: $LUA_INSTALL_LMOD"
977 fi
978 fi
979 echo " Build Tcl Bindings: $enable_tcl"
980 echo " Build Python Bindings: $enable_python"
981 echo " Build rrdcgi: $enable_rrdcgi"
982 echo " Build librrd MT: $enable_pthread"
983 echo " Use gettext: $USE_NLS"
984 echo " With libDBI: $have_libdbi"
985 echo " With libwrap: $have_libwrap"
986 echo
987 echo " Libraries: $ALL_LIBS"
988 echo
989 echo "Type 'make' to compile the software and use 'make install' to "
990 echo "install everything to: $prefix."
991 echo
992 echo " ... that wishlist is NO JOKE. If you find RRDtool useful"
993 echo "make me happy. Go to http://tobi.oetiker.ch/wish and"
994 echo "place an order."
995 echo
996 echo " -- Tobi Oetiker <tobi@oetiker.ch>"
997 echo "----------------------------------------------------------------"