1 dnl Process this file with autoconf to produce a configure script.
3 AC_PREREQ(2.53)
5 # Always use 0.xx+devel instead of 0.xxdevel for the version, e.g. 0.46+devel.
6 # Rationale: (i) placate simple version comparison software such as
7 # `dpkg --compare-versions'. (ii) We don't always know what the next
8 # version is going to be called until about the time we release it
9 # (whereas we always know what the previous version was called).
10 AC_INIT(inkscape, 0.47+devel)
12 AC_CANONICAL_HOST
13 AC_CONFIG_SRCDIR([src/main.cpp])
14 AM_INIT_AUTOMAKE([dist-zip dist-bzip2 tar-pax])
16 AC_ARG_ENABLE([lsb], AS_HELP_STRING([--enable-lsb], [LSB-compatible build configuration]), [
17 prefix=/opt/inkscape
18 PATH="/opt/lsb/bin:$PATH"
19 CC=lsbcc
20 CXX=lsbc++
21 export CC CXX
22 ])
24 AM_CONFIG_HEADER(config.h)
26 AC_LANG(C++)
27 AC_ISC_POSIX
28 AC_PROG_CXX
29 AM_PROG_CC_STDC
30 AM_PROG_AS
31 AC_PROG_RANLIB
32 AC_PROG_INTLTOOL(0.22)
33 AC_HEADER_STDC
34 INK_BZR_SNAPSHOT_BUILD
36 dnl If automake 1.11 shave the output to look nice
37 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
39 dnl These next few lines are needed only while libcroco is in our source tree.
40 AC_PROG_CC
41 AM_PROG_CC_C_O
42 if test "$GCC" = "yes"; then
43 # Enable some warnings from gcc.
44 AC_LANG_PUSH(C)
46 ####
47 # Generic cpp flags...
49 # What is just plain "-W" ?
50 # Fortify source requires -O2 or higher, which is handled with newer autoconf
51 CPPFLAGS="-W -D_FORTIFY_SOURCE=2 $CPPFLAGS"
52 # Enable format and format security warnings
53 CPPFLAGS="-Wformat -Wformat-security $CPPFLAGS"
54 # Enable all default warnings
55 CPPFLAGS="-Wall $CPPFLAGS"
57 # Test for -Werror=... (introduced some time post-4.0)
58 # If we hit a format error -- it should be fatal.
59 AC_MSG_CHECKING([compiler support for -Werror=format-security])
60 ink_svd_CPPFLAGS="$CPPFLAGS"
61 CPPFLAGS="-Werror=format-security $CPPFLAGS"
62 AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]), [ink_opt_ok=yes], [ink_opt_ok=no])
63 AC_MSG_RESULT([$ink_opt_ok])
64 if test "x$ink_opt_ok" != "xyes"; then
65 CPPFLAGS="$ink_svd_CPPFLAGS"
66 fi
68 ####
69 # C-specific flags...
71 # -Wno-pointer-sign is probably new in gcc 4.0; certainly it isn't accepted
72 # by gcc 2.95.
73 AC_MSG_CHECKING([compiler support for -Wno-pointer-sign])
74 ink_svd_CFLAGS="$CFLAGS"
75 CFLAGS="-Wno-pointer-sign $CFLAGS"
76 AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]), [ink_opt_ok=yes], [ink_opt_ok=no])
77 AC_MSG_RESULT([$ink_opt_ok])
78 if test "x$ink_opt_ok" != "xyes"; then
79 CFLAGS="$ink_svd_CFLAGS"
80 fi
82 ####
83 # Linker flags...
85 # Have linker produce read-only relocations, if it knows how
86 AC_MSG_CHECKING([linker tolerates -z relro])
87 ink_svd_LDFLAGS="$LDFLAGS"
88 LDFLAGS="-Wl,-z,relro $LDFLAGS"
89 AC_LINK_IFELSE(AC_LANG_PROGRAM([]), [ink_opt_ok=yes], [ink_opt_ok=no])
90 AC_MSG_RESULT([$ink_opt_ok])
91 if test "x$ink_opt_ok" != "xyes"; then
92 LDFLAGS="$ink_svd_LDFLAGS"
93 fi
95 AC_LANG_POP
97 # C++-specific flags are defined further below. Look for CXXFLAGS...
98 fi
100 dnl Honor aclocal flags
101 ACLOCAL="$ACLOCAL $ACLOCAL_FLAGS"
103 dnl Verify our GCC version
104 if test "x$GXX" = "xyes"; then
105 AC_MSG_CHECKING([GNU compiler version])
107 # Don't pass CXXFLAGS to the following CXX command as some
108 # of them can't be specified along with '-v'.
109 cc_version=["`$CXX -v 2>&1 </dev/null |grep 'gcc version' |\
110 sed 's/.*gcc version \([-a-z0-9\.]*\).*/\1/'`"]
112 AC_MSG_RESULT([$cc_version])
114 # Some version numbers
115 cc_vers_major=`echo $cc_version | cut -f1 -d.`
116 cc_vers_minor=`echo $cc_version | cut -f2 -d.`
117 cc_vers_patch=`echo $cc_version | cut -f3 -d.`
118 test -n "$cc_vers_major" || cc_vers_major=0
119 test -n "$cc_vers_minor" || cc_vers_minor=0
120 test -n "$cc_vers_patch" || cc_vers_patch=0
121 cc_vers_all=`expr $cc_vers_major '*' 1000000 + $cc_vers_minor '*' 1000 + $cc_vers_patch`
123 if test $cc_vers_major -lt 3; then
124 AC_MSG_ERROR([gcc >= 3.0 is needed to compile inkscape])
125 fi
126 fi
128 # Detect a working version of unordered containers.
129 AC_MSG_CHECKING([TR1 unordered_set usability])
130 AC_COMPILE_IFELSE([
131 #include <tr1/unordered_set>
132 int main() {
133 std::tr1::unordered_set<int> i, j;
134 i = j;
135 return 0;
136 }
137 ], [unordered_set_works=yes], [unordered_set_works=no])
138 if test "x$unordered_set_works" = "xyes"; then
139 AC_MSG_RESULT([ok])
140 AC_DEFINE(HAVE_TR1_UNORDERED_SET, 1, [Has working standard TR1 unordered_set])
141 else
142 AC_MSG_RESULT([not working])
143 fi
144 AC_CHECK_HEADER([boost/unordered_set.hpp], [AC_DEFINE(HAVE_BOOST_UNORDERED_SET, 1, [Boost unordered_set (Boost >= 1.36)])], [])
145 AC_CHECK_HEADER([ext/hash_set], [AC_DEFINE(HAVE_EXT_HASH_SET, 1, [Legacy GNU ext/hash_set])], [])
147 # Test whether GCC emits a spurious warning when using boost::optional
148 # If yes, turn off strict aliasing warnings to reduce noise
149 # and allow the legitimate warnings to stand out
150 AC_MSG_CHECKING([for overzealous strict aliasing warnings])
151 ignore_strict_aliasing=no
152 CXXFLAGS_SAVE=$CXXFLAGS
153 CXXFLAGS="$CXXFLAGS -Werror=strict-aliasing"
154 AC_COMPILE_IFELSE([
155 #include <boost/optional.hpp>
156 boost::optional<int> x;
157 int func() {
158 return *x;
159 }
160 ], [ignore_strict_aliasing=no], [ignore_strict_aliasing=yes])
161 AC_MSG_RESULT($ignore_strict_aliasing)
162 CXXFLAGS=$CXXFLAGS_SAVE
163 if test "x$ignore_strict_aliasing" = "xyes"; then
164 CXXFLAGS="$CXXFLAGS -Wno-strict-aliasing"
165 fi
167 dnl ******************************
168 dnl Gettext stuff
169 dnl ******************************
170 GETTEXT_PACKAGE="AC_PACKAGE_NAME"
171 AC_SUBST(GETTEXT_PACKAGE)
172 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Translation domain used])
173 dnl Add the languages which your application supports here.
174 ALL_LINGUAS="am ar az be bg bn br ca ca@valencia cs da de dz el en_AU en_CA en_GB en_US@piglatin eo es_MX es et eu fa fi fr ga gl he hr hu hy id it ja km ko lt mk mn nb ne nl nn pa pl pt_BR pt ro ru rw sk sl sq sr@latin sr sv te_IN th tr uk vi zh_CN zh_TW"
175 AM_GLIB_GNU_GETTEXT
177 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
178 if test "x$PKG_CONFIG" = "xno"; then
179 AC_MSG_ERROR(You have to install pkg-config to compile inkscape.)
180 fi
182 dnl Find msgfmt. Without this, po/Makefile fails to set MSGFMT on some platforms.
183 AC_PATH_PROG(MSGFMT, msgfmt, msgfmt)
184 AC_PATH_PROG(GMSGFMT, gmsgfmt, $MSGFMT)
186 dnl ******************************
187 dnl Check for OpenMP
188 dnl Replace this with AC_OPENMP once Autoconf 2.62 is widespread
189 dnl ******************************
190 AX_OPENMP([openmp_ok=yes],[openmp_ok=no])
191 if test "x$openmp_ok" = "xyes"; then
192 dnl We have it, now set up the flags
193 CXXFLAGS="$CXXFLAGS $OPENMP_CXXFLAGS"
194 AC_CHECK_HEADER(omp.h)
195 fi
197 dnl ******************************
198 dnl Check for libpng
199 dnl ******************************
200 AC_CHECK_LIB(png, png_read_info, [AC_CHECK_HEADER(png.h, png_ok=yes, png_ok=yes)], png_ok=no, -lz -lm)
201 if test "x$png_ok" != "xyes"; then
202 AC_MSG_ERROR([libpng >= 1.2 is needed to compile inkscape])
203 fi
205 dnl Handle possible dlopen requirement for libgc
206 dnl Isn't this internal to something in autoconf? Couldn't find it...
207 AC_CHECK_LIB([dld], [shl_load], [lt_cv_dlopen="shl_load" lt_cv_dlopen_libs="-dld"], [AC_CHECK_FUNC([dlopen],
208 [lt_cv_dlopen="dlopen"],
209 [AC_CHECK_LIB([dl], [dlopen],
210 [lt_cv_dlopen="dlopen" lt_cv_dlopen_libs="-ldl"],
211 [AC_CHECK_LIB([svld], [dlopen],
212 [lt_cv_dlopen="dlopen" lt_cv_dlopen_libs="-lsvld"],
213 [AC_CHECK_LIB([dld], [dld_link],
214 [lt_cv_dlopen="dld_link" lt_cv_dlopen_libs="-dld"])
215 ])
216 ])
217 ])
218 ])
220 AC_CHECK_HEADERS([gc.h gc/gc.h],
221 [
222 # To test for the different required libs, I have to
223 # overcome autoconf's caching system, so I change the
224 # desired function name. They're all in libgc.
225 # The "break" will exit from the top level
226 # AC_CHECK_HEADERS.
227 gc_libs=""
228 AC_CHECK_LIB(gc, GC_init,
229 [gc_ok=yes;
230 LIBS="-lgc $gc_libs $LIBS";
231 break], [gc_ok=no], [$gc_libs])
232 gc_libs="-lpthread"
233 AC_CHECK_LIB(gc, GC_malloc,
234 [gc_ok=yes;
235 LIBS="-lgc $gc_libs $LIBS";
236 break], [gc_ok=no], [$gc_libs])
237 gc_libs="$lt_cv_dlopen_libs"
238 AC_CHECK_LIB(gc, GC_realloc,
239 [gc_ok=yes;
240 LIBS="-lgc $gc_libs $LIBS";
241 break], [gc_ok=no], [$gc_libs])
242 gc_libs="-lpthread $lt_cv_dlopen_libs"
243 AC_CHECK_LIB(gc, GC_free,
244 [gc_ok=yes;
245 LIBS="-lgc $gc_libs $LIBS";
246 break], [gc_ok=no], [$gc_libs])
247 break],
248 [gc_ok=no])
249 if test "x$gc_ok" = "xyes" && test "x$cross_compiling" = "xno" ; then
250 AC_MSG_CHECKING([libgc version 6.4+])
251 AC_RUN_IFELSE(
252 [AC_LANG_SOURCE([[
253 #ifdef HAVE_GC_GC_H
254 # include <gc/gc.h>
255 #else
256 # include <gc.h>
257 #endif
258 #include <stdio.h>
259 extern unsigned GC_version;
260 int main(void){
261 unsigned min = ((6 << 16) | (4 << 8) | 0);
262 printf("%d.%d.%d ",GC_version >> 16, (GC_version >> 8) & 0xFF, GC_version & 0xFF);
263 if (GC_version>=min) return 0;
264 return 1;
265 }]])],
266 [gc_ok=yes],
267 [gc_ok=no]
268 )
269 AC_MSG_RESULT([$gc_ok])
270 fi
271 if test "x$gc_ok" != "xyes"; then
272 AC_MSG_ERROR([libgc (the Boehm Conservative Collector) 6.4+, is needed to compile inkscape -- http://www.hpl.hp.com/personal/Hans_Boehm/gc])
273 fi
275 dnl This check is to get a FIONREAD definition on Solaris 8
276 AC_CHECK_HEADERS([sys/filio.h])
279 AC_CHECK_HEADERS([malloc.h])
280 AC_CHECK_FUNCS([mallinfo], [
281 AC_CHECK_MEMBERS([struct mallinfo.usmblks,
282 struct mallinfo.fsmblks,
283 struct mallinfo.uordblks,
284 struct mallinfo.fordblks,
285 struct mallinfo.hblkhd],,,
286 [#include <malloc.h>])
287 ])
289 AC_PATH_PROG(FREETYPE_CONFIG, freetype-config, no)
290 if test "x$FREETYPE_CONFIG" = "xno"; then
291 AC_MSG_ERROR([Cannot find freetype-config])
292 fi
293 FREETYPE_CFLAGS=`$FREETYPE_CONFIG --cflags`
294 FREETYPE_LIBS=`$FREETYPE_CONFIG --libs`
295 AC_SUBST(FREETYPE_CFLAGS)
296 AC_SUBST(FREETYPE_LIBS)
298 dnl ******************************
299 dnl Win32
300 dnl ******************************
301 AC_MSG_CHECKING([for Win32 platform])
302 case "$host" in
303 *-*-mingw*)
304 platform_win32=yes
305 WIN32_CFLAGS="-mms-bitfields -DLIBXML_STATIC"
306 ;;
307 *)
308 platform_win32=no
309 ;;
310 esac
311 AC_MSG_RESULT([$platform_win32])
312 AM_CONDITIONAL(PLATFORM_WIN32, test "$platform_win32" = "yes")
313 AC_SUBST(WIN32_CFLAGS)
315 AC_MSG_CHECKING([for Solaris platform])
316 case "$host" in
317 *-solaris2.*)
318 platform_solaris=yes
319 solaris_version=`echo $host|sed -e 's/^.*-solaris2\.//' -e s'/\..*$//'`
320 CFLAGS="$CFLAGS -DSOLARIS=$solaris_version"
321 CXXFLAGS="$CXXFLAGS -DSOLARIS=$solaris_version"
322 ;;
323 *)
324 platform_solaris=no
325 ;;
326 esac
327 AC_MSG_RESULT([$platform_solaris])
328 AM_CONDITIONAL(PLATFORM_SOLARIS, test "$platform_solaris" = "yes")
330 dnl ******************************
331 dnl Xft checking
332 dnl ******************************
334 AC_ARG_WITH(xft,
335 AC_HELP_STRING([--with-xft], [use xft scalable font database (default is auto)]),
336 [with_xft=$withval], [with_xft=auto])
338 if test "x$with_xft" != "xno" ; then
339 dnl Test fontconfig package
340 PKG_CHECK_MODULES(XFT, fontconfig, xft_ok=yes, xft_ok=no)
341 if test "x$xft_ok" != "xyes"; then
342 dnl test xft package
343 PKG_CHECK_MODULES(XFT, xft, xft_ok=yes, xft_ok=no)
344 if test "x$xft_ok" != "xyes"; then
345 dnl Have to test xft presence
346 AC_CHECK_HEADER(X11/Xft/Xft.h, xft_ok=yes, xft_ok=no)
347 if test "x$xft_ok" != "xyes"; then
348 dnl No xft found
349 if test "x$with_xft" = "xyes"; then
350 dnl Xft was explicitly asked, so stop
351 AC_MSG_ERROR([--with-xft was specified, but appropriate development packages could not be found])
352 fi
353 else
354 dnl Working Xft1
355 XFT_LIBS="-L/usr/X11R6/lib -lXft "
356 fi
357 fi
358 fi
359 else
360 dnl Asked to ignore xft
361 xft_ok=no
362 fi
364 AC_SUBST(XFT_CFLAGS)
365 AC_SUBST(XFT_LIBS)
367 AM_CONDITIONAL(USE_XFT, test "x$xft_ok" = "xyes")
368 if test "x$xft_ok" = "xyes"; then
369 AC_DEFINE(WITH_XFT, 1, [Use Xft font database])
370 fi
372 dnl ******************************
373 dnl pangoft2 for xft
374 dnl ******************************
376 if test "x$xft_ok" = "xyes"; then
377 PKG_CHECK_MODULES(PANGOFT2, pangoft2, pango_ok=yes, pango_ok=no)
378 if test "x$pango_ok" = "xyes"; then
379 XFT_LIBS="$XFT_LIBS $PANGOFT2_LIBS"
380 fi
381 fi
384 dnl ******************************
385 dnl gnome vfs checking
386 dnl ******************************
388 AC_ARG_WITH(gnome-vfs,
389 AC_HELP_STRING([--with-gnome-vfs], [use gnome vfs for loading files]),
390 [with_gnome_vfs=$withval], [with_gnome_vfs=auto])
392 if test "x$with_gnome_vfs" = "xno"; then
393 dnl Asked to ignore gnome-vfs
394 gnome_vfs=no
395 else
396 dnl Have to test gnome-vfs presence
397 PKG_CHECK_MODULES(GNOME_VFS, gnome-vfs-2.0 >= 2.0, gnome_vfs=yes, gnome_vfs=no)
398 if test "x$gnome_vfs" != "xyes"; then
399 dnl No gnome-vfs found
400 if test "x$with_gnome_vfs" = "xyes"; then
401 dnl Gnome-VFS was explicitly asked for, so stop
402 AC_MSG_ERROR([--with-gnome-vfs was specified, but appropriate libgnomevfs development packages could not be found])
403 else
404 # gnome-vfs is no, tell us for the log file
405 AC_MSG_RESULT($gnome_vfs)
406 fi
407 fi
408 fi
410 AM_CONDITIONAL(USE_GNOME_VFS, test "x$gnome_vfs" = "xyes")
411 if test "x$gnome_vfs" = "xyes"; then
412 AC_DEFINE(WITH_GNOME_VFS, 1, [Use gnome vfs file load functionality])
413 fi
415 AC_SUBST(GNOME_VFS_CFLAGS)
416 AC_SUBST(GNOME_VFS_LIBS)
418 dnl ******************************
419 dnl libinkjar checking
420 dnl ******************************
422 AC_ARG_WITH(inkjar,
423 AC_HELP_STRING([--without-inkjar], [disable openoffice files (SVG jars)]),[with_ij=$withval], [with_ij=yes])
425 if test "x$with_ij" = "xyes"; then
426 AC_DEFINE(WITH_INKJAR, 1, [enable openoffice files (SVG jars)])
427 AC_C_BIGENDIAN
428 AC_CHECK_HEADERS(zlib.h)
429 ij=yes
430 else
431 ij=no
432 fi
433 AM_CONDITIONAL(INKJAR, test "$with_ij" = "yes")
435 ink_spell_pkg=
436 if pkg-config --exists gtkspell-2.0; then
437 ink_spell_pkg=gtkspell-2.0
438 AC_DEFINE(WITH_GTKSPELL, 1, [enable gtk spelling widget])
439 fi
441 dnl ******************************
442 dnl PERL checking
443 dnl ******************************
445 AC_MSG_CHECKING(for Perl development environment)
446 AC_ARG_WITH(perl,
447 AC_HELP_STRING([--with-perl], [use Perl for embedded scripting (EXPERIMENTAL)]),
448 [with_perl=$withval], [with_perl=skipped])
450 if test "x$with_perl" = "xyes"; then
451 checkPERL_CFLAGS=`perl -MExtUtils::Embed -e perl_inc 2>/dev/null`
452 if test "$?" -gt "0"; then
453 with_perl="no"
454 else
455 checkPERL_LIBS=`perl -MExtUtils::Embed -e ldopts 2>/dev/null`
456 if test "$?" -gt "0"; then
457 with_perl="no"
458 else
459 with_perl="yes"
460 fi
461 fi
462 fi
463 AC_MSG_RESULT([$with_perl])
464 if test "x$with_perl" = "xyes"; then
465 # Test that we actually have the perl libraries installed
466 oldCFLAGS="$CFLAGS"
467 oldLIBS="$LIBS"
468 CFLAGS="$CFLAGS $checkPERL_CFLAGS"
469 LIBS="$LIBS $checkPERL_LIBS"
470 AC_CHECK_FUNC([perl_parse],[
471 PERL_CFLAGS="$checkPERL_CFLAGS"
472 PERL_LIBS="$checkPERL_LIBS"
473 AC_DEFINE(WITH_PERL, 1, [use Perl for embedded scripting])
474 ],[
475 with_perl="no"
476 ])
477 CFLAGS="$oldCFLAGS"
478 LIBS="$oldLIBS"
479 fi
480 AM_CONDITIONAL(WITH_PERL, test "x$with_perl" = "xyes")
481 AC_SUBST(PERL_CFLAGS)
482 AC_SUBST(PERL_LIBS)
484 dnl ******************************
485 dnl Python checking
486 dnl ******************************
488 AC_MSG_CHECKING(for Python development environment)
489 AC_ARG_WITH(python,
490 AC_HELP_STRING([--with-python], [use Python for embedded scripting (EXPERIMENTAL)]),
491 [with_python=$withval], [with_python=skipped])
493 if test "x$with_python" = "xyes"; then
494 checkPYTHON_CFLAGS=`python -c "import distutils.sysconfig ; print '-I%s' % distutils.sysconfig.get_config_var('INCLUDEPY')" 2>/dev/null`
495 if test "$?" -gt "0"; then
496 with_python="no"
497 else
498 checkPYTHON_LIBS=`python -c "import distutils.sysconfig ; print '%s/%s %s' % (distutils.sysconfig.get_config_var('LIBPL'),distutils.sysconfig.get_config_var('LDLIBRARY'),distutils.sysconfig.get_config_var('LIBS'))" 2>/dev/null`
499 if test "$?" -gt "0"; then
500 with_python="no"
501 else
502 with_python="yes"
503 fi
504 fi
505 fi
506 AC_MSG_RESULT([$with_python])
507 if test "x$with_python" = "xyes"; then
508 # Test that we actually have the python libraries installed
509 oldCFLAGS="$CFLAGS"
510 oldLIBS="$LIBS"
511 CFLAGS="$CFLAGS $checkPYTHON_CFLAGS"
512 LIBS="$LIBS $checkPYTHON_LIBS"
513 AC_CHECK_FUNC([Py_Initialize],[
514 PYTHON_CFLAGS="$checkPYTHON_CFLAGS"
515 PYTHON_LIBS="$checkPYTHON_LIBS"
516 AC_DEFINE(WITH_PYTHON, 1, [use Python for embedded scripting])
517 ],[
518 with_python="no"
519 ])
520 CFLAGS="$oldCFLAGS"
521 LIBS="$oldLIBS"
522 fi
523 AM_CONDITIONAL(WITH_PYTHON, test "x$with_python" = "xyes")
524 AC_SUBST(PYTHON_CFLAGS)
525 AC_SUBST(PYTHON_LIBS)
527 dnl ******************************
528 dnl LittleCms checking
529 dnl ******************************
531 AC_ARG_ENABLE(lcms,
532 AC_HELP_STRING([--enable-lcms], [enable LittleCms for color management]),
533 [enable_lcms=$enableval], [enable_lcms=yes])
535 if test "x$enable_lcms" = "xno"; then
536 dnl Asked to ignore LittleCms
537 lcms=no
538 else
539 dnl Have to test LittleCms presence
540 PKG_CHECK_MODULES(LCMS, lcms >= 1.13, lcms=yes, lcms=no)
541 if test "x$lcms" != "xyes"; then
542 dnl No lcms found
543 if test "x$enable_lcms" = "xyes"; then
544 dnl LittleCms was explicitly asked for, so stop
545 AC_MSG_ERROR([--enable-lcms was specified, but appropriate LittleCms development packages could not be found])
546 else
547 # lcms is no, tell us for the log file
548 AC_MSG_RESULT($lcms)
549 fi
550 else
551 dnl Working lcms
552 LIBS="$LIBS $LCMS_LIBS"
553 AC_DEFINE(ENABLE_LCMS, 1, [Use LittleCms color management])
554 fi
555 fi
557 AC_SUBST(LCMS_CFLAGS)
558 AC_SUBST(LCMS_LIBS)
560 dnl ******************************
561 dnl Libpoppler checking
562 dnl ******************************
564 AC_ARG_ENABLE(poppler-cairo,
565 AC_HELP_STRING([--enable-poppler-cairo], [Enable libpoppler-cairo for rendering PDF preview]),
566 [enable_poppler_cairo=$enableval], [enable_poppler_cairo=yes])
568 POPPLER_CFLAGS=""
569 PKG_CHECK_MODULES(POPPLER, poppler >= 0.5.9, poppler=yes, poppler=no)
571 if test "x$poppler" = "xyes"; then
572 dnl Working libpoppler
573 dnl Have to test libpoppler-glib presence
574 PKG_CHECK_MODULES(POPPLER_GLIB, poppler-glib >= 0.5.9, poppler_glib=yes, poppler_glib=no)
575 if test "x$poppler_glib" = "xyes"; then
576 dnl Working libpoppler-glib found
577 dnl Check whether the Cairo SVG backend is available
578 PKG_CHECK_MODULES(CAIRO_SVG, cairo-svg, cairo_svg=yes, cairo_svg=no)
579 if test "x$cairo_svg" = "xyes"; then
580 POPPLER_LIBS="$POPPLER_LIBS $POPPLER_GLIB_LIBS "
581 fi
582 fi
583 if test "x$enable_poppler_cairo" = "xyes"; then
584 dnl Have to test libpoppler-cairo presence for PDF preview
585 dnl AC_CHECK_HEADER(Magick++.h, magick_ok=yes, magick_ok=no)
586 PKG_CHECK_MODULES(POPPLER_CAIRO, poppler-cairo >= 0.5.9, poppler_cairo=yes, poppler_cairo=no)
587 if test "x$poppler_glib" = "xyes" -a "x$poppler_cairo" = "xyes" -a \
588 "x$cairo_svg" = "xno"
589 then
590 POPPLER_LIBS="$POPPLER_LIBS $POPPLER_CAIRO_LIBS "
591 fi
592 fi
593 fi
595 if test "x$poppler" = "xyes"; then
596 LIBS="$LIBS $POPPLER_LIBS"
597 AC_DEFINE(HAVE_POPPLER, 1, [Use libpoppler for direct PDF import])
598 fi
599 if test "x$poppler_cairo" = "xyes" -a "x$poppler_glib" = "xyes"; then
600 AC_DEFINE(HAVE_POPPLER_CAIRO, 1, [Use libpoppler-cairo for rendering PDF preview])
601 fi
602 if test "x$poppler_glib" = "xyes" -a "x$cairo_svg" = "xyes"; then
603 AC_DEFINE(HAVE_POPPLER_GLIB, 1, [Use libpoppler-glib and Cairo-SVG for PDF import])
604 fi
605 AC_SUBST(POPPLER_CFLAGS)
606 AC_SUBST(POPPLER_LIBS)
608 PKG_CHECK_MODULES(POPPLER_GFXFONT, poppler >= 0.8.3, popplernew=yes, popplernew=no)
609 if test "x$popplernew" = "xyes"; then
610 AC_DEFINE(POPPLER_NEW_GFXFONT, 1, [Use GfxFont from Poppler >= 0.8.3])
611 fi
613 AC_MSG_CHECKING(for new color space API in Poppler)
614 ink_svd_CPPFLAGS=$CPPFLAGS
615 ink_svd_LIBS=$LIBS
616 CPPFLAGS="$CPPFLAGS $POPPLER_CFLAGS"
617 LIBS="$LIBS $POPPLER_LIBS"
618 popplercolor="no"
619 AC_COMPILE_IFELSE([
620 #include <GfxState.h>
622 int main() {
623 typedef GfxColorSpace *(*parse_p)(Object *, Gfx *);
624 parse_p p;
625 p = &GfxColorSpace::parse;
626 return 0;
627 }
628 ], [popplercolor=yes])
629 CPPFLAGS=$ink_svd_CPPFLAGS
630 LIBS=$ink_svd_LIBS
632 if test "x$popplercolor" = "xyes"; then
633 AC_DEFINE(POPPLER_NEW_COLOR_SPACE_API, 1, [Use color space API from Poppler >= 0.12.2])
634 AC_MSG_RESULT(yes)
635 else
636 AC_MSG_RESULT(no)
637 fi
639 dnl ******************************
640 dnl Inkboard dependency checking
641 dnl ******************************
643 dnl with_inkboard="no"
644 dnl with_inkboard_ssl="no"
646 dnl INKBOARD_CFLAGS=""
648 dnl AC_ARG_ENABLE(inkboard,
649 dnl AS_HELP_STRING([--enable-inkboard], [enable Inkboard online whiteboard facility (disabled by default)]),
650 dnl with_inkboard=$enableval,with_inkboard=no)
652 dnl if test "x$with_inkboard" = "xyes"; then
653 dnl with_inkboard="yes"
654 dnl AC_DEFINE(WITH_INKBOARD,1,[Build in Inkboard support])
656 dnl Test for OpenSSL
657 dnl PKG_CHECK_MODULES(INKBOARD, openssl, with_inkboard_ssl=yes, with_inkboard_ssl=no)
658 dnl if test "x$with_inkboard_ssl" = "xyes"; then
659 dnl OpenSSL found; enable SSL support in Pedro
660 dnl INKBOARD_CFLAGS="$INKBOARD_CFLAGS -DHAVE_SSL"
661 dnl RELAYTOOL([ssl], INKBOARD_LIBS, INKBOARD_CFLAGS, [inkboard_weak=yes])
662 dnl RELAYTOOL([crypto], INKBOARD_LIBS, INKBOARD_CFLAGS, [inkboard_weak=yes])
663 dnl AC_DEFINE(WITH_INKBOARD_SSL,1,[Build in SSL support for Inkboard])
664 dnl fi
665 dnl else
666 dnl with_inkboard="no"
667 dnl fi
669 dnl AM_CONDITIONAL(WITH_INKBOARD, test "x$with_inkboard" = "xyes")
671 INKBOARD_CFLAGS=""
672 INKBOARD_LIBS=""
673 AC_SUBST(INKBOARD_LIBS)
674 AC_SUBST(INKBOARD_CFLAGS)
676 dnl ******************************
677 dnl Check for libwpg for extension
678 dnl ******************************
680 PKG_CHECK_MODULES(LIBWPG, libwpg-0.1 libwpg-stream-0.1, with_libwpg=yes, with_libwpg=no)
681 if test "x$with_libwpg" = "xyes"; then
682 AC_DEFINE(WITH_LIBWPG,1,[Build in libwpg])
683 fi
684 AM_CONDITIONAL(WITH_LIBWPG, test "x$with_libwpg" = "xyes")
686 AC_SUBST(LIBWPG_LIBS)
687 AC_SUBST(LIBWPG_CFLAGS)
689 dnl ******************************
690 dnl Check for ImageMagick Magick++
691 dnl ******************************
693 PKG_CHECK_MODULES(IMAGEMAGICK, ImageMagick++, magick_ok=yes, magick_ok=no)
694 if test "x$magick_ok" = "xyes"; then
695 AC_DEFINE(WITH_IMAGE_MAGICK,1,[Image Magick++ support for bitmap effects])
696 fi
697 AM_CONDITIONAL(USE_IMAGE_MAGICK, test "x$magick_ok" = "xyes")
699 AC_SUBST(IMAGEMAGICK_LIBS)
700 AC_SUBST(IMAGEMAGICK_CFLAGS)
702 dnl ***********************************************************************************************************
703 dnl Check for a Cairo version that implements user-fonts feature (with a stable API, that is cairo > 1.7.6),
704 dnl so that we conditionally add SVGFonts support
705 dnl ***********************************************************************************************************
707 PKG_CHECK_MODULES(CAIRO_USER_FONTS, cairo > 1.7.6, cairouserfonts=yes, cairouserfonts=no)
708 if test "x$cairouserfonts" = "xyes"; then
709 AC_DEFINE(ENABLE_SVG_FONTS, 1, [SVG Fonts should be used])
710 fi
712 dnl ******************************
713 dnl Unconditional dependencies
714 dnl ******************************
716 dnl sigc++-2.0 >= 2.0.12: using "visit_each" not available in 2.0.10
717 if test $cc_vers_major -gt 3; then
718 min_sigc_version=2.0.12
719 else
720 min_sigc_version=2.0.11
721 fi
722 PKG_CHECK_MODULES(INKSCAPE, gdkmm-2.4 glibmm-2.4 giomm-2.4 gtkmm-2.4 >= 2.10.0 gtk+-2.0 libxml-2.0 >= 2.6.11 libxslt >= 1.0.15 cairo sigc++-2.0 >= $min_sigc_version $ink_spell_pkg gthread-2.0 >= 2.0 libpng >= 1.2 gsl)
724 # Check for Apple Mac OS X Carbon framework
725 carbon_ok=no
726 AC_MSG_CHECKING([for Mac OS X Carbon support])
727 AC_COMPILE_IFELSE([
728 #include <Carbon/Carbon.h>
729 #include <CoreServices/CoreServices.h>
730 ], [carbon_ok=yes])
731 AC_MSG_RESULT($carbon_ok)
732 if test "x$carbon_ok" = "xyes"; then
733 AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
734 CARBON_LDFLAGS="-framework Carbon"
735 AC_SUBST(CARBON_LDFLAGS)
736 fi
737 AM_CONDITIONAL(HAVE_CARBON, test "x$carbon_ok" = "xyes")
739 # Check for some boost header files
740 AC_CHECK_HEADERS([boost/concept_check.hpp], [], AC_MSG_ERROR([You need the boost package (e.g. libboost-dev)]))
742 PKG_CHECK_MODULES(CAIRO_PDF, cairo-pdf, cairo_pdf=yes, cairo_pdf=no)
743 if test "x$cairo_pdf" = "xyes"; then
744 AC_DEFINE(HAVE_CAIRO_PDF, 1, [Whether the Cairo PDF backend is available])
745 fi
747 dnl Shouldn't we test for libpng and libz?
748 if test "x$openmp_ok" = "xyes"; then
749 INKSCAPE_LIBS="$INKSCAPE_LIBS -lpng -lz -lgomp"
750 else
751 INKSCAPE_LIBS="$INKSCAPE_LIBS -lpng -lz"
752 fi
754 AC_CHECK_HEADER(popt.h,
755 [INKSCAPE_LIBS="$INKSCAPE_LIBS -lpopt"],
756 AC_MSG_ERROR([libpopt is required]))
758 dnl **************************
759 dnl Check for aspell
760 dnl ******************************
761 AC_CHECK_LIB(aspell, new_aspell_config, [AC_CHECK_HEADER(aspell.h, aspell_ok=yes, aspell_ok=no)], aspell_ok=no, -lz -lm)
762 if test "x$aspell_ok" = "xyes"; then
763 AC_DEFINE(HAVE_ASPELL, 1, [Use aspell for built-in spellchecker])
764 INKSCAPE_LIBS="$INKSCAPE_LIBS -laspell"
765 else
766 AC_MSG_CHECKING([Aspell not found, spell checker will be disabled])
767 fi
769 dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
770 sp_save_LIBS=$LIBS
771 LIBS="$LIBS $INKSCAPE_LIBS"
772 AC_CHECK_FUNCS(bind_textdomain_codeset)
773 dnl Check for gtk_window_fullscreen in gtk (>= 2.2)
774 AC_CHECK_FUNCS(gtk_window_set_default_icon_from_file)
775 AC_CHECK_FUNCS(gtk_window_fullscreen)
776 LIBS=$sp_save_LIBS
779 dnl Check for binary relocation support
780 dnl Hongli Lai <h.lai@chello.nl>
782 AC_ARG_ENABLE(binreloc,
783 [ --enable-binreloc compile with binary relocation support],
784 enable_binreloc=$enableval,enable_binreloc=no)
786 AC_MSG_CHECKING(whether binary relocation support should be enabled)
787 if test "$enable_binreloc" = "yes"; then
788 AC_MSG_RESULT(yes)
789 AC_MSG_CHECKING(for linker mappings at /proc/self/maps)
790 if test -e /proc/self/maps; then
791 AC_MSG_RESULT(yes)
792 else
793 AC_MSG_RESULT(no)
794 AC_MSG_ERROR(/proc/self/maps is not available. Binary relocation cannot be enabled.)
795 enable_binreloc="no"
796 fi
798 elif test "$enable_binreloc" = "auto"; then
799 AC_MSG_RESULT(yes when available)
800 AC_MSG_CHECKING(for linker mappings at /proc/self/maps)
801 if test -e /proc/self/maps; then
802 AC_MSG_RESULT(yes)
803 enable_binreloc=yes
805 AC_MSG_CHECKING(whether everything is installed to the same prefix)
806 if test "$bindir" = '${exec_prefix}/bin' -a "$sbindir" = '${exec_prefix}/sbin' -a \
807 "$datadir" = '${prefix}/share' -a "$libdir" = '${exec_prefix}/lib' -a \
808 "$libexecdir" = '${exec_prefix}/libexec' -a "$sysconfdir" = '${prefix}/etc'
809 then
810 AC_MSG_RESULT(yes)
811 else
812 AC_MSG_RESULT(no)
813 AC_MSG_NOTICE(Binary relocation support will be disabled.)
814 enable_binreloc=no
815 fi
817 else
818 AC_MSG_RESULT(no)
819 enable_binreloc=no
820 fi
822 elif test "$enable_binreloc" = "no"; then
823 AC_MSG_RESULT(no)
824 else
825 AC_MSG_RESULT([no (unknown value "$enable_binreloc")])
826 enable_binreloc=no
827 fi
828 AC_DEFINE(BR_PTHREADS,[0],[Use binreloc thread support?])
829 if test "$enable_binreloc" = "yes"; then
830 AC_DEFINE(ENABLE_BINRELOC,,[Use AutoPackage?])
831 fi
833 AC_ARG_ENABLE(osxapp,
834 [ --enable-osxapp compile with OSX .app data dir paths],
835 enable_osxapp=$enableval,enable_osxapp=no)
836 if test "$enable_osxapp" = "yes"; then
837 AC_DEFINE(ENABLE_OSX_APP_LOCATIONS,,[Build with OSX .app data dir paths?])
838 fi
840 dnl ******************************
841 dnl Reported by autoscan
842 dnl ******************************
843 AC_CHECK_FUNCS(pow)
844 # if we did not find pow(), see if it's in libm.
845 if test x"$ac_cv_func_pow" = x"no" ; then
846 AC_CHECK_LIB(m,pow)
847 fi
848 AC_CHECK_FUNCS(sqrt)
849 AC_CHECK_FUNCS(floor)
850 AC_CHECK_FUNCS(gettimeofday)
851 AC_CHECK_FUNCS(memmove)
852 AC_CHECK_FUNCS(memset)
853 AC_CHECK_FUNCS(mkdir)
854 AC_CHECK_FUNCS(strncasecmp)
855 AC_CHECK_FUNCS(strpbrk)
856 AC_CHECK_FUNCS(strrchr)
857 AC_CHECK_FUNCS(strspn)
858 AC_CHECK_FUNCS(strstr)
859 AC_CHECK_FUNCS(strtoul)
860 AC_CHECK_FUNCS(fpsetmask)
861 AC_CHECK_FUNCS(ecvt)
862 AC_CHECK_HEADERS(ieeefp.h)
863 AC_CHECK_HEADERS(fcntl.h)
864 AC_CHECK_HEADERS(libintl.h)
865 AC_CHECK_HEADERS(stddef.h)
866 AC_CHECK_HEADERS(sys/time.h)
867 AC_FUNC_STAT
868 AC_FUNC_STRFTIME
869 AC_FUNC_STRTOD
870 AC_HEADER_STAT
871 AC_HEADER_TIME
872 AC_STRUCT_TM
873 AC_TYPE_MODE_T
874 AC_TYPE_SIGNAL
876 dnl Work around broken gcc 3.3 (seen on OSX) where "ENABLE_NLS" isn't
877 dnl set correctly because the gettext function isn't noticed.
878 if test "$ac_cv_header_libintl_h" = "yes" &&
879 test "$ac_cv_func_bind_textdomain_codeset" = "yes" &&
880 test "$gt_cv_func_have_gettext" != "yes"; then
881 AC_DEFINE(ENABLE_NLS)
882 fi
884 dnl ******************************
885 dnl Compilation warnings
886 dnl ******************************
887 if test "$GXX" = "yes"; then
888 # Enable some warnings from g++.
890 # Rationale: a number of bugs in inkscape have been fixed by enabling g++
891 # warnings and addressing the produced warnings. Usually the committing
892 # developer is the best person to address the warnings.
894 ink_svd_CXXFLAGS="$CXXFLAGS"
895 CXXFLAGS="-Wno-unused-parameter $CXXFLAGS"
896 # -Wno-unused-parameter isn't accepted by gcc 2.95.
897 AC_COMPILE_IFELSE([int dummy;
898 ], , CXXFLAGS="-Wno-unused $ink_svd_CXXFLAGS",)
899 # Note: At least one bug has been caught from unused parameter warnings,
900 # so it might be worth trying not to disable it.
901 # One way of selectively disabling the warnings (i.e. only where the
902 # programmer deliberately isn't using the parameter, e.g. for a callback)
903 # is to remove the parameter name (leaving just its type), as is done
904 # in src/seltrans.cpp:sp_seltrans_handle_event; this indicates that the
905 # programmer deliberately has an unused parameter (e.g. because it's used
906 # as a callback or similar function pointer use).
908 # Add even more stuff
909 CXXFLAGS="-Wpointer-arith -Wcast-align -Wsign-compare -Woverloaded-virtual -Wswitch $CXXFLAGS"
911 fi
913 dnl ******************************
914 dnl libinkscape
915 dnl ******************************
916 dnl
917 dnl AC_ARG_ENABLE(libinkscape, AC_HELP_STRING([--enable-libinkscape], [Compile dynamic library (experimental)]), [splib=$enableval], [splib=no])
918 dnl
919 dnl AM_CONDITIONAL(ENABLE_LIBINKSCAPE, test "x$splib" != "xno")
920 dnl
922 AC_SUBST(INKSCAPE_CFLAGS)
923 AC_SUBST(INKSCAPE_LIBS)
925 dnl Define our data paths for config.h
926 AC_DEFINE_DIR([INKSCAPE_DATADIR], [datadir], [Base data directory])
927 AC_DEFINE_DIR([PACKAGE_LOCALE_DIR], [localedir], [Locatization directory])
929 AC_CONFIG_FILES([
930 Makefile
931 src/Makefile
932 src/check-header-compile
933 src/application/makefile
934 src/bind/makefile
935 src/debug/makefile
936 src/dialogs/makefile
937 src/display/makefile
938 src/dom/makefile
939 src/extension/implementation/makefile
940 src/extension/internal/makefile
941 src/extension/makefile
942 src/extension/script/makefile
943 src/filters/makefile
944 src/helper/makefile
945 src/io/makefile
946 src/libcroco/makefile
947 src/libgdl/makefile
948 src/libnr/makefile
949 src/libnrtype/makefile
950 src/libavoid/makefile
951 src/livarot/makefile
952 src/live_effects/makefile
953 src/live_effects/parameter/makefile
954 src/pedro/makefile
955 src/jabber_whiteboard/makefile
956 src/svg/makefile
957 src/trace/makefile
958 src/ui/cache/makefile
959 src/ui/dialog/makefile
960 src/ui/makefile
961 src/ui/view/makefile
962 src/ui/widget/makefile
963 src/util/makefile
964 src/widgets/makefile
965 src/xml/makefile
966 src/2geom/makefile
967 doc/Makefile
968 po/Makefile.in
969 share/Makefile
970 share/clipart/Makefile
971 share/examples/Makefile
972 share/extensions/Makefile
973 share/extensions/alphabet_soup/Makefile
974 share/extensions/Barcode/Makefile
975 share/extensions/Poly3DObjects/Makefile
976 share/extensions/test/Makefile
977 share/extensions/xaml2svg/Makefile
978 share/filters/Makefile
979 share/fonts/Makefile
980 share/gradients/Makefile
981 share/icons/Makefile
982 share/icons/application/Makefile
983 share/icons/application/16x16/Makefile
984 share/icons/application/22x22/Makefile
985 share/icons/application/24x24/Makefile
986 share/icons/application/32x32/Makefile
987 share/icons/application/48x48/Makefile
988 share/icons/application/256x256/Makefile
989 share/keys/Makefile
990 share/markers/Makefile
991 share/palettes/Makefile
992 share/patterns/Makefile
993 share/screens/Makefile
994 share/templates/Makefile
995 share/tutorials/Makefile
996 share/ui/Makefile
997 packaging/autopackage/default.apspec
998 inkscape.spec
999 Info.plist
1000 inkview.1
1001 ])
1003 AH_BOTTOM([
1006 ])
1008 AC_OUTPUT
1010 echo "
1011 Configuration:
1013 Source code location: ${srcdir}
1014 Destination path prefix: ${prefix}
1015 Compiler: ${CXX}
1016 CPPFLAGS: ${CPPFLAGS}
1017 CXXFLAGS: ${CXXFLAGS}
1018 CFLAGS: ${CFLAGS}
1019 LDFLAGS: ${LDFLAGS}
1021 Use Xft font database: ${xft_ok}
1022 Use gnome-vfs: ${gnome_vfs}
1023 Use openoffice files: ${ij}
1024 Use relocation support: ${enable_binreloc}
1025 Internal Python: ${with_python}
1026 Internal Perl: ${with_perl}
1027 Enable LittleCms: ${enable_lcms}
1028 Enable Poppler-Cairo: ${enable_poppler_cairo}
1029 ImageMagick Magick++: ${magick_ok}
1030 Libwpg: ${with_libwpg}
1031 "