1 dnl RRDtool AutoConf script ...
2 dnl ---------------------------
3 dnl $Id: configure.ac 1857 2009-06-08 05:12:26Z oetiker $
4 dnl
5 dnl Created by Jeff Allen, Tobi Oetiker, Blair Zajac
6 dnl
7 dnl Inspiration from http://autoconf-archive.cryp.to
9 dnl tell automake the this script is for rrdtool
11 dnl Minimum Autoconf version required.
12 AC_PREREQ(2.59)
14 dnl the official version number is
15 dnl a.b.c
16 AC_INIT([rrdtool],[1.3.99909060808])
18 dnl for testing a numberical version number comes handy
19 dnl the released version are
20 dnl a.bccc
21 dnl the devel versions will be something like
22 dnl a.b999yymmddhh
23 NUMVERS=1.399909060808
24 AC_SUBST(NUMVERS)
26 dnl for the linker to understand which versions the library are compatible with
27 dnl each other we must keep a separate library version cout of the format c:r:a.
28 dnl - if only implementation changed but all interfaces are kept, do r++
29 dnl - if only functionality was added do c++,r=0,a++
30 dnl - if any functionality was removed do c++,r=0,a=0.
31 dnl
32 dnl see http://sourceware.org/autobook/autobook/autobook_91.html
33 dnl
34 LIBVERS=5:0:1
35 AC_SUBST(LIBVERS)
37 AC_CANONICAL_TARGET
38 m4_version_prereq(2.60, [AC_USE_SYSTEM_EXTENSIONS], [#])
39 AM_INIT_AUTOMAKE(m4_version_prereq(2.63, [silent-rules], [[]]))
40 AM_MAINTAINER_MODE
41 m4_version_prereq(2.63, [AM_SILENT_RULES([yes])], [#])
42 AC_CONFIG_HEADERS([rrd_config.h])
43 AC_CONFIG_MACRO_DIR([m4])
45 dnl all our local stuff like install scripts and include files
46 dnl is in there
49 dnl determine the type of system we are running on
51 AC_SUBST(VERSION)
53 AC_PREFIX_DEFAULT( /usr/local/rrdtool-$PACKAGE_VERSION )
55 dnl At the TOP of the HEADER
57 AH_TOP([
58 #ifndef RRD_CONFIG_H
59 #define RRD_CONFIG_H
61 /* IEEE can be prevented from raising signals with fpsetmask(0) */
62 #undef MUST_DISABLE_FPMASK
64 /* IEEE math only works if SIGFPE gets actively set to IGNORE */
65 #undef MUST_DISABLE_SIGFPE
67 /* realloc does not support NULL as argument */
68 #undef NO_NULL_REALLOC
70 /* lets enable madvise defines in NetBSD */
71 #if defined(__NetBSD__)
72 # if !defined(_NETBSD_SOURCE)
73 # define _NETBSD_SOURCE
74 # endif
75 #endif
77 ])
79 AH_BOTTOM([
81 #ifdef MUST_HAVE_MALLOC_MALLOC_H
82 # include <malloc/malloc.h>
83 #endif
85 #include <rrd_config_bottom.h>
87 #endif
88 ])
90 dnl Process Special Options
91 dnl -----------------------------------
93 dnl How the vertical axis label is printed
94 AC_ARG_VAR(RRDGRAPH_YLEGEND_ANGLE,
95 [Vertical label angle: -90.0 (default) or 90.0])
96 AC_DEFINE_UNQUOTED(RRDGRAPH_YLEGEND_ANGLE,${RRDGRAPH_YLEGEND_ANGLE:-90.0},
97 [Vertical label angle: -90.0 (default) or 90.0])
99 AC_ARG_ENABLE(rrdcgi,AS_HELP_STRING([--disable-rrdcgi],[disable building of rrdcgi]),
100 [],[enable_rrdcgi=yes])
102 dnl Check if we run on a system that has fonts
103 AC_ARG_WITH(rrd-default-font,
104 [ --with-rrd-default-font=[OPTIONS] set the full path to your default font.],
105 [RRD_DEFAULT_FONT=$withval],[
106 if test -d ${WINDIR:-nodir}/cour.ttf ; then
107 RRD_DEFAULT_FONT=`cd $WINDIR;pwd`/cour.ttf
108 else
109 RRD_DEFAULT_FONT='"DejaVu Sans Mono,Bitstream Vera Sans Mono,monospace,Courier"'
110 fi
111 ])
113 dnl Use mmap in rrd_update instead of seek+write
114 AC_ARG_ENABLE([mmap],
115 AS_HELP_STRING([--disable-mmap],[disable mmap in rrd_update, use seek+write instead]),
116 [],
117 [enable_mmap=yes])
119 AC_ARG_ENABLE(pthread,AS_HELP_STRING([--disable-pthread],[disable multithread support]),
120 [],[enable_pthread=yes])
122 AC_ARG_ENABLE(static-programs,
123 AS_HELP_STRING([--enable-static-programs],[Build static programs]),
124 [case "${enableval}" in
125 yes) staticprogs=yes ;;
126 no) staticprogs=no ;;
127 *) AC_MSG_ERROR(bad value ${enableval} for --enable-static-programs) ;;
128 esac],[staticprogs=no])
129 AM_CONDITIONAL(STATIC_PROGRAMS,[test "x$staticprogs" = "xyes"])
132 CONFIGURE_PART(Audit Compilation Environment)
135 dnl Check for the compiler and static/shared library creation.
136 AC_PROG_CPP
137 AC_PROG_CC
138 AM_PROG_CC_C_O
139 AC_PROG_LIBTOOL
141 dnl Try to detect/use GNU features
142 CFLAGS="$CFLAGS -D_GNU_SOURCE"
144 dnl check for -Werror separatly
145 dnl (quite a few autotool checks do not work with -Werror; also, the
146 dnl check for -Werror fails after checking and adding the other flags)
147 AC_CACHE_CHECK([if gcc likes the -Werror flag], rd_cv_gcc_flag__Werror,
148 [AC_COMPILE_IFELSE(
149 [AC_LANG_PROGRAM([[]], [[return 0 ]])],
150 [rd_cv_gcc_flag__Werror="yes"],
151 [rd_cv_gcc_flag__Werror="no"])])
152 if test "x$rd_cv_gcc_flag__Werror" = "xyes"; then
153 WERROR="-Werror"
154 else
155 WERROR=""
156 fi
157 AC_SUBST(WERROR)
159 dnl which flags does the compiler support?
160 if test "x$GCC" = "xyes"; then
161 for flag in -fno-strict-aliasing -Wall -std=c99 -pedantic -Wundef -Wshadow -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Winline -Wold-style-definition -W; do
162 oCFLAGS="$CFLAGS"
163 CFLAGS="$CFLAGS $flag"
164 cachename=rd_cv_gcc_flag_`echo $flag|sed 's/[[^A-Za-z]]/_/g'`
165 AC_CACHE_CHECK([if gcc likes the $flag flag], $cachename,
166 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[return 0 ]])],[eval $cachename=yes],[eval $cachename=no])])
167 if eval test \$$cachename = no; then
168 CFLAGS="$oCFLAGS"
169 fi
170 done
171 fi
175 AC_SUBST(RRD_DEFAULT_FONT)
177 CONFIGURE_PART(Checking for Header Files)
179 dnl Checks for header files.
180 AC_HEADER_STDC
181 AC_HEADER_DIRENT
182 AC_CHECK_HEADERS(libgen.h features.h sys/stat.h sys/types.h fcntl.h locale.h fp_class.h malloc.h unistd.h ieeefp.h math.h sys/times.h sys/param.h sys/resource.h signal.h float.h stdio.h stdlib.h errno.h string.h ctype.h)
184 dnl Checks for typedefs, structures, and compiler characteristics.
185 AC_C_CONST
186 AC_HEADER_TIME
187 AC_STRUCT_TM
189 CONFIGURE_PART(Test Library Functions)
191 dnl Checks for libraries.
192 AC_CHECK_FUNC(acos, , AC_CHECK_LIB(m, acos))
195 dnl add pic flag in any case this makes sure all our code is relocatable
196 eval `./libtool --config | grep pic_flag`
197 CFLAGS="$CFLAGS $pic_flag"
200 dnl Checks for library functions.
201 AC_FUNC_STRFTIME
202 AC_FUNC_VPRINTF
204 AC_C_BIGENDIAN
206 dnl for each function found we get a definition in config.h
207 dnl of the form HAVE_FUNCTION
209 AC_CHECK_FUNCS(tzset fsync mbstowcs opendir readdir chdir chroot getuid setlocale strerror snprintf vsnprintf vasprintf fpclass class fp_class isnan memmove strchr mktime getrusage gettimeofday)
211 AC_FUNC_STRERROR_R
213 CONFIGURE_PART(Map/Fadvis/Madvise checking)
215 dnl Could use these to know if we need to provide a prototype
216 dnl AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
218 dnl check for fdatasync. Solaris has fdatasync in the librt
220 AC_CHECK_FUNCS(fdatasync, [], AC_CHECK_LIB(rt, fdatasync, [LIBS="${LIBS} -lrt"; AC_DEFINE(HAVE_FDATASYNC)],[]))
221 dnl if there is no fdatasync we may get lucky with fsync
222 AC_CHECK_FUNCS(fsync)
225 dnl XXX: dunno about windows.. add AC_CHECK_FUNCS(munmap) there too?
226 if test "x$enable_mmap" = "xyes"; then
227 case "$host" in
228 *cygwin*)
229 # the normal mmap test does not work in cygwin
230 AC_CHECK_FUNCS(mmap)
231 if test "x$ac_cv_func_mmap" = "xyes"; then
232 ac_cv_func_mmap_fixed_mapped=yes
233 fi
234 ;;
235 *)
236 AC_CHECK_HEADERS(sys/mman.h)
237 AC_FUNC_MMAP
238 AC_CHECK_FUNCS(mmap munmap msync)
239 AC_CHECK_DECLS(madvise, [], [], [#ifdef HAVE_SYS_MMAN_H
240 # include <sys/mman.h>
241 #endif])
242 if test "x$ac_cv_have_decl_madvise" = "xyes";
243 then
244 AC_CHECK_FUNCS(madvise)
245 else
246 AC_CHECK_FUNCS(posix_madvise)
247 if test "x$ac_cv_func_posix_madvise" != "xyes"; then
248 AC_MSG_WARN([madvise() nor posix_madvise() found.])
249 fi
250 fi
251 ;;
252 esac
253 if test "x$ac_cv_func_mmap" != "xyes";
254 then
255 AC_MSG_ERROR([--enable-mmap requested but mmap() was not detected])
256 dnl enable_mmap="no"
257 fi
258 fi
260 dnl can we use posix_fadvise
261 AC_CHECK_DECLS(posix_fadvise, [], [], [#define _XOPEN_SOURCE 600
262 #include <fcntl.h>])
263 AC_CHECK_FUNCS(posix_fadvise)
265 CONFIGURE_PART(Libintl Processing)
267 AM_GNU_GETTEXT_VERSION(0.14.4)
268 AM_GNU_GETTEXT()
270 CONFIGURE_PART(IEEE Math Checks)
273 dnl actual code to check if this works
274 AC_CHECK_FUNCS(fpclassify, ,
275 [AC_MSG_CHECKING(for fpclassify with <math.h>)
276 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
277 volatile int x;volatile float f; ]], [[x = fpclassify(f)]])],[AC_MSG_RESULT(yes)
278 AC_DEFINE(HAVE_FPCLASSIFY)],[AC_MSG_RESULT(no)])])
280 AC_CHECK_FUNCS(isinf, ,
281 [AC_MSG_CHECKING(for isinf with <math.h>)
282 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
283 volatile int x;volatile float f; ]], [[x = isinf(f)]])],[AC_MSG_RESULT(yes)
284 AC_DEFINE(HAVE_ISINF)],[AC_MSG_RESULT(no)])])
286 dnl finite is BSD, isfinite is C99, so prefer the latter
287 AC_CACHE_CHECK([whether isfinite is broken],[ac_cv_have_broken_isfinite],[
288 AC_TRY_RUN([
289 #ifdef HAVE_MATH_H
290 #include <math.h>
291 #endif
292 #ifdef HAVE_FLOAT_H
293 #include <float.h>
294 #endif
295 int main ()
296 {
297 #ifdef isfinite
298 #ifdef LDBL_MAX
299 if (!isfinite(LDBL_MAX)) return 1;
300 #endif
301 #ifdef DBL_MAX
302 if (!isfinite(DBL_MAX)) return 1;
303 #endif
304 #endif
305 return 0;
306 }],[ac_cv_have_broken_isfinite=no],[ac_cv_have_broken_isfinite=yes],[
307 case "${target}" in
308 hppa*-*-hpux*) ac_cv_have_broken_isfinite=yes ;;
309 *-solaris2.8) ac_cv_have_broken_isfinite=yes ;;
310 *-solaris2.9) ac_cv_have_broken_isfinite=yes ;;
311 *) ac_cv_have_broken_isfinite=no ;;
312 esac])
313 ])
315 dnl the test does not seem to work on solaris 2.8
316 dnl so lets fix this by hand
317 case "${target}" in
318 *-solaris2.8) ac_cv_have_broken_isfinite=yes ;;
319 *-solaris2.9) ac_cv_have_broken_isfinite=yes ;;
320 esac
322 if test "x$ac_cv_have_broken_isfinite" = "xno"; then
323 AC_DEFINE(HAVE_ISFINITE)
324 else
325 AC_CHECK_FUNCS(finite,[],
326 [AC_CHECK_FUNCS(isfinite,[],
327 [AC_MSG_CHECKING(for isfinite with <math.h>)
328 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
329 volatile int x;volatile float f; ]],[[x = isfinite(f)]])],[AC_MSG_RESULT(yes)
330 AC_DEFINE(HAVE_ISFINITE)],[AC_MSG_RESULT(no)])])])
331 fi
333 AC_FULL_IEEE
335 CONFIGURE_PART(Resolve Portability Issues)
337 CHECK_FOR_WORKING_MS_ASYNC
339 dnl Do we need getopt_long
341 dnl even when including our own getopt implementation
342 dnl we may want to make sure we use the external
343 dnl defined by libc to not run into linker resolve trouble
345 AC_CACHE_CHECK([for opterr], rd_cv_var_int_opterr,
346 [AC_TRY_LINK([#include <unistd.h>],
347 [extern int opterr; opterr = 1;],
348 [rd_cv_var_int_opterr=yes],
349 [rd_cv_var_int_opterr=no])])
350 if test x"$rd_cv_var_int_opterr" = x"yes"; then
351 AC_DEFINE(HAVE_INT_OPTERR, 1, [Define to 1 if you have the global variable 'int opterr'.])
352 fi
354 build_getopt=no
355 RRD_GETOPT_LONG="LIBC_HAS_GETOPT_LONG"
356 AC_CHECK_FUNC(getopt_long,[],[
357 RRD_GETOPT_LONG="getopt_long"
358 build_getopt=yes
359 ])
360 AC_SUBST(RRD_GETOPT_LONG)
361 AM_CONDITIONAL(BUILD_GETOPT,[test $build_getopt = yes])
363 dnl what does realloc do if it gets called with a NULL pointer
365 AC_CACHE_CHECK([if realloc can deal with NULL], rd_cv_null_realloc,
366 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
367 int main(void){
368 char *x = NULL;
369 x = realloc (x,10);
370 if (x==NULL) return 1;
371 return 0;
372 }]])],[rd_cv_null_realloc=yes],[rd_cv_null_realloc=nope],[:])])
374 if test x"$rd_cv_null_realloc" = xnope; then
375 AC_DEFINE(NO_NULL_REALLOC)
376 fi
378 AC_LANG_PUSH(C)
379 dnl solaris has some odd defines it needs in order to propperly compile ctime_r
380 AC_MSG_CHECKING([if ctime_r need special care to act posixly correct])
381 AC_LINK_IFELSE(
382 AC_LANG_PROGRAM(
383 [[#include <time.h>]],
384 [[ctime_r(NULL,NULL,0)]]
385 ),
386 [ CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
387 AC_LINK_IFELSE(
388 AC_LANG_PROGRAM(
389 [[#include <time.h>]],
390 [[ctime_r(NULL,NULL)]]
391 ),
392 [AC_MSG_RESULT([yes, this seems to be solaris style])],
393 [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
394 )
395 ],
396 [ AC_LINK_IFELSE(
397 AC_LANG_PROGRAM(
398 [[#include <time.h>]],
399 [[ctime_r(NULL,NULL)]]
400 ),
401 [AC_MSG_RESULT(no)],
402 [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
403 )
404 ]
405 )
406 AC_LANG_POP(C)
408 dnl Check for pthreads
409 dnl http://autoconf-archive.cryp.to/acx_pthread.m4
411 AC_SUBST(MULTITHREAD_CFLAGS)
412 AC_SUBST(MULTITHREAD_LDFLAGS)
414 if test $enable_pthread != no; then
415 ACX_PTHREAD([
416 MULTITHREAD_CFLAGS=$PTHREAD_CFLAGS
417 MULTITHREAD_LDFLAGS=$PTHREAD_LIBS
418 ],
419 [])
420 fi
422 dnl since we use lots of *_r functions all over the code we better
423 dnl make sure they are known
425 if test "x$x_rflag" != "xno"; then
426 CPPFLAGS="$CPPFLAGS $x_rflag"
427 fi
429 AM_CONDITIONAL(BUILD_MULTITHREAD,[test $enable_pthread != no])
431 AC_LANG_PUSH(C)
432 dnl see if we have to include malloc/malloc.h
433 AC_MSG_CHECKING([do we need malloc/malloc.h])
434 AC_LINK_IFELSE(
435 AC_LANG_PROGRAM(
436 [[#include <stdlib.h>]],
437 [[malloc(1)]]
438 ),
439 [ AC_MSG_RESULT([nope, works out of the box]) ],
440 [ AC_LINK_IFELSE(
441 AC_LANG_PROGRAM(
442 [[#include <stdlib.h>
443 #include <malloc/malloc.h>]],
444 [[malloc(1)]]
445 ),[
446 AC_DEFINE([MUST_HAVE_MALLOC_MALLOC_H])
447 AC_MSG_RESULT([yes we do])],
448 [AC_MSG_ERROR([Can not figure how to compile malloc])]
449 )
450 ]
451 )
452 AC_LANG_POP(C)
454 CONFIGURE_PART(Find 3rd-Party Libraries)
456 AC_ARG_ENABLE(libdbi,AS_HELP_STRING([--disable-libdbi],[do not build in support for libdbi]),[have_libdbi=no],[
457 XXX=$LIBS
458 LIBS="$LIBS -ldbi -ldl"
459 AC_MSG_CHECKING(for libdbi)
460 AC_LINK_IFELSE(
461 [AC_LANG_PROGRAM([[#include <dbi/dbi.h>]],
462 [[dbi_initialize(NULL)]]
463 )
464 ],[AC_DEFINE(HAVE_LIBDBI,[1],[have got libdbi installed])
465 AC_MSG_RESULT([yes])
466 have_libdbi=yes
467 ],[LIBS=$XXX
468 AC_MSG_RESULT([no])
469 have_libdbi=no
470 ]
471 )
472 ])
473 AM_CONDITIONAL(BUILD_LIBDBI,[test $have_libdbi != no])
475 AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
478 CORE_LIBS="$LIBS"
480 dnl EX_CHECK_ALL(z, zlibVersion, zlib.h, zlib, 1.2.3, http://www.gzip.org/zlib/, "")
481 dnl EX_CHECK_ALL(png, png_access_version_number, png.h, libpng, 1.2.10, http://prdownloads.sourceforge.net/libpng/, "")
482 dnl EX_CHECK_ALL(freetype, FT_Init_FreeType, ft2build.h, freetype2, 2.1.10, http://prdownloads.sourceforge.net/freetype/, /usr/include/freetype2)
483 dnl EX_CHECK_ALL(fontconfig, FcInit, fontconfig.h, fontconfig, 2.3.1, http://fontconfig.org/release/, /usr/include)
484 EX_CHECK_ALL(cairo, cairo_font_options_create, cairo.h, cairo-png, 1.4.6, http://cairographics.org/releases/, "")
485 EX_CHECK_ALL(cairo, cairo_svg_surface_create, cairo-svg.h, cairo-svg, 1.4.6, http://cairographics.org/releases/, "")
486 EX_CHECK_ALL(cairo, cairo_pdf_surface_create, cairo-pdf.h, cairo-pdf, 1.4.6, http://cairographics.org/releases/, "")
487 EX_CHECK_ALL(cairo, cairo_ps_surface_create, cairo-ps.h, cairo-ps, 1.4.6, http://cairographics.org/releases/, "")
488 EX_CHECK_ALL(glib-2.0, glib_check_version, glib.h, glib-2.0, 2.12.12, ftp://ftp.gtk.org/pub/glib/2.12/, "")
489 EX_CHECK_ALL(pango-1.0, pango_cairo_context_set_font_options, pango/pango.h, pangocairo, 1.17, http://ftp.gnome.org/pub/GNOME/sources/pango/1.17, "")
490 EX_CHECK_ALL(xml2, xmlParseFile, libxml/parser.h, libxml-2.0, 2.6.31, http://xmlsoft.org/downloads.html, /usr/include/libxml2)
492 if test "$EX_CHECK_ALL_ERR" = "YES"; then
493 AC_MSG_ERROR([Please fix the library issues listed above and try again.])
494 fi
496 ALL_LIBS="$LIBS"
497 LIBS=
499 AC_SUBST(CORE_LIBS)
500 AC_SUBST(ALL_LIBS)
502 CONFIGURE_PART(Prep for Building Language Bindings)
504 dnl Check for Perl and friends
505 PATH=$PATH:/usr/perl5/bin
506 export PATH
507 AC_PATH_PROG(PERL, perl, no)
508 AC_PATH_PROG(POD2MAN, pod2man, no)
509 AC_PATH_PROG(POD2HTML, pod2html, no)
512 AC_ARG_ENABLE(perl,AS_HELP_STRING([--disable-perl],[do not build the perl modules]),
513 [],[enable_perl=yes])
516 AC_ARG_VAR(PERLCC, [[] C compiler for Perl modules])
517 AC_ARG_VAR(PERLCCFLAGS, [[] CC flags for Perl modules])
518 AC_ARG_VAR(PERLLD, [[same as PERLCC] Linker for Perl modules])
519 AC_ARG_VAR(PERLLDFLAGS, [[] LD flags for Perl modules])
521 if test "x$PERL" = "xno" -o x$enable_perl = xno; then
522 COMP_PERL=
523 else
524 COMP_PERL="perl_piped perl_shared"
525 AC_MSG_CHECKING(for the perl version you are running)
526 PERL_VERSION=`$PERL -MConfig -e 'print $Config{version}'`
527 AC_MSG_RESULT($PERL_VERSION)
528 if test -z "$PERLCC"; then
529 AC_MSG_CHECKING(for the C compiler perl wants to use to build its modules)
530 perlcc=`$PERL -MConfig -e 'print $Config{cc}'`
531 AC_MSG_RESULT($perlcc)
532 if test ! -x "$perlcc"; then
533 AC_PATH_PROG(PERL_CC, ${perlcc}, no)
534 if test "$PERL_CC" = "no"; then
535 AC_MSG_WARN([
536 I would not find the Compiler ($perlcc) that was originally used to compile
537 your perl binary. You should either make sure that this compiler is
538 available on your system, pick an other compiler and set PERLCC
539 appropriately, or use a different perl setup that was compiled locally.
541 I will disable the compilation of the RRDs perl module for now.
542 ])
543 COMP_PERL="perl_piped"
544 fi
545 fi
546 fi
547 fi
549 AC_MSG_CHECKING(Perl Modules to build)
550 AC_MSG_RESULT(${COMP_PERL:-No Perl Modules will be built})
552 # Options to pass when configuring perl module
553 langpref=$prefix
554 test "$langpref" = '$(DESTDIR)NONE' && langpref='$(DESTDIR)'$ac_default_prefix
555 test "$langpref" = "NONE" && langpref=$ac_default_prefix
557 PERL_MAKE_OPTIONS="PREFIX=$langpref LIB=$langpref/lib/perl/$PERL_VERSION"
559 dnl pass additional perl options when generating Makefile from Makefile.PL
560 AC_ARG_ENABLE(perl-site-install,
561 AS_HELP_STRING([--enable-perl-site-install],[by default the rrdtool perl modules are installed together with rrdtool in $prefix/lib/perl. You have to put a 'use lib qw($prefix/lib/perl)' into your scripts when you want to use them. When you set this option the perl modules will get installed wherever your perl setup thinks it is best.]),
562 [PERL_MAKE_OPTIONS=],[])
564 if test ! -z "$PERLCC"; then
565 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CC=$PERLCC"
567 if test ! -z "$PERLCCFLAGS"; then
568 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CCFLAGS=$PERLCCFLAGS"
569 fi
571 if test -z "$PERLLD"; then
572 PERLLD=$PERLCC
573 fi
574 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LD=$PERLLD"
576 if test ! -z "$PERLLDFLAGS"; then
577 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LDFLAGS=$PERLLDFLAGS"
578 fi
579 fi
581 AC_ARG_WITH(perl-options,
582 [ --with-perl-options=[OPTIONS] options to pass on command-line when
583 generating Makefile from Makefile.PL. If you set this
584 option, interesting things may happen unless you know
585 what you are doing!],
586 [PERL_MAKE_OPTIONS=$withval])
588 AC_SUBST(PERL_MAKE_OPTIONS)
589 AC_SUBST(PERL)
590 AC_SUBST(COMP_PERL)
591 AC_SUBST(PERL_VERSION)
593 dnl Check for Ruby.
594 AC_PATH_PROG(RUBY, ruby, no)
596 AC_ARG_ENABLE(ruby,AS_HELP_STRING([--disable-ruby],[do not build the ruby modules]),
597 [],[enable_ruby=yes])
599 AC_MSG_CHECKING(if ruby modules can be built)
601 if test "x$RUBY" = "xno" -o x$enable_ruby = xno; then
602 COMP_RUBY=
603 AC_MSG_RESULT(No .. Ruby not found or disabled)
604 else
605 if $RUBY -e 'require "mkmf"' >/dev/null 2>&1; then
606 COMP_RUBY="ruby"
607 AC_MSG_RESULT(YES)
608 else
609 COMP_RUBY=
610 AC_MSG_RESULT(Ruby found but mkmf is missing! Install the -dev package)
611 fi
612 fi
614 dnl pass additional ruby options when generating Makefile from Makefile.PL
615 AC_ARG_ENABLE(ruby-site-install,
616 AS_HELP_STRING([--enable-ruby-site-install],[by default the rrdtool ruby modules are installed together with rrdtool in $prefix/lib/ruby. You have to add $prefix/lib/ruby/$ruby_version/$sitearch to your $: variable for ruby to find the RRD.so file.]),
617 [RUBY_MAKE_OPTIONS=],[RUBY_MAKE_OPTIONS="sitedir=$langpref/lib/ruby"])
620 AC_ARG_WITH(ruby-options,
621 [ --with-ruby-options=[OPTIONS] options to pass on command-line when
622 generating Makefile from extconf.rb. If you set this
623 option, interesting things may happen unless you know
624 what you are doing!],
625 [RUBY_MAKE_OPTIONS=$withval])
627 AC_SUBST(RUBY_MAKE_OPTIONS)
628 AC_SUBST(RUBY)
629 AC_SUBST(COMP_RUBY)
631 dnl Check for Lua.
632 AC_PATH_PROG(LUA, lua, no)
634 AC_ARG_ENABLE(lua,AS_HELP_STRING([--disable-lua],[do not build the lua modules]),
635 [],[enable_lua=yes])
637 COMP_LUA=
638 if test "$LUA" = "no" -o "$enable_lua" = "no"; then
639 enable_lua=no
640 else
641 AC_MSG_CHECKING(for lua >= 5.0)
642 read LUA_MAJOR LUA_MINOR LUA_POINT <<LUA_EOF
643 $($LUA -v 2>&1 | cut -f2 -d' ' | sed -e 's/\./ /g')
644 LUA_EOF
645 if test 0$LUA_MAJOR -lt 5; then
646 AC_MSG_RESULT([no, version found is $LUA_MAJOR.$LUA_MINOR])
647 else
648 AC_MSG_RESULT([$LUA_MAJOR.$LUA_MINOR found])
649 lua_vdot=$LUA_MAJOR.$LUA_MINOR
650 lua_vndot=$LUA_MAJOR$LUA_MINOR
651 lua_version=$LUA_MAJOR.$LUA_MINOR.$LUA_POINT
652 AC_CHECK_HEADERS(lua$lua_vndot/lua.h,
653 [AC_CHECK_HEADERS(lua$lua_vndot/lualib.h,
654 [AC_CHECK_HEADER(lua$lua_vndot/lauxlib.h,
655 [lua_headerdir=lua$lua_vndot],
656 [])],
657 [])],
658 [AC_CHECK_HEADERS(lua$lua_vdot/lua.h,
659 [AC_CHECK_HEADERS(lua$lua_vdot/lualib.h,
660 [AC_CHECK_HEADER(lua$lua_vdot/lauxlib.h,
661 [lua_headerdir=lua$lua_vdot],
662 [])],
663 [])],
664 [AC_CHECK_HEADERS(lua.h,
665 [AC_CHECK_HEADERS(lualib.h,
666 [AC_CHECK_HEADER(lauxlib.h,
667 [lua_headerdir=""],
668 [lua_headerdir="no"])],
669 [])],
670 [])])])
672 if test "$lua_headerdir" = "no"; then
673 enable_lua=no
674 else
675 COMP_LUA=lua
676 fi
678 if test "$COMP_LUA" != "lua"; then
679 enable_lua=no
680 AC_MSG_WARN([Lua $lua_vdot found but not lua.h, lualib.h and lauxlib.h! Please install the -dev packages for Lua $lua_vdot])
681 else
682 # OK, headers found, let's check the libraries (LIBS is not used)
683 LIBS=
684 lua_havelib=no
685 LUA_HAVE_COMPAT51=DONT_HAVE_COMPAT51
686 AC_SEARCH_LIBS(lua_call, lua$lua_vdot lua$lua_vndot lua,
687 [AC_SEARCH_LIBS(luaL_register, lua$lua_vdot lua$lua_vndot lua,
688 [lua_havelib=LUA$lua_vndot],
689 [AC_SEARCH_LIBS(luaL_module, lualib$lua_vndot lualib$lua_vdot lualib,
690 [lua_havelib=$lua_vndot; $LUA -l compat-5.1 2>/dev/null;
691 test "$?" = "0" && LUA_HAVE_COMPAT51=HAVE_COMPAT51],
692 [AC_SEARCH_LIBS(luaL_openlib, lualib$lua_vdot lualib$lua_vndot lualib,
693 [lua_havelib=$lua_vndot],
694 [COMP_LUA=], [-lm])], [-lm])], [-lm])],
695 [COMP_LUA=], [-lm])
696 lua_libs=$LIBS
697 LIBS=
699 # Options to pass when configuring Lua module
700 if test "$lua_havelib" != "no"; then
701 # OK, headers and libs found. Try to set lua flags
702 # and modules installation dirs with pkg-config
703 if test "$PKGCONFIG" != "no"; then
704 if test "$lua_vndot" = "50"; then
705 lua_pkg_prefix=lualib
706 else
707 lua_pkg_prefix=lua
708 fi
709 # try with dot, without dot and finally without version
710 for f in $lua_pkg_prefix$lua_vdot $lua_pkg_prefix$lua_vndot $lua_pkg_prefix; do
711 lua_exec_prefix=`$PKGCONFIG --variable=prefix $f 2>/dev/null`
712 # same binaries?
713 if test "$lua_exec_prefix/bin/lua" = "$LUA"; then
714 # OK, found CFLAGS. Get Lua LFLAGS and modules install dir
715 LUA_CFLAGS=`$PKGCONFIG --cflags $f 2>/dev/null`
716 LUA_LFLAGS=`$PKGCONFIG --libs $f 2>/dev/null`
717 LUA_INSTALL_CMOD=`$PKGCONFIG --variable=INSTALL_CMOD $f 2>/dev/null`
718 LUA_INSTALL_LMOD=`$PKGCONFIG --variable=INSTALL_LMOD $f 2>/dev/null`
719 break
720 fi
721 done
722 fi
724 LUA_RRD_LIBDIR="$langpref/lib/lua/$lua_vdot"
725 # if lua 5.0 can't find compat-5.1, force installation of
726 # compat-5.1.lua together with RRDtool.
727 if test "$lua_vdot" = "5.0" -a "$LUA_HAVE_COMPAT51" != "HAVE_COMPAT51"; then
728 lua_need_compat51=1
729 LUA_INSTALL_LMOD="$LUA_RRD_LIBDIR"
730 fi
732 # if not set with pkg-config, use default values in src packages compat-5.1, lua 5.1
733 if test "$LUA_CFLAGS" = ""; then
734 AC_MSG_WARN(Setting Lua include and lib flags to defaults in compat-5.1 and lua 5.1 sources)
735 LUA_CFLAGS="-I/usr/local/include -I/usr/local/include/lua -I/usr/local/include/lua/$lua_vdot"
736 LUA_LFLAGS="-L/usr/local/lib -L/usr/local/lib/lua -L/usr/local/lib/lua/$lua_vdot $lua_libs"
737 LUA_INSTALL_CMOD="/usr/local/lib/lua/$lua_vdot"
738 fi
740 dnl pass additional lua options
741 dnl if lua-site-install is not set, overwrite LUA_INSTALL_CMOD already
742 dnl found and install together with RRDtool, under $langpref.
743 AC_ARG_ENABLE(lua-site-install,
744 AS_HELP_STRING([--enable-lua-site-install],[by default the lua module is installed together with rrdtool in $prefix/lib/lua/$lua_version. You have to add $prefix/lib/lua/$lua_version/?.so to package.cpath for lua to find 'rrd.so'. For lua 5.0 you may also need to change LUA_PATH to the same dir, to require 'compat-5.1'. When you set this option the lua modules will get installed wherever your Lua setup thinks it is best. WARNING: if you set this option, system lua modules compat-5.1.lua and rrd.so, if any, may be overwritten.]),
745 [],
746 [LUA_INSTALL_CMOD="$LUA_RRD_LIBDIR"; LUA_INSTALL_LMOD="$LUA_RRD_LIBDIR"])
748 LUA_DEFINES="-DLUA$lua_vndot -D$LUA_HAVE_COMPAT51"
749 AC_SUBST(LUA)
750 AC_SUBST(COMP_LUA)
751 AC_SUBST(LUA_INSTALL_CMOD)
752 AC_SUBST(LUA_INSTALL_LMOD)
753 AC_SUBST(LUA_CFLAGS)
754 AC_SUBST(LUA_LFLAGS)
755 AC_SUBST(LUA_DEFINES)
756 else
757 enable_lua=no
758 AC_MSG_RESULT([Lua headers found but not the libraries! Please reinstall the dev packages for Lua $LUA_MAJOR.$LUA_MINOR])
759 fi
760 fi
761 fi
762 fi
763 dnl If Lua 5.0, we need compat-5.1. Add ours unless already
764 dnl integrated as in Debian/Ubuntu 5.0 -dev packages.
765 AM_CONDITIONAL(LUA_NEED_OUR_COMPAT51,
766 [test "$lua_vdot" = "5.0" -a "$LUA_HAVE_COMPAT51" != "HAVE_COMPAT51"])
767 AM_CONDITIONAL(LUA_SITE_CINSTALL, [test "$LUA_INSTALL_CMOD" != "$LUA_RRD_LIBDIR"])
768 AM_CONDITIONAL(LUA_SITE_LINSTALL, [test "$LUA_INSTALL_LMOD" != "$LUA_RRD_LIBDIR"])
769 AM_CONDITIONAL(LUA50, [test "$lua_vndot" = "50"])
770 AM_CONDITIONAL(BUILD_LUA, [test "$enable_lua" = "yes"])
772 enable_tcl_site=no
774 AC_ARG_ENABLE(tcl,AS_HELP_STRING([--disable-tcl],[do not build the tcl modules]),
775 [],[enable_tcl=yes])
777 if test "$enable_tcl" = "yes"; then
778 dnl Check for Tcl.
779 withval=""
780 AC_ARG_WITH(tcllib,[ --with-tcllib=DIR location of the tclConfig.sh])
781 enable_tcl=no
782 for dir in $withval /usr/lib /usr/local/lib /usr/lib/tcl8.4 /usr/lib/tcl8.3 ; do
783 AC_MSG_CHECKING(for tclConfig.sh in $dir)
784 if test -f "$dir/tclConfig.sh" ; then
785 tcl_config=$dir/tclConfig.sh
786 enable_tcl=yes
787 AC_MSG_RESULT(yes)
788 break
789 else
790 AC_MSG_RESULT(no)
791 fi
792 done
794 if test "$enable_tcl" = "no"; then
795 AC_MSG_WARN([tclConfig.sh not found - Tcl interface will not be built])
796 else
797 . $tcl_config
798 TCL_PACKAGE_DIR="$TCL_PACKAGE_PATH/tclrrd$VERSION"
799 if test -n "$TCL_INC_DIR"; then
800 TCL_INCLUDE_SPEC="$TCL_INCLUDE_SPEC -I$TCL_INC_DIR"
801 fi
802 fi
803 AC_ARG_ENABLE(tcl,AS_HELP_STRING([--enable-tcl-site],[install the tcl extension in the tcl tree]),
804 [],[enable_tcl_site=yes])
806 fi
808 AM_CONDITIONAL(BUILD_TCL, test "$enable_tcl" = "yes" )
809 AM_CONDITIONAL(BUILD_TCL_SITE, test "$enable_tcl_site" = "yes" )
812 AC_SUBST(TCL_PREFIX)
813 AC_SUBST(TCL_SHLIB_CFLAGS)
814 AC_SUBST(TCL_SHLIB_LD)
815 AC_SUBST(TCL_SHLIB_SUFFIX)
816 AC_SUBST(TCL_PACKAGE_PATH)
817 AC_SUBST(TCL_LD_SEARCH_FLAGS)
818 AC_SUBST(TCL_STUB_LIB_SPEC)
819 AC_SUBST(TCL_VERSION)
820 AC_SUBST(TCL_PACKAGE_DIR)
821 AC_SUBST(TCL_INCLUDE_SPEC)
823 AC_ARG_ENABLE(python,AS_HELP_STRING([--disable-python],[do not build the python modules]),
824 [],[enable_python=yes])
826 if test "$enable_python" = "yes"; then
827 dnl Check for python
828 AM_PATH_PYTHON(2.3,[],[enable_python=no])
829 AM_CHECK_PYTHON_HEADERS(,[enable_python=no;AC_MSG_WARN(could not find Python headers)])
830 fi
832 if test x$enable_python = xno; then
833 COMP_PYTHON=
834 else
835 COMP_PYTHON="python"
836 fi
838 AC_SUBST(COMP_PYTHON)
840 dnl Check for nroff
841 AC_PATH_PROGS(NROFF, gnroff nroff)
842 AC_PATH_PROGS(TROFF, groff troff)
844 AC_ARG_VAR(RRDDOCDIR, [[DATADIR/doc/PACKAGE-VERSION] Documentation directory])
845 if test -z "$RRDDOCDIR"; then
846 RRDDOCDIR='${datadir}/doc/${PACKAGE}-${VERSION}'; fi
849 CONFIGURE_PART(Apply Configuration Information)
851 AC_CONFIG_FILES([examples/shared-demo.pl])
852 AC_CONFIG_FILES([examples/piped-demo.pl])
853 AC_CONFIG_FILES([examples/stripes.pl])
854 AC_CONFIG_FILES([examples/bigtops.pl])
855 AC_CONFIG_FILES([examples/minmax.pl])
856 AC_CONFIG_FILES([examples/4charts.pl])
857 AC_CONFIG_FILES([examples/perftest.pl])
858 AC_CONFIG_FILES([examples/Makefile])
859 AC_CONFIG_FILES([examples/rrdcached/Makefile])
860 AC_CONFIG_FILES([doc/Makefile])
861 AC_CONFIG_FILES([po/Makefile.in])
862 AC_CONFIG_FILES([intl/Makefile])
863 AC_CONFIG_FILES([src/Makefile])
864 AC_CONFIG_FILES([src/librrd.sym.in])
865 AC_CONFIG_FILES([src/librrd.pc])
866 AC_CONFIG_FILES([bindings/Makefile])
867 AC_CONFIG_FILES([bindings/tcl/Makefile])
868 AC_CONFIG_FILES([bindings/tcl/ifOctets.tcl])
869 AC_CONFIG_FILES([Makefile])
870 AC_CONFIG_FILES([bindings/lua/Makefile])
872 AC_CONFIG_COMMANDS([default],[[ chmod +x examples/*.pl]],[[]])
874 dnl intl requires our config to be called config.h. indulge it.
875 AC_CONFIG_COMMANDS_POST([ test -f config.h || ln -s rrd_config.h config.h ])
877 AC_OUTPUT
879 AC_MSG_CHECKING(in)
880 AC_MSG_RESULT(and out again)
882 echo $ECHO_N "ordering CD from http://tobi.oetiker.ch/wish $ECHO_C" 1>&6
883 sleep 1
884 echo $ECHO_N ".$ECHO_C" 1>&6
885 sleep 1
886 echo $ECHO_N ".$ECHO_C" 1>&6
887 sleep 1
888 echo $ECHO_N ".$ECHO_C" 1>&6
889 sleep 1
890 echo $ECHO_N ".$ECHO_C" 1>&6
891 sleep 1
892 AC_MSG_RESULT([ just kidding ;-)])
893 echo
894 echo "----------------------------------------------------------------"
895 echo "Config is DONE!"
896 echo
897 echo " With MMAP IO: $enable_mmap"
898 echo " Build rrd_getopt: $build_getopt"
899 echo " Static programs: $staticprogs"
900 echo " Perl Modules: $COMP_PERL"
901 echo " Perl Binary: $PERL"
902 echo " Perl Version: $PERL_VERSION"
903 echo " Perl Options: $PERL_MAKE_OPTIONS"
904 echo " Ruby Modules: $COMP_RUBY"
905 echo " Ruby Binary: $RUBY"
906 echo " Ruby Options: $RUBY_MAKE_OPTIONS"
907 echo " Build Lua Bindings: $enable_lua"
908 if test "$enable_lua" = "yes"; then
909 echo " Lua Binary: $LUA"
910 echo " Lua Version: $lua_version"
911 echo " Lua C-modules dir: $LUA_INSTALL_CMOD"
912 if test "$lua_need_compat51" = "1"; then
913 echo " Lua Lua-modules dir: $LUA_INSTALL_LMOD"
914 fi
915 fi
916 echo " Build Tcl Bindings: $enable_tcl"
917 echo " Build Python Bindings: $enable_python"
918 echo " Build rrdcgi: $enable_rrdcgi"
919 echo " Build librrd MT: $enable_pthread"
920 echo " Use gettext: $USE_NLS"
921 echo " With libDBI: $have_libdbi"
922 echo
923 echo " Libraries: $ALL_LIBS"
924 echo
925 echo "Type 'make' to compile the software and use 'make install' to "
926 echo "install everything to: $prefix."
927 echo
928 echo " ... that wishlist is NO JOKE. If you find RRDtool useful"
929 echo "make me happy. Go to http://tobi.oetiker.ch/wish and"
930 echo "place an order."
931 echo
932 echo " -- Tobi Oetiker <tobi@oetiker.ch>"
933 echo "----------------------------------------------------------------"