1 dnl
2 dnl $Id$
3 dnl
5 AC_INIT
6 AC_CONFIG_SRCDIR([src/main.c])
7 AM_INIT_AUTOMAKE([ncmpc], [0.11.2-svn])
8 AM_CONFIG_HEADER([config.h])
10 dnl Check for programs
11 AC_PROG_CC
12 AC_PROG_INSTALL
13 dnl AC_PROG_LIBTOOL
14 AC_PROG_LIBTOOL
16 dnl =======================================================
17 dnl initialize variables
18 dnl =======================================================
20 dnl i18n
21 ALL_LINGUAS="es da de fr gl no ru sv"
23 set -- $CFLAGS
25 dnl
26 dnl Check for types
27 dnl
29 AC_SOCKLEN_T
32 dnl
33 dnl Check for headers
34 dnl
36 AC_CHECK_HEADER([libgen.h],
37 AC_DEFINE([HAVE_LIBGEN_H], [1], [glibc - libgen.h]),
38 ,)
40 AC_CHECK_HEADER([locale.h],
41 AC_DEFINE([HAVE_LOCALE_H], [1], [locale.h]),
42 ,)
45 dnl
46 dnl Check for functions
47 dnl
48 AC_CHECK_FUNCS([basename strcasestr])
51 dnl
52 dnl Check for libraries
53 dnl
55 dnl Try to find the socket functions
56 AC_CHECK_FUNC([socket],
57 [],
58 [AC_CHECK_LIB([socket],[socket],[LIBS="$LIBS -lsocket"],
59 [AC_MSG_ERROR(No UNIX socket API found)])
60 ])
62 dnl Try to find the gethostbyname functions
63 AC_CHECK_FUNC([gethostbyname],
64 [],
65 [AC_CHECK_LIB([nsl],[gethostbyname],[LIBS="$LIBS -lnsl"],
66 [AC_MSG_ERROR(No UNIX gethostbyname API found)])
67 ])
70 dnl ncurses
71 ncurses=auto
72 AC_ARG_WITH([ncurses],
73 AC_HELP_STRING([--with-ncurses], [compile/link with ncurses library] ),
74 [ncurses=ncurses])
75 AC_ARG_WITH(ncursesw,
76 AC_HELP_STRING([--with-ncursesw], [compile/link with wide-char ncurses library @<:@default@:>@]),
77 [ncurses=ncursesw])
79 if test "x$ncurses" = "xauto"; then
80 AC_CHECK_LIB([ncursesw],
81 [initscr],
82 [ncurses=ncursesw],
83 [ncurses=ncurses])
84 fi
86 AC_CHECK_HEADER([ncursesw/ncurses.h],
87 [have_ncursesw_h=yes],
88 ,)
93 AC_CHECK_LIB([$ncurses],
94 [initscr],
95 [LIBS="$LIBS -l$ncurses"],
96 [AC_MSG_ERROR($ncurses library is required)])
99 if test "x$ncurses" != "xncursesw" ; then
100 if test "x$have_ncursesw_h" = "xyes" ; then
101 AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, [wide-char wget_ch()])
102 AC_DEFINE(USE_NCURSESW, 1, [use wide-char ncurses library])
103 fi
104 fi
108 dnl Check for glib-2.4
109 PKG_CHECK_MODULES([GLIB],
110 [glib-2.0 >= 2.4],
111 [glib24=yes],
112 [AC_MSG_WARN([glib-2.4 is required for NLS support!])])
113 if test "x$glib24" != "xyes"; then
114 PKG_CHECK_MODULES([GLIB],
115 [glib-2.0 >= 2.2],
116 [nls=no],
117 [AC_MSG_ERROR([glib-2.2 is required])])
118 fi
121 dnl i18n
122 AM_NLS
123 if test "x$glib24" = "xyes"; then
124 nls=$USE_NLS
125 else
126 USE_NLS=no
127 AC_SUBST(USE_NLS)
128 fi
130 if test "x$nls" = "xyes"; then
131 AM_GLIB_GNU_GETTEXT
132 GETTEXT_PACKAGE=$PACKAGE
133 AC_SUBST(GETTEXT_PACKAGE)
134 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],
135 ["${GETTEXT_PACKAGE}"],
136 [gettext domain])
137 nls=$gt_cv_have_gettext
138 if test "x$nls" != "xyes"; then
139 AC_MSG_WARN([NLS support disabled!])
140 fi
141 else
142 AM_PO_SUBDIRS
143 fi
145 dnl check for gthreads
146 PKG_CHECK_MODULES([GTHREAD],
147 [gthread-2.0],
148 [gthread=yes],
149 [AC_MSG_WARN([gthread-2.0 >= 0.20 is required the lyrics screen])])
150 AC_SUBST(GTHREAD_LIBS)
151 AC_SUBST(GTHREAD_CFLAGS)
153 dnl check for gmodule
154 PKG_CHECK_MODULES([GMODULE],
155 [gmodule-2.0],
156 [gmodule=yes],
157 [AC_MSG_WARN([gmodule-2.0 >= 0.20 is required the plugin system])])
158 AC_SUBST(GMODULE_LIBS)
159 AC_SUBST(GMODULE_CFLAGS)
161 dnl check for libcurl
162 PKG_CHECK_MODULES([libcurl],
163 [libcurl],
164 [libcurl=yes],
165 #[libcurl=yes,LIBS="$LIBS -lcurl"], #doesn't work for me on arch
166 [AC_MSG_WARN([libcurl is required for the lyrics screen])])
168 if test "x$libcurl" = "xyes"; then
169 LIBS="$LIBS -lcurl"
170 fi
172 dnl check for expat
173 expat=expat
174 AC_CHECK_LIB([$expat],
175 [XML_ParserCreate],
176 [have_expat=yes],
177 [AC_MSG_WARN($expat library is required for lyrics screen)])
178 if test "x$have_expat" = "xyes"; then
179 LIBS="$LIBS -l$expat"
180 fi
182 #if test "x$gthread-2.0" != "xyes"; then
183 # PKG_CHECK_MODULES([GTHREAD],
184 # [glib-2.0 >= 2.2],
185 # [nls=no],
186 # [AC_MSG_ERROR([glib-2.2 is required])])
187 #fi
189 dnl disbale raw mode
190 AC_MSG_CHECKING([Place the terminal into raw mode])
191 AC_ARG_ENABLE([raw-mode],
192 AC_HELP_STRING([--disable-raw-mode],
193 [Disable raw terminal mode]),
194 [use_raw=$enableval],
195 [use_raw=yes])
196 AC_MSG_RESULT([$use_raw])
197 if test "x$use_raw" = "xyes" ; then
198 AC_DEFINE([ENABLE_RAW_MODE], [1], [Place the terminal into raw mode])
199 fi
201 dnl Debugging
202 AC_MSG_CHECKING([whether to build with debug support])
203 AC_ARG_ENABLE([debug],
204 AC_HELP_STRING([--enable-debug],
205 [Enable debugging @<:@default=no@:>@]),
206 [enable_debug="$enableval"],
207 [enable_debug=no])
208 AC_MSG_RESULT([$enable_debug])
209 if test "x$enable_debug" = "xyes" ; then
210 CFLAGS="$CFLAGS -Wall -g -DDEBUG"
211 fi
213 dnl Optional screen - help screen
214 #AC_MSG_CHECKING([whether to include the help screen])
215 #AC_ARG_ENABLE([help-screen],
216 # AC_HELP_STRING([--enable-help-screen],
217 # [Enable the help screen @<:@default=yes@:>@]),
218 # [help_screen="$enableval"],
219 # [help_screen=yes])
220 #AC_MSG_RESULT([$help_screen])
221 #if test "x$help_screen" = "xyes" ; then
222 # AC_DEFINE(ENABLE_HELP_SCREEN, 1, [Enable the help screen])
223 #fi
225 dnl Optional screen - browse screen
226 #AC_MSG_CHECKING([whether to include the browse screen])r
227 #AC_ARG_ENABLE([browse-screen],
228 # AC_HELP_STRING([--enable-browse-screen],
229 # [Enable the browse screen @<:@default=yes@:>@]),
230 # [browse_screen="$enableval"],
231 # [browse_screen=yes])
232 #AC_MSG_RESULT([$browse_screen])
233 #if test "x$browse_screen" = "xyes" ; then
234 # AC_DEFINE(ENABLE_BROWSE_SCREEN, 1, [Enable the browse screen])
235 #fi
237 dnl Optional - curses getmouse support
238 AC_MSG_CHECKING([whether to include mouse support])
239 AC_ARG_ENABLE([mouse],
240 AC_HELP_STRING([--enable-mouse],
241 [Enable curses getmouse support @<:@default=yes@:>@]),
242 [getmouse="$enableval"],
243 [getmouse=yes])
244 AC_MSG_RESULT([$getmouse])
245 if test "x$getmouse" = "xyes" ; then
246 AC_CHECK_LIB([$ncurses],
247 [getmouse],
248 [AC_DEFINE([HAVE_GETMOUSE], [1], [$ncurses - getmouse()])],
249 [])
250 fi
252 dnl Plugin loading for lyrics sources
253 AC_MSG_CHECKING([whether to include the plugin infrastructure])
254 AC_ARG_ENABLE([plugin-support],
255 AC_HELP_STRING([--enable-plugin-support],
256 [Enable loading lyrics plugins @<:@default=yes@:>@]),
257 [plugin_support="$enableval"],
258 [plugin_support=yes])
259 if test "x$plugin_support" != "xyes" ; then
260 AC_DEFINE(DISABLE_PLUGIN_SYSTEM, 1, [Disable plugin system])
261 fi
263 if test "x$gmodule" != "xyes" ; then
264 AC_DEFINE(DISABLE_PLUGIN_SYSTEM, 1, [Disable plugin system])
265 plugin_support=no
266 fi
267 AC_MSG_RESULT([$plugin_support])
269 dnl Optional screen - artist
270 AC_MSG_CHECKING([whether to include the artist screen])
271 AC_ARG_ENABLE([artist-screen],
272 AC_HELP_STRING([--enable-artist-screen],
273 [Enable artist screen (EXPERIMENTAL) @<:@default=no@:>@]),
274 [artist_screen="$enableval"],
275 [artist_screen=no])
276 AC_MSG_RESULT([$artist_screen])
277 if test "x$artist_screen" != "xyes" ; then
278 AC_DEFINE(DISABLE_ARTIST_SCREEN, 1, [Disable artist screen])
279 fi
281 dnl Optional screen - search
282 AC_MSG_CHECKING([whether to include the search screen])
283 AC_ARG_ENABLE([search-screen],
284 AC_HELP_STRING([--enable-search-screen],
285 [Enable search screen (EXPERIMENTAL) @<:@default=yes@:>@]),
286 [search_screen="$enableval"],
287 [search_screen=yes])
288 AC_MSG_RESULT([$search_screen])
289 if test "x$search_screen" != "xyes" ; then
290 AC_DEFINE(DISABLE_SEARCH_SCREEN, 1, [Disable search screen])
291 fi
293 dnl Optional screen - key editor
294 AC_MSG_CHECKING([whether to include the key editor screen])
295 AC_ARG_ENABLE([key-screen],
296 AC_HELP_STRING([--enable-key-screen],
297 [Enable key editor screen @<:@default=yes@:>@]),
298 [keydef_screen="$enableval"],
299 [keydef_screen=yes])
300 AC_MSG_RESULT([$keydef_screen])
301 if test "x$keydef_screen" != "xyes" ; then
302 AC_DEFINE(DISABLE_KEYDEF_SCREEN, 1, [Disable key editor screen])
303 fi
305 dnl Optional screen - clock
306 AC_MSG_CHECKING([whether to include the clock screen])
307 AC_ARG_ENABLE([clock-screen],
308 AC_HELP_STRING([--enable-clock-screen],
309 [Enable clock screen @<:@default=yes@:>@]),
310 [clock_screen="$enableval"],
311 [clock_screen=yes])
312 AC_MSG_RESULT([$clock_screen])
313 if test "x$clock_screen" != "xyes" ; then
314 AC_DEFINE(DISABLE_CLOCK_SCREEN, 1, [Disable clock screen])
315 fi
317 dnl Optional screen - lyrics
318 AC_MSG_CHECKING([whether to include the lyrics screen])
319 AC_ARG_ENABLE([lyrics-screen],
320 AC_HELP_STRING([--enable-lyrics-screen],
321 [Enable lyrics screen @<:@default=no@:>@]),
322 [lyrics_screen="$enableval"],
323 [lyrics_screen=yes])
324 if test "x$lyrics_screen" != "xyes" ; then
325 AC_DEFINE(DISABLE_LYRICS_SCREEN, 1, [Disable lyrics screen])
326 lyrics_screen=no
327 fi
328 #lyrics_screen=yes
329 #if test "x$libcurl" != "xyes" ; then
330 # AC_MSG_RESULT([$lyrics_screen])
331 # AC_DEFINE(DISABLE_LYRICS_SCREEN, 1, [Disable lyrics screen])
332 # lyrics_screen=no
333 #fi
334 if test "x$gthread" != "xyes" ; then
335 AC_DEFINE(DISABLE_LYRICS_SCREEN, 1, [Disable lyrics screen])
336 lyrics_screen=no
337 fi
338 #if test "x$have_expat" != "xyes" ; then
339 # AC_DEFINE(DISABLE_LYRICS_SCREEN, 1, [Disable lyrics screen])
340 # lyrics_screen=no
341 #fi
343 AC_MSG_RESULT([$lyrics_screen])
345 dnl hd
346 AC_MSG_CHECKING([whether to build with .lyrics support])
347 AC_ARG_WITH([lyrics-hd],
348 AC_HELP_STRING([[--with-lyrics-leoslyrics[=plugin/fixed/no]]],
349 [enable leoslyrics lyrics source @<:@default=plugin@:>@]),
350 [hd=$withval],
351 [hd=plugin])
353 if test "x$plugin_support" != "xyes" ; then
354 if test "x$hd" == "xplugin" ; then
355 hd=fixed
356 AC_MSG_NOTICE([Enable lyrics plugin support to compile as a plugin!])
357 fi
358 fi
359 AC_MSG_RESULT([$hd])
360 if test "x$hd" == "xfixed"; then
361 AC_DEFINE_UNQUOTED([ENABLE_LYRSRC_HD], 1,
362 [~/.lyrics inclusion])
363 fi
364 if test "x$hd" == "xplugin" ; then
365 src_lyr_plugins="${src_lyr_plugins}hd "
366 fi
367 AM_CONDITIONAL(HD_FIXED, test x$hd = xfixed)
369 dnl leoslyrics
370 AC_MSG_CHECKING([whether to build with leoslyrics])
371 AC_ARG_WITH([lyrics-leoslyrics],
372 AC_HELP_STRING([[--with-lyrics-leoslyrics[=plugin/fixed/no]]],
373 [enable leoslyrics lyrics source @<:@default=plugin@:>@]),
374 [leoslyrics=$withval],
375 [leoslyrics=plugin])
377 if test "x$plugin_support" != "xyes" ; then
378 if test "x$leoslyrics" == "xplugin" ; then
379 leoslyrics=fixed
380 AC_MSG_NOTICE([Enable lyrics plugin support to compile as a plugin!])
381 fi
382 fi
384 if test "x$have_expat" != "xyes" ; then
385 leoslyrics=no
386 fi
387 if test "x$libcurl" != "xyes" ; then
388 leoslyrics=no
389 fi
391 if test "x$leoslyrics" == "xplugin" ; then
392 src_lyr_plugins="${src_lyr_plugins}leoslyrics "
393 fi
394 AC_MSG_RESULT([$leoslyrics])
396 if test "x$leoslyrics" == "xfixed" ; then
397 AC_DEFINE_UNQUOTED([ENABLE_LYRSRC_LEOSLYRICS], 1,
398 [Leoslyrics inclusion])
399 fi
401 #if test "x$leoslyrics" == "xfixed" ; then
402 # src_lyr_fixed="${src_lyr_fixed}../plugins/leoslyrics/lyrics_leoslyrics.c "
403 # leoslyrics_fixed=yes
404 #fi
405 AM_CONDITIONAL(LEOSLYRICS_FIXED, test x$leoslyrics = xfixed)
407 dnl plugins directory
408 AC_ARG_WITH([plugin-dir],
409 AC_HELP_STRING([[--with-plugin-dir[=DIRECTORY]]],
410 [Directory where plugins are stored @<:@default=/usr/share/ncmpc/modules@:>@]),
411 [plugindir=$withval],
412 [plugindir="/usr/share/ncmpc/modules"])
413 AC_DEFINE_UNQUOTED([PLUGIN_DIR_SYSTEM], ["$plugindir"],
414 [Directory to search for plugins])
416 AC_SUBST(plugindir)
417 dnl Default host
418 AC_MSG_CHECKING([for default MPD host])
419 AC_ARG_WITH([default-host],
420 AC_HELP_STRING([--with-default-host=ARG],
421 [Default MPD host @<:@localhost@:>@]),
422 [DEFAULT_HOST="$withval"],
423 [DEFAULT_HOST="localhost"])
424 AC_MSG_RESULT([$DEFAULT_HOST])
425 AC_DEFINE_UNQUOTED([DEFAULT_HOST], ["$DEFAULT_HOST"], [Default MPD host])
427 dnl Default port
428 AC_MSG_CHECKING([for default MPD port])
429 AC_ARG_WITH([default-port],
430 AC_HELP_STRING([--with-default-port=ARG],
431 [Default port @<:@6600@:>@]),
432 [DEFAULT_PORT="$withval"],
433 [DEFAULT_PORT="6600"])
434 AC_MSG_RESULT([$DEFAULT_PORT])
435 AC_DEFINE_UNQUOTED([DEFAULT_PORT], [$DEFAULT_PORT], [Default MPD port])
436 AC_DEFINE_UNQUOTED([DEFAULT_PORT_STR], ["$DEFAULT_PORT"], [Default MPD port])
438 dnl Default timedisplay type
439 AC_MSG_CHECKING([for default timedisplay type])
440 AC_ARG_WITH([default-timedisplay_type],
441 AC_HELP_STRING([--with-default-timedisplay_type=ARG],
442 [default_timedisplay]),
443 [DEFAULT_TIMEDISPLAY_TYPE="$withval"],
444 [DEFAULT_TIMEDISPLAY_TYPE="elapsed"])
445 AC_MSG_RESULT([$DEFAULT_TIMEDISPLAY_TYPE])
446 AC_DEFINE_UNQUOTED([DEFAULT_TIMEDISPLAY_TYPE], ["$DEFAULT_TIMEDISPLAY_TYPE"], [Default way to display time, either 'elapsed' or 'remaining'])
447 AC_SUBST(src_lyr_plugins)
448 AC_SUBST(src_lyr_fixed)
449 AC_CONFIG_FILES([Makefile src/Makefile plugins/Makefile doc/Makefile po/Makefile
450 plugins/hd/Makefile
451 plugins/leoslyrics/Makefile])
452 AC_OUTPUT