1 dnl
2 dnl $Id$
3 dnl
5 AC_INIT(ncurses MPD client, 0.12~git, max@duempel.org, ncmpc)
6 AC_CONFIG_SRCDIR([src/main.c])
7 AM_INIT_AUTOMAKE([gnu 1.6 dist-bzip2])
8 AM_CONFIG_HEADER([config.h])
9 AC_CONFIG_MACRO_DIR([m4])
11 dnl Check for programs
12 AC_PROG_CC_C99
13 AC_PROG_INSTALL
14 AC_PROG_LIBTOOL
16 dnl =======================================================
17 dnl initialize variables
18 dnl =======================================================
20 dnl i18n
21 ALL_LINGUAS="es da de fr gl no ru sv"
23 set -- $CFLAGS
25 dnl
26 dnl Check for types
27 dnl
29 AC_MSG_RESULT([$ac_have_socklen_t])
31 dnl
32 dnl Check for headers
33 dnl
35 AC_CHECK_HEADER([locale.h],
36 AC_DEFINE([HAVE_LOCALE_H], [1], [locale.h]),
37 ,)
40 dnl
41 dnl Check for functions
42 dnl
43 AC_CHECK_FUNCS([strcasestr])
46 dnl
47 dnl Check for libraries
48 dnl
50 dnl Try to find the socket functions
51 AC_CHECK_FUNC([socket],
52 [],
53 [AC_CHECK_LIB([socket],[socket],[LIBS="$LIBS -lsocket"],
54 [AC_MSG_ERROR(No UNIX socket API found)])
55 ])
57 dnl Try to find the gethostbyname functions
58 AC_CHECK_FUNC([gethostbyname],
59 [],
60 [AC_CHECK_LIB([nsl],[gethostbyname],[LIBS="$LIBS -lnsl"],
61 [AC_MSG_ERROR(No UNIX gethostbyname API found)])
62 ])
65 dnl wide character support
66 AC_ARG_ENABLE([wide],
67 AC_HELP_STRING([--enable-wide],
68 [Enable wide character support]),
69 [use_wide=$enableval],
70 [use_wide=auto])
73 dnl ncurses
74 ncurses=auto
75 AC_ARG_WITH([ncurses],
76 AC_HELP_STRING([--with-ncurses], [compile/link with ncurses library] ),
77 [ncurses=ncurses])
78 AC_ARG_WITH(ncursesw,
79 AC_HELP_STRING([--with-ncursesw], [compile/link with wide-char ncurses library @<:@default@:>@]),
80 [ncurses=ncursesw])
82 if test "x$enable_wide" = "xno"; then
83 if test "x$ncurses" = "xauto"; then
84 dnl select narrow ncurses
85 ncurses=ncurses
86 fi
88 if test "x$ncurses" = "xncursesw"; then
89 AC_MSG_WARN([Narrow ncmpc linking against wide libncurses])
90 fi
91 fi
93 if test "x$ncurses" = "xauto"; then
94 AC_CHECK_LIB([ncursesw],
95 [initscr],
96 [ncurses=ncursesw],
97 [ncurses=ncurses])
98 fi
100 AC_CHECK_LIB([$ncurses],
101 [initscr],
102 [LIBS="$LIBS -l$ncurses"],
103 [AC_MSG_ERROR($ncurses library is required)])
105 if test "x$ncurses" = "xncursesw"; then
106 AC_CHECK_HEADER([ncursesw/ncurses.h],
107 AC_DEFINE([HAVE_NCURSESW_NCURSES_H], [1], [ncursesw/ncurses.h]),
108 ,)
109 fi
112 dnl wide character support II
114 if test "x$use_wide" = "xauto" ; then
115 AC_CHECK_LIB([$ncurses],
116 [wget_wch],
117 [use_wide=yes],
118 [use_wide=no])
119 fi
121 AC_MSG_CHECKING([wide character support])
122 AC_MSG_RESULT([$use_wide])
124 if test "x$use_wide" = "xyes" ; then
125 AC_DEFINE([ENABLE_WIDE], [1], [Enable wide character support])
126 fi
129 dnl Check for glib-2.4
130 PKG_CHECK_MODULES([GLIB],
131 [glib-2.0 >= 2.4],
132 [glib24=yes],
133 [AC_MSG_WARN([glib-2.4 is required for NLS support!])])
134 if test "x$glib24" != "xyes"; then
135 PKG_CHECK_MODULES([GLIB],
136 [glib-2.0 >= 2.2],
137 [nls=no],
138 [AC_MSG_ERROR([glib-2.2 is required])])
139 fi
142 dnl i18n
143 AM_NLS
144 if test "x$glib24" = "xyes"; then
145 nls=$USE_NLS
146 else
147 USE_NLS=no
148 AC_SUBST(USE_NLS)
149 fi
151 if test "x$nls" = "xyes"; then
152 AM_GLIB_GNU_GETTEXT
153 GETTEXT_PACKAGE=$PACKAGE
154 AC_SUBST(GETTEXT_PACKAGE)
155 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],
156 ["${GETTEXT_PACKAGE}"],
157 [gettext domain])
158 nls=$gt_cv_have_gettext
159 if test "x$nls" != "xyes"; then
160 AC_MSG_WARN([NLS support disabled!])
161 fi
162 else
163 AM_PO_SUBDIRS
164 fi
166 dnl enable colors
167 AC_MSG_CHECKING([color support])
168 AC_ARG_ENABLE([colors],
169 AC_HELP_STRING([--enable-colors],
170 [Enable color support]),
171 [use_colors=$enableval],
172 [use_colors=no])
173 AC_MSG_RESULT([$use_colors])
174 if test "x$use_colors" = "xyes" ; then
175 AC_DEFINE([ENABLE_COLORS], [1], [Enable color support])
176 fi
178 dnl Debugging
179 AC_MSG_CHECKING([whether to build with debug support])
180 AC_ARG_ENABLE([debug],
181 AC_HELP_STRING([--enable-debug],
182 [Enable debugging @<:@default=no@:>@]),
183 [enable_debug="$enableval"],
184 [enable_debug=no])
185 AC_MSG_RESULT([$enable_debug])
186 if test "x$enable_debug" = "xyes" ; then
187 CFLAGS="$CFLAGS -g"
188 else
189 CFLAGS="$CFLAGS -DNDEBUG"
190 fi
192 dnl CFLAGS
194 AC_SUBST(AM_CFLAGS)
196 CHECK_CFLAG([-Wall])
197 CHECK_CFLAG([-Wextra])
198 CHECK_CFLAG([-Wno-deprecated-declarations])
199 CHECK_CFLAG([-Wmissing-prototypes])
200 CHECK_CFLAG([-Wdeclaration-after-statement])
201 CHECK_CFLAG([-Wshadow])
202 CHECK_CFLAG([-Wpointer-arith])
203 CHECK_CFLAG([-Wstrict-prototypes])
204 CHECK_CFLAG([-Wcast-qual])
205 CHECK_CFLAG([-Wwrite-strings])
207 dnl Optional screen - help screen
208 #AC_MSG_CHECKING([whether to include the help screen])
209 #AC_ARG_ENABLE([help-screen],
210 # AC_HELP_STRING([--enable-help-screen],
211 # [Enable the help screen @<:@default=yes@:>@]),
212 # [help_screen="$enableval"],
213 # [help_screen=yes])
214 #AC_MSG_RESULT([$help_screen])
215 #if test "x$help_screen" = "xyes" ; then
216 # AC_DEFINE(ENABLE_HELP_SCREEN, 1, [Enable the help screen])
217 #fi
219 dnl Optional screen - browse screen
220 #AC_MSG_CHECKING([whether to include the browse screen])r
221 #AC_ARG_ENABLE([browse-screen],
222 # AC_HELP_STRING([--enable-browse-screen],
223 # [Enable the browse screen @<:@default=yes@:>@]),
224 # [browse_screen="$enableval"],
225 # [browse_screen=yes])
226 #AC_MSG_RESULT([$browse_screen])
227 #if test "x$browse_screen" = "xyes" ; then
228 # AC_DEFINE(ENABLE_BROWSE_SCREEN, 1, [Enable the browse screen])
229 #fi
231 dnl Optional - curses getmouse support
232 AC_MSG_CHECKING([whether to include mouse support])
233 AC_ARG_ENABLE([mouse],
234 AC_HELP_STRING([--enable-mouse],
235 [Enable curses getmouse support @<:@default=yes@:>@]),
236 [getmouse="$enableval"],
237 [getmouse=yes])
238 AC_MSG_RESULT([$getmouse])
239 if test "x$getmouse" = "xyes" ; then
240 AC_CHECK_LIB([$ncurses],
241 [getmouse],
242 [AC_DEFINE([HAVE_GETMOUSE], [1], [$ncurses - getmouse()])],
243 [])
244 fi
246 dnl Optional screen - artist
247 AC_MSG_CHECKING([whether to include the artist screen])
248 AC_ARG_ENABLE([artist-screen],
249 AC_HELP_STRING([--enable-artist-screen],
250 [Enable artist screen (EXPERIMENTAL) @<:@default=no@:>@]),
251 [artist_screen="$enableval"],
252 [artist_screen=no])
253 AC_MSG_RESULT([$artist_screen])
254 if test "x$artist_screen" = "xyes" ; then
255 AC_DEFINE(ENABLE_ARTIST_SCREEN, 1, [Enable artist screen])
256 fi
258 AM_CONDITIONAL(ENABLE_ARTIST_SCREEN, test x$artist_screen = xyes)
260 dnl Optional screen - search
261 AC_MSG_CHECKING([whether to include the search screen])
262 AC_ARG_ENABLE([search-screen],
263 AC_HELP_STRING([--enable-search-screen],
264 [Enable search screen (EXPERIMENTAL) @<:@default=yes@:>@]),
265 [search_screen="$enableval"],
266 [search_screen=yes])
267 AC_MSG_RESULT([$search_screen])
268 if test "x$search_screen" = "xyes" ; then
269 AC_DEFINE(ENABLE_SEARCH_SCREEN, 1, [Enable search screen])
270 fi
272 AM_CONDITIONAL(ENABLE_SEARCH_SCREEN, test x$search_screen = xyes)
274 dnl Optional screen - key editor
275 AC_MSG_CHECKING([whether to include the key editor screen])
276 AC_ARG_ENABLE([key-screen],
277 AC_HELP_STRING([--enable-key-screen],
278 [Enable key editor screen @<:@default=yes@:>@]),
279 [keydef_screen="$enableval"],
280 [keydef_screen=yes])
281 AC_MSG_RESULT([$keydef_screen])
282 if test "x$keydef_screen" = "xyes" ; then
283 AC_DEFINE(ENABLE_KEYDEF_SCREEN, 1, [Enable key editor screen])
284 fi
286 AM_CONDITIONAL(ENABLE_KEYDEF_SCREEN, test x$keydef_screen = xyes)
288 dnl Optional screen - lyrics
289 AC_MSG_CHECKING([whether to include the lyrics screen])
290 AC_ARG_ENABLE([lyrics-screen],
291 AC_HELP_STRING([--enable-lyrics-screen],
292 [Enable lyrics screen @<:@default=no@:>@]),
293 [lyrics_screen="$enableval"],
294 [lyrics_screen=no])
295 if test "x$lyrics_screen" = "xyes" ; then
296 AC_DEFINE(ENABLE_LYRICS_SCREEN, 1, [Enable lyrics screen])
297 fi
299 AM_CONDITIONAL(ENABLE_LYRICS_SCREEN, test x$lyrics_screen = xyes)
301 AC_MSG_RESULT([$lyrics_screen])
303 AC_ARG_WITH([lyrics-plugin-dir],
304 AC_HELP_STRING([[--with-lyrics-plugin-dir[=DIRECTORY]]],
305 [Directory where lyrics plugins are stored @<:@default=PREFIX/lib/ncmpc/lyrics@:>@]),
306 [lyrics_plugin_dir=$withval],
307 [lyrics_plugin_dir=""])
308 if test "x${lyrics_plugin_dir}" = "x"; then
309 if test "x${prefix}" = "xNONE"; then
310 lyrics_plugin_dir="${ac_default_prefix}/lib/ncmpc/lyrics"
311 else
312 lyrics_plugin_dir="${prefix}/lib/ncmpc/lyrics"
313 fi
314 fi
315 AC_DEFINE_UNQUOTED([LYRICS_PLUGIN_DIR], ["$lyrics_plugin_dir"],
316 [Directory to search for lyrics plugins])
317 AC_SUBST(lyrics_plugin_dir)
319 dnl Default host
320 AC_MSG_CHECKING([for default MPD host])
321 AC_ARG_WITH([default-host],
322 AC_HELP_STRING([--with-default-host=ARG],
323 [Default MPD host @<:@localhost@:>@]),
324 [DEFAULT_HOST="$withval"],
325 [DEFAULT_HOST="localhost"])
326 AC_MSG_RESULT([$DEFAULT_HOST])
327 AC_DEFINE_UNQUOTED([DEFAULT_HOST], ["$DEFAULT_HOST"], [Default MPD host])
329 dnl Default port
330 AC_MSG_CHECKING([for default MPD port])
331 AC_ARG_WITH([default-port],
332 AC_HELP_STRING([--with-default-port=ARG],
333 [Default port @<:@6600@:>@]),
334 [DEFAULT_PORT="$withval"],
335 [DEFAULT_PORT="6600"])
336 AC_MSG_RESULT([$DEFAULT_PORT])
337 AC_DEFINE_UNQUOTED([DEFAULT_PORT], [$DEFAULT_PORT], [Default MPD port])
338 AC_DEFINE_UNQUOTED([DEFAULT_PORT_STR], ["$DEFAULT_PORT"], [Default MPD port])
340 dnl Default timedisplay type
341 AC_MSG_CHECKING([for default timedisplay type])
342 AC_ARG_WITH([default-timedisplay_type],
343 AC_HELP_STRING([--with-default-timedisplay_type=ARG],
344 [default_timedisplay]),
345 [DEFAULT_TIMEDISPLAY_TYPE="$withval"],
346 [DEFAULT_TIMEDISPLAY_TYPE="elapsed"])
347 AC_MSG_RESULT([$DEFAULT_TIMEDISPLAY_TYPE])
348 AC_DEFINE_UNQUOTED([DEFAULT_TIMEDISPLAY_TYPE], ["$DEFAULT_TIMEDISPLAY_TYPE"], [Default way to display time, either 'elapsed' or 'remaining'])
349 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile po/Makefile.in po/Makefile])
350 AC_OUTPUT