1 dnl RRDtool AutoConf script ...
2 dnl ---------------------------
3 dnl
4 dnl Created by Jeff Allen, Tobi Oetiker, Blair Zajac
5 dnl
6 dnl Inspiration from http://autoconf-archive.cryp.to
8 dnl tell automake the this script is for rrdtool
10 dnl the official version number is
11 dnl a.b.c
12 AC_INIT([rrdtool],[1.3.2])
14 dnl for testing a numberical version number comes handy
15 dnl the released version are
16 dnl a.bccc
17 dnl the devel versions will be something like
18 dnl a.b999yymmddhh
19 NUMVERS=1.3002
20 AC_SUBST(NUMVERS)
22 dnl for the linker to understand which versions the library are compatible with
23 dnl each other we must keep a separate library version cout of the format c:r:a.
24 dnl - if only implementation changed but all interfaces are kept, do r++
25 dnl - if only functionality was added do c++,r=0,a++
26 dnl - if any functionality was removed do c++,r=0,a=0.
27 dnl
28 dnl see http://sourceware.org/autobook/autobook/autobook_91.html
29 dnl
30 LIBVERS=4:1:0
31 AC_SUBST(LIBVERS)
33 AC_CANONICAL_TARGET
34 AM_INIT_AUTOMAKE
35 AM_MAINTAINER_MODE
37 AC_CONFIG_HEADERS([rrd_config.h])
39 dnl all our local stuff like install scripts and include files
40 dnl is in there
43 dnl determine the type of system we are running on
45 AC_SUBST(VERSION)
47 AC_PREFIX_DEFAULT( /usr/local/rrdtool-$PACKAGE_VERSION )
49 dnl Minimum Autoconf version required.
50 AC_PREREQ(2.59)
52 dnl At the TOP of the HEADER
54 AH_TOP([
55 #ifndef RRD_CONFIG_H
56 #define RRD_CONFIG_H
58 /* IEEE can be prevented from raising signals with fpsetmask(0) */
59 #undef MUST_DISABLE_FPMASK
61 /* IEEE math only works if SIGFPE gets actively set to IGNORE */
62 #undef MUST_DISABLE_SIGFPE
64 /* realloc does not support NULL as argument */
65 #undef NO_NULL_REALLOC
67 /* lets enable madvise defines in NetBSD */
68 #if defined(__NetBSD__)
69 # if !defined(_NETBSD_SOURCE)
70 # define _NETBSD_SOURCE
71 # endif
72 #endif
74 ])
76 AH_BOTTOM([
78 #ifdef MUST_HAVE_MALLOC_MALLOC_H
79 # include <malloc/malloc.h>
80 #endif
82 #include <rrd_config_bottom.h>
84 #endif
85 ])
87 dnl Process Special Options
88 dnl -----------------------------------
90 dnl How the vertical axis label is printed
91 AC_ARG_VAR(RRDGRAPH_YLEGEND_ANGLE,
92 [Vertical label angle: -90.0 (default) or 90.0])
93 AC_DEFINE_UNQUOTED(RRDGRAPH_YLEGEND_ANGLE,${RRDGRAPH_YLEGEND_ANGLE:-90.0},
94 [Vertical label angle: -90.0 (default) or 90.0])
96 AC_ARG_ENABLE(rrdcgi,AS_HELP_STRING([--disable-rrdcgi],[disable building of rrdcgi]),
97 [],[enable_rrdcgi=yes])
99 dnl Check if we run on a system that has fonts
100 AC_ARG_WITH(rrd-default-font,
101 [ --with-rrd-default-font=[OPTIONS] set the full path to your default font.],
102 [RRD_DEFAULT_FONT=$withval],[
103 if test -d ${WINDIR:-nodir}/cour.ttf ; then
104 RRD_DEFAULT_FONT=`cd $WINDIR;pwd`/cour.ttf
105 else
106 RRD_DEFAULT_FONT='"DejaVu Sans Mono,Bitstream Vera Sans Mono,monospace,Courier"'
107 fi
108 ])
110 dnl Use mmap in rrd_update instead of seek+write
111 AC_ARG_ENABLE([mmap],
112 AS_HELP_STRING([--disable-mmap],[disable mmap in rrd_update, use seek+write instead]),
113 [],
114 [enable_mmap=yes])
116 AC_ARG_ENABLE(pthread,AS_HELP_STRING([--disable-pthread],[disable multithread support]),
117 [],[enable_pthread=yes])
119 AC_ARG_ENABLE(static-programs,
120 AS_HELP_STRING([--enable-static-programs],[Build static programs]),
121 [case "${enableval}" in
122 yes) staticprogs=yes ;;
123 no) staticprogs=no ;;
124 *) AC_MSG_ERROR(bad value ${enableval} for --enable-static-programs) ;;
125 esac],[staticprogs=no])
126 AM_CONDITIONAL(STATIC_PROGRAMS,[test "x$staticprogs" = "xyes"])
129 CONFIGURE_PART(Audit Compilation Environment)
132 dnl Check for the compiler and static/shared library creation.
133 AC_PROG_CPP
134 AC_PROG_CC
135 AM_PROG_CC_C_O
136 AC_PROG_LIBTOOL
138 dnl Try to detect/use GNU features
139 CFLAGS="$CFLAGS -D_GNU_SOURCE"
141 dnl check for -Werror separatly
142 dnl (quite a few autotool checks don't work with -Werror; also, the
143 dnl check for -Werror fails after checking and adding the other flags)
144 AC_CACHE_CHECK([if gcc likes the -Werror flag], rd_cv_gcc_flag__Werror,
145 [AC_COMPILE_IFELSE(
146 [AC_LANG_PROGRAM([[]], [[return 0 ]])],
147 [rd_cv_gcc_flag__Werror="yes"],
148 [rd_cv_gcc_flag__Werror="no"])])
149 if test "x$rd_cv_gcc_flag__Werror" = "xyes"; then
150 WERROR="-Werror"
151 else
152 WERROR=""
153 fi
154 AC_SUBST(WERROR)
156 dnl which flags does the compiler support?
157 if test "x$GCC" = "xyes"; then
158 for flag in -fno-strict-aliasing -Wall -std=c99 -pedantic -Wundef -Wshadow -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Winline -Wold-style-definition -W; do
159 oCFLAGS="$CFLAGS"
160 CFLAGS="$CFLAGS $flag"
161 cachename=rd_cv_gcc_flag_`echo $flag|sed 's/[[^A-Za-z]]/_/g'`
162 AC_CACHE_CHECK([if gcc likes the $flag flag], $cachename,
163 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[return 0 ]])],[eval $cachename=yes],[eval $cachename=no])])
164 if eval test \$$cachename = no; then
165 CFLAGS="$oCFLAGS"
166 fi
167 done
168 fi
172 AC_SUBST(RRD_DEFAULT_FONT)
174 CONFIGURE_PART(Checking for Header Files)
176 dnl Checks for header files.
177 AC_HEADER_STDC
178 AC_HEADER_DIRENT
179 AC_CHECK_HEADERS(libgen.h features.h sys/stat.h sys/types.h fcntl.h locale.h fp_class.h malloc.h unistd.h ieeefp.h math.h sys/times.h sys/param.h sys/resource.h signal.h float.h stdio.h stdlib.h errno.h string.h ctype.h)
181 dnl Checks for typedefs, structures, and compiler characteristics.
182 AC_C_CONST
183 AC_HEADER_TIME
184 AC_STRUCT_TM
186 CONFIGURE_PART(Test Library Functions)
188 dnl Checks for libraries.
189 AC_CHECK_FUNC(acos, , AC_CHECK_LIB(m, acos))
192 dnl add pic flag in any case this makes sure all our code is relocatable
193 eval `./libtool --config | grep pic_flag`
194 CFLAGS="$CFLAGS $pic_flag"
197 dnl Checks for library functions.
198 AC_FUNC_STRFTIME
199 AC_FUNC_VPRINTF
201 AC_C_BIGENDIAN
203 dnl for each function found we get a definition in config.h
204 dnl of the form HAVE_FUNCTION
206 AC_CHECK_FUNCS(tzset fsync mbstowcs opendir readdir chdir chroot getuid setlocale strerror snprintf vsnprintf fpclass class fp_class isnan memmove strchr mktime getrusage gettimeofday)
208 AC_FUNC_STRERROR_R
210 CONFIGURE_PART(Map/Fadvis/Madvise checking)
212 dnl Could use these to know if we need to provide a prototype
213 dnl AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
215 dnl check for fdatasync. Solaris has fdatasync in the librt
217 AC_CHECK_FUNCS(fdatasync, [], AC_CHECK_LIB(rt, fdatasync, [LIBS="${LIBS} -lrt"; AC_DEFINE(HAVE_FDATASYNC)],[]))
218 dnl if there is no fdatasync we may get lucky with fsync
219 AC_CHECK_FUNCS(fsync)
222 dnl XXX: dunno about windows.. add AC_CHECK_FUNCS(munmap) there too?
223 if test "x$enable_mmap" = "xyes"; then
224 case "$host" in
225 *cygwin*)
226 # the normal mmap test does not work in cygwin
227 AC_CHECK_FUNCS(mmap)
228 if test "x$ac_cv_func_mmap" = "xyes"; then
229 ac_cv_func_mmap_fixed_mapped=yes
230 fi
231 ;;
232 *)
233 AC_CHECK_HEADERS(sys/mman.h)
234 AC_FUNC_MMAP
235 AC_CHECK_FUNCS(mmap munmap msync)
236 AC_CHECK_DECLS(madvise, [], [], [#ifdef HAVE_SYS_MMAN_H
237 # include <sys/mman.h>
238 #endif])
239 if test "x$ac_cv_have_decl_madvise" = "xyes";
240 then
241 AC_CHECK_FUNCS(madvise)
242 else
243 AC_CHECK_FUNCS(posix_madvise)
244 if test "x$ac_cv_func_posix_madvise" != "xyes"; then
245 AC_MSG_WARN([madvise() nor posix_madvise() found.])
246 fi
247 fi
248 ;;
249 esac
250 if test "x$ac_cv_func_mmap" != "xyes";
251 then
252 AC_MSG_ERROR([--enable-mmap requested but mmap() was not detected])
253 dnl enable_mmap="no"
254 fi
255 fi
257 dnl can we use posix_fadvise
258 AC_CHECK_DECLS(posix_fadvise, [], [], [#define _XOPEN_SOURCE 600
259 #include <fcntl.h>])
260 AC_CHECK_FUNCS(posix_fadvise)
262 CONFIGURE_PART(Libintl Processing)
265 dnl gettext
266 GETTEXT_PACKAGE=rrdtool
267 AC_SUBST(GETTEXT_PACKAGE)
268 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package])
270 AM_GLIB_GNU_GETTEXT()
272 AC_ARG_ENABLE(libintl,AS_HELP_STRING([--disable-libintl],[i18n support (libintl)]),
273 [],[enable_libintl=yes])
275 if test x$enable_libintl = xyes; then
276 IT_PROG_INTLTOOL([0.35.0],[no-xml])
277 fi
279 if test x$enable_libintl = xyes -a x$MSGFMT = xno; then
280 AC_MSG_WARN(I could not find msgfmt. Diabeling libintl build.)
281 enable_libintl=no
282 fi
284 if test x$enable_libintl = xyes; then
285 AC_CHECK_HEADERS(libintl.h,[],[AC_MSG_RESULT(disabeling libintl build); enable_libintl=no])
286 fi
288 if test x$enable_libintl = xyes ; then
289 dnl it seems bsd synstems need to link against libintl
290 dnl when compiling rrdupdate. lets check
291 AC_CHECK_LIB(intl, libintl_gettext,[LIB_LIBINTL="-lintl"])
292 fi
294 dnl use for linking rrdupdate
295 AC_SUBST(LIB_LIBINTL)
297 dnl do not touch the po stuff if we are not going to build intl
298 AM_CONDITIONAL(BUILD_LIBINTL,[test x$enable_libintl = xyes])
300 if test x$enable_libintl = xyes; then
301 AC_DEFINE([BUILD_LIBINTL], [], [Use this in code sections to mark them for libintl build])
302 fi
304 CONFIGURE_PART(IEEE Math Checks)
307 dnl actual code to check if this works
308 AC_CHECK_FUNCS(fpclassify, ,
309 [AC_MSG_CHECKING(for fpclassify with <math.h>)
310 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
311 volatile int x;volatile float f; ]], [[x = fpclassify(f)]])],[AC_MSG_RESULT(yes)
312 AC_DEFINE(HAVE_FPCLASSIFY)],[AC_MSG_RESULT(no)])])
314 AC_CHECK_FUNCS(isinf, ,
315 [AC_MSG_CHECKING(for isinf with <math.h>)
316 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
317 volatile int x;volatile float f; ]], [[x = isinf(f)]])],[AC_MSG_RESULT(yes)
318 AC_DEFINE(HAVE_ISINF)],[AC_MSG_RESULT(no)])])
320 dnl finite is BSD, isfinite is C99, so prefer the latter
321 AC_CACHE_CHECK([whether isfinite is broken],[ac_cv_have_broken_isfinite],[
322 AC_TRY_RUN([
323 #ifdef HAVE_MATH_H
324 #include <math.h>
325 #endif
326 #ifdef HAVE_FLOAT_H
327 #include <float.h>
328 #endif
329 int main ()
330 {
331 #ifdef isfinite
332 #ifdef LDBL_MAX
333 if (!isfinite(LDBL_MAX)) return 1;
334 #endif
335 #ifdef DBL_MAX
336 if (!isfinite(DBL_MAX)) return 1;
337 #endif
338 #endif
339 return 0;
340 }],[ac_cv_have_broken_isfinite=no],[ac_cv_have_broken_isfinite=yes],[
341 case "${target}" in
342 hppa*-*-hpux*) ac_cv_have_broken_isfinite=yes ;;
343 *-solaris2.8) ac_cv_have_broken_isfinite=yes ;;
344 *-solaris2.9) ac_cv_have_broken_isfinite=yes ;;
345 *) ac_cv_have_broken_isfinite=no ;;
346 esac])
347 ])
349 dnl the test does not seem to work on solaris 2.8
350 dnl so lets fix this by hand
351 case "${target}" in
352 *-solaris2.8) ac_cv_have_broken_isfinite=yes ;;
353 *-solaris2.9) ac_cv_have_broken_isfinite=yes ;;
354 esac
356 if test "x$ac_cv_have_broken_isfinite" = "xno"; then
357 AC_DEFINE(HAVE_ISFINITE)
358 else
359 AC_CHECK_FUNCS(finite,[],
360 [AC_CHECK_FUNCS(isfinite,[],
361 [AC_MSG_CHECKING(for isfinite with <math.h>)
362 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
363 volatile int x;volatile float f; ]],[[x = isfinite(f)]])],[AC_MSG_RESULT(yes)
364 AC_DEFINE(HAVE_ISFINITE)],[AC_MSG_RESULT(no)])])])
365 fi
367 AC_FULL_IEEE
369 CONFIGURE_PART(Resolve Portability Issues)
371 CHECK_FOR_WORKING_MS_ASYNC
373 dnl Do we need getopt_long
375 build_getopt=no
376 RRD_GETOPT_LONG="LIBC_HAS_GETOPT_LONG"
377 AC_CHECK_FUNC(getopt_long,[],[
378 RRD_GETOPT_LONG="getopt_long"
379 build_getopt=yes
380 ])
381 AC_SUBST(RRD_GETOPT_LONG)
382 AM_CONDITIONAL(BUILD_GETOPT,[test $build_getopt = yes])
384 dnl what does realloc do if it gets called with a NULL pointer
386 AC_CACHE_CHECK([if realloc can deal with NULL], rd_cv_null_realloc,
387 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
388 int main(void){
389 char *x = NULL;
390 x = realloc (x,10);
391 if (x==NULL) return 1;
392 return 0;
393 }]])],[rd_cv_null_realloc=yes],[rd_cv_null_realloc=nope],[:])])
395 if test x"$rd_cv_null_realloc" = xnope; then
396 AC_DEFINE(NO_NULL_REALLOC)
397 fi
399 AC_LANG_PUSH(C)
400 dnl solaris has some odd defines it needs in order to propperly compile ctime_r
401 AC_MSG_CHECKING([if ctime_r need special care to act posixly correct])
402 AC_LINK_IFELSE(
403 AC_LANG_PROGRAM(
404 [[#include <time.h>]],
405 [[ctime_r(NULL,NULL,0)]]
406 ),
407 [ CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
408 AC_LINK_IFELSE(
409 AC_LANG_PROGRAM(
410 [[#include <time.h>]],
411 [[ctime_r(NULL,NULL)]]
412 ),
413 [AC_MSG_RESULT([yes, this seems to be solaris style])],
414 [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
415 )
416 ],
417 [ AC_LINK_IFELSE(
418 AC_LANG_PROGRAM(
419 [[#include <time.h>]],
420 [[ctime_r(NULL,NULL)]]
421 ),
422 [AC_MSG_RESULT(no)],
423 [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
424 )
425 ]
426 )
427 AC_LANG_POP(C)
429 dnl Check for pthreads
430 dnl http://autoconf-archive.cryp.to/acx_pthread.m4
432 AC_SUBST(MULTITHREAD_CFLAGS)
433 AC_SUBST(MULTITHREAD_LDFLAGS)
435 if test $enable_pthread != no; then
436 ACX_PTHREAD([
437 MULTITHREAD_CFLAGS=$PTHREAD_CFLAGS
438 MULTITHREAD_LDFLAGS=$PTHREAD_LIBS
439 ],
440 [])
441 fi
443 dnl since we use lots of *_r functions all over the code we better
444 dnl make sure they are known
446 if test "x$x_rflag" != "xno"; then
447 CPPFLAGS="$CPPFLAGS $x_rflag"
448 fi
450 AM_CONDITIONAL(BUILD_MULTITHREAD,[test $enable_pthread != no])
452 AC_LANG_PUSH(C)
453 dnl see if we have to include malloc/malloc.h
454 AC_MSG_CHECKING([do we need malloc/malloc.h])
455 AC_LINK_IFELSE(
456 AC_LANG_PROGRAM(
457 [[#include <stdlib.h>]],
458 [[malloc(1)]]
459 ),
460 [ AC_MSG_RESULT([nope, works out of the box]) ],
461 [ AC_LINK_IFELSE(
462 AC_LANG_PROGRAM(
463 [[#include <stdlib.h>
464 #include <malloc/malloc.h>]],
465 [[malloc(1)]]
466 ),[
467 AC_DEFINE([MUST_HAVE_MALLOC_MALLOC_H])
468 AC_MSG_RESULT([yes we do])],
469 [AC_MSG_ERROR([Can not figure how to compile malloc])]
470 )
471 ]
472 )
473 AC_LANG_POP(C)
475 CONFIGURE_PART(Find 3rd-Party Libraries)
477 AC_ARG_ENABLE(libdbi,AS_HELP_STRING([--disable-libdbi],[do not build in support for libdbi]),[have_libdbi=no],[
478 XXX=$LIBS
479 LIBS="$LIBS -ldbi -ldl"
480 AC_MSG_CHECKING(for libdbi)
481 AC_LINK_IFELSE(
482 [AC_LANG_PROGRAM([[#include <dbi/dbi.h>]],
483 [[dbi_initialize(NULL)]]
484 )
485 ],[AC_DEFINE(HAVE_LIBDBI,[1],[have got libdbi installed])
486 AC_MSG_RESULT([yes])
487 have_libdbi=yes
488 ],[LIBS=$XXX
489 AC_MSG_RESULT([no])
490 have_libdbi=no
491 ]
492 )
493 ])
494 AM_CONDITIONAL(BUILD_LIBDBI,[test $have_libdbi != no])
496 AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
499 CORE_LIBS="$LIBS"
501 dnl EX_CHECK_ALL(z, zlibVersion, zlib.h, zlib, 1.2.3, http://www.gzip.org/zlib/, "")
502 dnl EX_CHECK_ALL(png, png_access_version_number, png.h, libpng, 1.2.10, http://prdownloads.sourceforge.net/libpng/, "")
503 dnl EX_CHECK_ALL(freetype, FT_Init_FreeType, ft2build.h, freetype2, 2.1.10, http://prdownloads.sourceforge.net/freetype/, /usr/include/freetype2)
504 dnl EX_CHECK_ALL(fontconfig, FcInit, fontconfig.h, fontconfig, 2.3.1, http://fontconfig.org/release/, /usr/include)
505 EX_CHECK_ALL(cairo, cairo_font_options_create, cairo.h, cairo-png, 1.4.6, http://cairographics.org/releases/, "")
506 EX_CHECK_ALL(cairo, cairo_svg_surface_create, cairo-svg.h, cairo-svg, 1.4.6, http://cairographics.org/releases/, "")
507 EX_CHECK_ALL(cairo, cairo_pdf_surface_create, cairo-pdf.h, cairo-pdf, 1.4.6, http://cairographics.org/releases/, "")
508 EX_CHECK_ALL(cairo, cairo_ps_surface_create, cairo-ps.h, cairo-ps, 1.4.6, http://cairographics.org/releases/, "")
509 EX_CHECK_ALL(glib-2.0, glib_check_version, glib.h, glib-2.0, 2.12.12, ftp://ftp.gtk.org/pub/glib/2.12/, "")
510 EX_CHECK_ALL(pango-1.0, pango_cairo_context_set_font_options, pango/pango.h, pangocairo, 1.17, http://ftp.gnome.org/pub/GNOME/sources/pango/1.17, "")
511 EX_CHECK_ALL(xml2, xmlParseFile, libxml/parser.h, libxml-2.0, 2.6.31, http://xmlsoft.org/downloads.html, /usr/include/libxml2)
513 if test "$EX_CHECK_ALL_ERR" = "YES"; then
514 AC_MSG_ERROR([Please fix the library issues listed above and try again.])
515 fi
517 ALL_LIBS="$LIBS"
518 LIBS=
520 AC_SUBST(CORE_LIBS)
521 AC_SUBST(ALL_LIBS)
523 CONFIGURE_PART(Prep for Building Language Bindings)
525 dnl Check for Perl and friends
526 PATH=$PATH:/usr/perl5/bin
527 export PATH
528 AC_PATH_PROG(PERL, perl, no)
529 AC_PATH_PROG(POD2MAN, pod2man, no)
530 AC_PATH_PROG(POD2HTML, pod2html, no)
533 AC_ARG_ENABLE(perl,AS_HELP_STRING([--disable-perl],[do not build the perl modules]),
534 [],[enable_perl=yes])
537 AC_ARG_VAR(PERLCC, [[] C compiler for Perl modules])
538 AC_ARG_VAR(PERLCCFLAGS, [[] CC flags for Perl modules])
539 AC_ARG_VAR(PERLLD, [[same as PERLCC] Linker for Perl modules])
540 AC_ARG_VAR(PERLLDFLAGS, [[] LD flags for Perl modules])
542 if test "x$PERL" = "xno" -o x$enable_perl = xno; then
543 COMP_PERL=
544 else
545 COMP_PERL="perl_piped perl_shared"
546 AC_MSG_CHECKING(for the perl version you are running)
547 PERL_VERSION=`$PERL -MConfig -e 'print $Config{version}'`
548 AC_MSG_RESULT($PERL_VERSION)
549 if test -z "$PERLCC"; then
550 AC_MSG_CHECKING(for the C compiler perl wants to use to build its modules)
551 perlcc=`$PERL -MConfig -e 'print $Config{cc}'`
552 AC_MSG_RESULT($perlcc)
553 if test ! -x "$perlcc"; then
554 AC_PATH_PROG(PERL_CC, ${perlcc}, no)
555 if test "$PERL_CC" = "no"; then
556 AC_MSG_WARN([
557 I would not find the Compiler ($perlcc) that was originally used to compile
558 your perl binary. You should either make sure that this compiler is
559 available on your system, pick an other compiler and set PERLCC
560 appropriately, or use a different perl setup that was compiled locally.
562 I will disable the compilation of the RRDs perl module for now.
563 ])
564 COMP_PERL="perl_piped"
565 fi
566 fi
567 fi
568 fi
570 AC_MSG_CHECKING(Perl Modules to build)
571 AC_MSG_RESULT(${COMP_PERL:-No Perl Modules will be built})
573 # Options to pass when configuring perl module
574 langpref=$prefix
575 test "$langpref" = "$(DESTDIR)NONE" && langpref='$(DESTDIR)'$ac_default_prefix
576 test "$langpref" = "NONE" && langpref=$ac_default_prefix
578 PERL_MAKE_OPTIONS="PREFIX=$langpref LIB=$langpref/lib/perl/$PERL_VERSION"
580 dnl pass additional perl options when generating Makefile from Makefile.PL
581 AC_ARG_ENABLE(perl-site-install,
582 AS_HELP_STRING([--enable-perl-site-install],[by default the rrdtool perl modules are installed together with rrdtool in $prefix/lib/perl. You have to put a 'use lib qw($prefix/lib/perl)' into your scripts when you want to use them. When you set this option the perl modules will get installed wherever your perl setup thinks it is best.]),
583 [PERL_MAKE_OPTIONS=],[])
585 if test ! -z "$PERLCC"; then
586 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CC=$PERLCC"
588 if test ! -z "$PERLCCFLAGS"; then
589 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CCFLAGS=$PERLCCFLAGS"
590 fi
592 if test -z "$PERLLD"; then
593 PERLLD=$PERLCC
594 fi
595 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LD=$PERLLD"
597 if test ! -z "$PERLLDFLAGS"; then
598 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LDFLAGS=$PERLLDFLAGS"
599 fi
600 fi
602 AC_ARG_WITH(perl-options,
603 [ --with-perl-options=[OPTIONS] options to pass on command-line when
604 generating Makefile from Makefile.PL. If you set this
605 option, interesting things may happen unless you know
606 what you are doing!],
607 [PERL_MAKE_OPTIONS=$withval])
609 AC_SUBST(PERL_MAKE_OPTIONS)
610 AC_SUBST(PERL)
611 AC_SUBST(COMP_PERL)
612 AC_SUBST(PERL_VERSION)
614 dnl Check for Ruby.
615 AC_PATH_PROG(RUBY, ruby, no)
617 AC_ARG_ENABLE(ruby,AS_HELP_STRING([--disable-ruby],[do not build the ruby modules]),
618 [],[enable_ruby=yes])
620 AC_MSG_CHECKING(if ruby modules can be built)
622 if test "x$RUBY" = "xno" -o x$enable_ruby = xno; then
623 COMP_RUBY=
624 AC_MSG_RESULT(No .. Ruby not found or disabled)
625 else
626 if $RUBY -e 'require "mkmf"' >/dev/null 2>&1; then
627 COMP_RUBY="ruby"
628 AC_MSG_RESULT(YES)
629 else
630 COMP_RUBY=
631 AC_MSG_RESULT(Ruby found but mkmf is missing! Install the -dev package)
632 fi
633 fi
635 dnl pass additional ruby options when generating Makefile from Makefile.PL
636 AC_ARG_ENABLE(ruby-site-install,
637 AS_HELP_STRING([--enable-ruby-site-install],[by default the rrdtool ruby modules are installed together with rrdtool in $prefix/lib/ruby. You have to add $prefix/lib/ruby/$ruby_version/$sitearch to your $: variable for ruby to find the RRD.so file.]),
638 [RUBY_MAKE_OPTIONS=],[RUBY_MAKE_OPTIONS="sitedir=$langpref/lib/ruby"])
641 AC_ARG_WITH(ruby-options,
642 [ --with-ruby-options=[OPTIONS] options to pass on command-line when
643 generating Makefile from extconf.rb. If you set this
644 option, interesting things may happen unless you know
645 what you are doing!],
646 [RUBY_MAKE_OPTIONS=$withval])
648 AC_SUBST(RUBY_MAKE_OPTIONS)
649 AC_SUBST(RUBY)
650 AC_SUBST(COMP_RUBY)
652 dnl Check for Lua.
653 AC_PATH_PROG(LUA, lua, no)
655 AC_ARG_ENABLE(lua,AS_HELP_STRING([--disable-lua],[do not build the lua modules]),
656 [],[enable_lua=yes])
658 COMP_LUA=
659 if test "$LUA" = "no" -o "$enable_lua" = "no"; then
660 enable_lua=no
661 else
662 AC_MSG_CHECKING(for lua >= 5.0)
663 read LUA_MAJOR LUA_MINOR LUA_POINT <<LUA_EOF
664 $($LUA -v 2>&1 | cut -f2 -d' ' | sed -e 's/\./ /g')
665 LUA_EOF
666 if test 0$LUA_MAJOR -lt 5; then
667 AC_MSG_RESULT([no, version found is $LUA_MAJOR.$LUA_MINOR])
668 else
669 AC_MSG_RESULT([$LUA_MAJOR.$LUA_MINOR found])
670 lua_vdot=$LUA_MAJOR.$LUA_MINOR
671 lua_vndot=$LUA_MAJOR$LUA_MINOR
672 lua_version=$LUA_MAJOR.$LUA_MINOR.$LUA_POINT
673 AC_CHECK_HEADERS(lua$lua_vndot/lua.h,
674 [AC_CHECK_HEADERS(lua$lua_vndot/lualib.h,
675 [AC_CHECK_HEADER(lua$lua_vndot/lauxlib.h,
676 [lua_headerdir=lua$lua_vndot],
677 [])],
678 [])],
679 [AC_CHECK_HEADERS(lua$lua_vdot/lua.h,
680 [AC_CHECK_HEADERS(lua$lua_vdot/lualib.h,
681 [AC_CHECK_HEADER(lua$lua_vdot/lauxlib.h,
682 [lua_headerdir=lua$lua_vdot],
683 [])],
684 [])],
685 [AC_CHECK_HEADERS(lua.h,
686 [AC_CHECK_HEADERS(lualib.h,
687 [AC_CHECK_HEADER(lauxlib.h,
688 [lua_headerdir=""],
689 [lua_headerdir="no"])],
690 [])],
691 [])])])
693 if test "$lua_headerdir" = "no"; then
694 enable_lua=no
695 else
696 COMP_LUA=lua
697 fi
699 if test "$COMP_LUA" != "lua"; then
700 enable_lua=no
701 AC_MSG_WARN([Lua $lua_vdot found but not lua.h, lualib.h and lauxlib.h! Please install the -dev packages for Lua $lua_vdot])
702 else
703 # OK, headers found, let's check the libraries (LIBS is not used)
704 LIBS=
705 lua_havelib=no
706 LUA_HAVE_COMPAT51=DONT_HAVE_COMPAT51
707 AC_SEARCH_LIBS(lua_call, lua$lua_vdot lua$lua_vndot lua,
708 [AC_SEARCH_LIBS(luaL_register, lua$lua_vdot lua$lua_vndot lua,
709 [lua_havelib=LUA$lua_vndot],
710 [AC_SEARCH_LIBS(luaL_module, lualib$lua_vndot lualib$lua_vdot lualib,
711 [lua_havelib=$lua_vndot; $LUA -l compat-5.1 2>/dev/null;
712 test "$?" = "0" && LUA_HAVE_COMPAT51=HAVE_COMPAT51],
713 [AC_SEARCH_LIBS(luaL_openlib, lualib$lua_vdot lualib$lua_vndot lualib,
714 [lua_havelib=$lua_vndot],
715 [COMP_LUA=], [-lm])], [-lm])], [-lm])],
716 [COMP_LUA=], [-lm])
717 lua_libs=$LIBS
718 LIBS=
720 # Options to pass when configuring Lua module
721 if test "$lua_havelib" != "no"; then
722 # OK, headers and libs found. Try to set lua flags
723 # and modules installation dirs with pkg-config
724 if test "$PKGCONFIG" != "no"; then
725 if test "$lua_vndot" = "50"; then
726 lua_pkg_prefix=lualib
727 else
728 lua_pkg_prefix=lua
729 fi
730 # try with dot, without dot and finally without version
731 for f in $lua_pkg_prefix$lua_vdot $lua_pkg_prefix$lua_vndot $lua_pkg_prefix; do
732 lua_exec_prefix=`$PKGCONFIG --variable=prefix $f 2>/dev/null`
733 # same binaries?
734 if test "$lua_exec_prefix/bin/lua" = "$LUA"; then
735 # OK, found CFLAGS. Get Lua LFLAGS and modules install dir
736 LUA_CFLAGS=`$PKGCONFIG --cflags $f 2>/dev/null`
737 LUA_LFLAGS=`$PKGCONFIG --libs $f 2>/dev/null`
738 LUA_INSTALL_CMOD=`$PKGCONFIG --variable=INSTALL_CMOD $f 2>/dev/null`
739 LUA_INSTALL_LMOD=`$PKGCONFIG --variable=INSTALL_LMOD $f 2>/dev/null`
740 break
741 fi
742 done
743 fi
745 LUA_RRD_LIBDIR="$langpref/lib/lua/$lua_vdot"
746 # if lua 5.0 can't find compat-5.1, force installation of
747 # compat-5.1.lua together with RRDtool.
748 if test "$lua_vdot" = "5.0" -a "$LUA_HAVE_COMPAT51" != "HAVE_COMPAT51"; then
749 lua_need_compat51=1
750 LUA_INSTALL_LMOD="$LUA_RRD_LIBDIR"
751 fi
753 # if not set with pkg-config, use default values in src packages compat-5.1, lua 5.1
754 if test "$LUA_CFLAGS" = ""; then
755 AC_MSG_WARN(Setting Lua include and lib flags to defaults in compat-5.1 and lua 5.1 sources)
756 LUA_CFLAGS="-I/usr/local/include -I/usr/local/include/lua -I/usr/local/include/lua/$lua_vdot"
757 LUA_LFLAGS="-L/usr/local/lib -L/usr/local/lib/lua -L/usr/local/lib/lua/$lua_vdot $lua_libs"
758 LUA_INSTALL_CMOD="/usr/local/lib/lua/$lua_vdot"
759 fi
761 dnl pass additional lua options
762 dnl if lua-site-install is not set, overwrite LUA_INSTALL_CMOD already
763 dnl found and install together with RRDtool, under $langpref.
764 AC_ARG_ENABLE(lua-site-install,
765 AS_HELP_STRING([--enable-lua-site-install],[by default the lua module is installed together with rrdtool in $prefix/lib/lua/$lua_version. You have to add $prefix/lib/lua/$lua_version/?.so to package.cpath for lua to find 'rrd.so'. For lua 5.0 you may also need to change LUA_PATH to the same dir, to require 'compat-5.1'. When you set this option the lua modules will get installed wherever your Lua setup thinks it is best. WARNING: if you set this option, system lua modules compat-5.1.lua and rrd.so, if any, may be overwritten.]),
766 [],
767 [LUA_INSTALL_CMOD="$LUA_RRD_LIBDIR"; LUA_INSTALL_LMOD="$LUA_RRD_LIBDIR"])
769 LUA_DEFINES="-DLUA$lua_vndot -D$LUA_HAVE_COMPAT51"
770 AC_SUBST(LUA)
771 AC_SUBST(COMP_LUA)
772 AC_SUBST(LUA_INSTALL_CMOD)
773 AC_SUBST(LUA_INSTALL_LMOD)
774 AC_SUBST(LUA_CFLAGS)
775 AC_SUBST(LUA_LFLAGS)
776 AC_SUBST(LUA_DEFINES)
777 else
778 enable_lua=no
779 AC_MSG_RESULT([Lua headers found but not the libraries! Please reinstall the dev packages for Lua $LUA_MAJOR.$LUA_MINOR])
780 fi
781 fi
782 fi
783 fi
784 dnl If Lua 5.0, we need compat-5.1. Add ours unless already
785 dnl integrated as in Debian/Ubuntu 5.0 -dev packages.
786 AM_CONDITIONAL(LUA_NEED_OUR_COMPAT51,
787 [test "$lua_vdot" = "5.0" -a "$LUA_HAVE_COMPAT51" != "HAVE_COMPAT51"])
788 AM_CONDITIONAL(LUA_SITE_CINSTALL, [test "$LUA_INSTALL_CMOD" != "$LUA_RRD_LIBDIR"])
789 AM_CONDITIONAL(LUA_SITE_LINSTALL, [test "$LUA_INSTALL_LMOD" != "$LUA_RRD_LIBDIR"])
790 AM_CONDITIONAL(LUA50, [test "$lua_vndot" = "50"])
791 AM_CONDITIONAL(BUILD_LUA, [test "$enable_lua" = "yes"])
793 enable_tcl_site=no
795 AC_ARG_ENABLE(tcl,AS_HELP_STRING([--disable-tcl],[do not build the tcl modules]),
796 [],[enable_tcl=yes])
798 if test "$enable_tcl" = "yes"; then
799 dnl Check for Tcl.
800 withval=""
801 AC_ARG_WITH(tcllib,[ --with-tcllib=DIR location of the tclConfig.sh])
802 enable_tcl=no
803 for dir in $withval /usr/lib /usr/local/lib /usr/lib/tcl8.4 /usr/lib/tcl8.3 ; do
804 AC_MSG_CHECKING(for tclConfig.sh in $dir)
805 if test -f "$dir/tclConfig.sh" ; then
806 tcl_config=$dir/tclConfig.sh
807 enable_tcl=yes
808 AC_MSG_RESULT(yes)
809 break
810 else
811 AC_MSG_RESULT(no)
812 fi
813 done
815 if test "$enable_tcl" = "no"; then
816 AC_MSG_WARN([tclConfig.sh not found - Tcl interface will not be built])
817 else
818 . $tcl_config
819 TCL_PACKAGE_DIR="$TCL_PACKAGE_PATH/tclrrd$VERSION"
820 if test -n "$TCL_INC_DIR"; then
821 TCL_INCLUDE_SPEC="$TCL_INCLUDE_SPEC -I$TCL_INC_DIR"
822 fi
823 fi
824 AC_ARG_ENABLE(tcl,AS_HELP_STRING([--enable-tcl-site],[install the tcl extension in the tcl tree]),
825 [],[enable_tcl_site=yes])
827 fi
829 AM_CONDITIONAL(BUILD_TCL, test "$enable_tcl" = "yes" )
830 AM_CONDITIONAL(BUILD_TCL_SITE, test "$enable_tcl_site" = "yes" )
833 AC_SUBST(TCL_PREFIX)
834 AC_SUBST(TCL_SHLIB_CFLAGS)
835 AC_SUBST(TCL_SHLIB_LD)
836 AC_SUBST(TCL_SHLIB_SUFFIX)
837 AC_SUBST(TCL_PACKAGE_PATH)
838 AC_SUBST(TCL_LD_SEARCH_FLAGS)
839 AC_SUBST(TCL_STUB_LIB_SPEC)
840 AC_SUBST(TCL_VERSION)
841 AC_SUBST(TCL_PACKAGE_DIR)
842 AC_SUBST(TCL_INCLUDE_SPEC)
844 AC_ARG_ENABLE(python,AS_HELP_STRING([--disable-python],[do not build the python modules]),
845 [],[enable_python=yes])
847 if test "$enable_python" = "yes"; then
848 dnl Check for python
849 AM_PATH_PYTHON(2.3,[],[enable_python=no])
850 AM_CHECK_PYTHON_HEADERS(,[enable_python=no;AC_MSG_WARN(could not find Python headers)])
851 fi
853 if test x$enable_python = xno; then
854 COMP_PYTHON=
855 else
856 COMP_PYTHON="python"
857 fi
859 AC_SUBST(COMP_PYTHON)
861 dnl Check for nroff
862 AC_PATH_PROGS(NROFF, gnroff nroff)
863 AC_PATH_PROGS(TROFF, groff troff)
865 AC_ARG_VAR(RRDDOCDIR, [[DATADIR/doc/PACKAGE-VERSION] Documentation directory])
866 if test -z "$RRDDOCDIR"; then
867 RRDDOCDIR='${datadir}/doc/${PACKAGE}-${VERSION}'; fi
870 CONFIGURE_PART(Apply Configuration Information)
872 AC_CONFIG_FILES([examples/shared-demo.pl])
873 AC_CONFIG_FILES([examples/piped-demo.pl])
874 AC_CONFIG_FILES([examples/stripes.pl])
875 AC_CONFIG_FILES([examples/bigtops.pl])
876 AC_CONFIG_FILES([examples/minmax.pl])
877 AC_CONFIG_FILES([examples/4charts.pl])
878 AC_CONFIG_FILES([examples/perftest.pl])
879 AC_CONFIG_FILES([examples/Makefile])
880 AC_CONFIG_FILES([examples/rrdcached/Makefile])
881 AC_CONFIG_FILES([doc/Makefile])
882 AC_CONFIG_FILES([po/Makefile.in])
883 AC_CONFIG_FILES([src/Makefile])
884 AC_CONFIG_FILES([src/librrd.sym.in])
885 AC_CONFIG_FILES([src/librrd.pc])
886 AC_CONFIG_FILES([bindings/Makefile])
887 AC_CONFIG_FILES([bindings/tcl/Makefile])
888 AC_CONFIG_FILES([bindings/tcl/ifOctets.tcl])
889 AC_CONFIG_FILES([Makefile])
890 AC_CONFIG_FILES([bindings/lua/Makefile])
892 AC_CONFIG_COMMANDS([default],[[ chmod +x examples/*.pl]],[[]])
893 AC_OUTPUT
895 AC_MSG_CHECKING(in)
896 AC_MSG_RESULT(and out again)
898 echo $ECHO_N "ordering CD from http://tobi.oetiker.ch/wish $ECHO_C" 1>&6
899 sleep 1
900 echo $ECHO_N ".$ECHO_C" 1>&6
901 sleep 1
902 echo $ECHO_N ".$ECHO_C" 1>&6
903 sleep 1
904 echo $ECHO_N ".$ECHO_C" 1>&6
905 sleep 1
906 echo $ECHO_N ".$ECHO_C" 1>&6
907 sleep 1
908 AC_MSG_RESULT([ just kidding ;-)])
909 echo
910 echo "----------------------------------------------------------------"
911 echo "Config is DONE!"
912 echo
913 echo " With MMAP IO: $enable_mmap"
914 echo " Build rrd_getopt: $build_getopt"
915 echo " Static programs: $staticprogs"
916 echo " Perl Modules: $COMP_PERL"
917 echo " Perl Binary: $PERL"
918 echo " Perl Version: $PERL_VERSION"
919 echo " Perl Options: $PERL_MAKE_OPTIONS"
920 echo " Ruby Modules: $COMP_RUBY"
921 echo " Ruby Binary: $RUBY"
922 echo " Ruby Options: $RUBY_MAKE_OPTIONS"
923 echo " Build Lua Bindings: $enable_lua"
924 if test "$enable_lua" = "yes"; then
925 echo " Lua Binary: $LUA"
926 echo " Lua Version: $lua_version"
927 echo " Lua C-modules dir: $LUA_INSTALL_CMOD"
928 if test "$lua_need_compat51" = "1"; then
929 echo " Lua Lua-modules dir: $LUA_INSTALL_LMOD"
930 fi
931 fi
932 echo " Build Tcl Bindings: $enable_tcl"
933 echo " Build Python Bindings: $enable_python"
934 echo " Build rrdcgi: $enable_rrdcgi"
935 echo " Build librrd MT: $enable_pthread"
936 echo " Link with libintl: $enable_libintl"
937 echo " With libDBI: $have_libdbi"
938 echo
939 echo " Libraries: $ALL_LIBS"
940 echo
941 echo "Type 'make' to compile the software and use 'make install' to "
942 echo "install everything to: $prefix."
943 echo
944 echo " ... that wishlist is NO JOKE. If you find RRDtool useful"
945 echo "make me happy. Go to http://tobi.oetiker.ch/wish and"
946 echo "place an order."
947 echo
948 echo " -- Tobi Oetiker <tobi@oetiker.ch>"
949 echo "----------------------------------------------------------------"