program/configure.ac

   1 dnl RRDtool AutoConf script ...
   2 dnl ---------------------------
   3 dnl $Id$
   4 dnl
   5 dnl Created by Jeff Allen, Tobi Oetiker, Blair Zajac
   6 dnl
   7 dnl Inspiration from http://autoconf-archive.cryp.to
   8
   9 dnl tell automake the this script is for rrdtool
  10
  11 dnl Minimum Autoconf version required.
  12 AC_PREREQ(2.59)
  13
  14 dnl the official version number is
  15 dnl a.b.c
  16 AC_INIT([rrdtool],[1.4.2])
  17
  18 dnl for testing a numberical version number comes handy
  19 dnl the released version are
  20 dnl a.bccc
  21 dnl the devel versions will be something like
  22 dnl a.b999yymmddhh
  23 NUMVERS=1.4002
  24 AC_SUBST(NUMVERS)
  25
  26 dnl for the linker to understand which versions the library are compatible with
  27 dnl each other we must keep a separate library version cout of the format c:r:a.
  28 dnl - if only implementation changed but all interfaces are kept, do r++
  29 dnl - if only functionality was added do c++,r=0,a++
  30 dnl - if any functionality was removed do c++,r=0,a=0.
  31 dnl
  32 dnl see http://sourceware.org/autobook/autobook/autobook_91.html
  33 dnl
  34 LIBVERS=5:2:1
  35 AC_SUBST(LIBVERS)
  36
  37 AC_CANONICAL_TARGET
  38 m4_version_prereq(2.60, [AC_USE_SYSTEM_EXTENSIONS], [#])
  39 AM_INIT_AUTOMAKE
  40 AM_MAINTAINER_MODE
  41 # Enable silent build rules by default, requires at least
  42 # Automake-1.11. Disable by either passing --disable-silent-rules to
  43 # configure or passing V=1 to make
  44 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  45 AC_CONFIG_HEADERS([rrd_config.h])
  46 AC_CONFIG_MACRO_DIR([m4])
  47
  48 dnl all our local stuff like install scripts and include files
  49 dnl is in there
  50
  51
  52 dnl determine the type of system we are running on
  53
  54 AC_SUBST(VERSION)
  55
  56 AC_PREFIX_DEFAULT( /opt/rrdtool-$PACKAGE_VERSION )
  57
  58 dnl At the TOP of the HEADER
  59
  60 AH_TOP([
  61 #ifndef RRD_CONFIG_H
  62 #define RRD_CONFIG_H
  63
  64 /* IEEE can be prevented from raising signals with fpsetmask(0) */
  65 #undef MUST_DISABLE_FPMASK
  66
  67 /* IEEE math only works if SIGFPE gets actively set to IGNORE */
  68 #undef MUST_DISABLE_SIGFPE
  69
  70 /* realloc does not support NULL as argument */
  71 #undef NO_NULL_REALLOC
  72
  73 /* lets enable madvise defines in NetBSD */
  74 #if defined(__NetBSD__)
  75 # if !defined(_NETBSD_SOURCE)
  76 #  define _NETBSD_SOURCE
  77 # endif
  78 #endif
  79
  80 ])
  81
  82 AH_BOTTOM([
  83
  84 #ifdef MUST_HAVE_MALLOC_MALLOC_H
  85 #  include <malloc/malloc.h>
  86 #endif
  87
  88 #include "src/rrd_config_bottom.h"
  89
  90 #endif
  91 ])
  92
  93 dnl Process Special Options
  94 dnl -----------------------------------
  95
  96 dnl How the vertical axis label is printed
  97 AC_ARG_VAR(RRDGRAPH_YLEGEND_ANGLE,
  98  [Vertical label angle: -90.0 (default) or 90.0])
  99 AC_DEFINE_UNQUOTED(RRDGRAPH_YLEGEND_ANGLE,${RRDGRAPH_YLEGEND_ANGLE:-90.0},
 100  [Vertical label angle: -90.0 (default) or 90.0])
 101
 102 AC_ARG_ENABLE(rrdcgi,AS_HELP_STRING([--disable-rrdcgi],[disable building of rrdcgi]),
 103 [],[enable_rrdcgi=yes])
 104
 105 dnl Check if we run on a system that has fonts
 106 AC_ARG_WITH(rrd-default-font,
 107 [  --with-rrd-default-font=[OPTIONS]  set the full path to your default font.],
 108 [RRD_DEFAULT_FONT=$withval],[
 109   if test -d ${WINDIR:-nodir}/cour.ttf ; then
 110         RRD_DEFAULT_FONT=`cd $WINDIR;pwd`/cour.ttf
 111   else
 112         RRD_DEFAULT_FONT='"DejaVu Sans Mono,Bitstream Vera Sans Mono,monospace,Courier"'
 113   fi
 114 ])
 115
 116 dnl Use mmap in rrd_update instead of seek+write
 117 AC_ARG_ENABLE([mmap],
 118 AS_HELP_STRING([--disable-mmap],[disable mmap in rrd_update, use seek+write instead]),
 119 [],
 120 [enable_mmap=yes])
 121
 122 AC_ARG_ENABLE(pthread,AS_HELP_STRING([--disable-pthread],[disable multithread support]),
 123 [],[enable_pthread=yes])
 124
 125 AC_ARG_ENABLE(static-programs,
 126      AS_HELP_STRING([--enable-static-programs],[Build static programs]),
 127      [case "${enableval}" in
 128        yes) staticprogs=yes ;;
 129        no)  staticprogs=no ;;
 130        *) AC_MSG_ERROR(bad value ${enableval} for --enable-static-programs) ;;
 131      esac],[staticprogs=no])
 132 AM_CONDITIONAL(STATIC_PROGRAMS,[test "x$staticprogs" = "xyes"])
 133
 134
 135 CONFIGURE_PART(Audit Compilation Environment)
 136
 137
 138 dnl Check for the compiler and static/shared library creation.
 139 AC_PROG_CPP
 140 AC_PROG_CC
 141 AM_PROG_CC_C_O
 142 AC_PROG_LIBTOOL
 143
 144 dnl Try to detect/use GNU features
 145 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 146
 147 dnl check for -Werror separatly
 148 dnl (quite a few autotool checks do not work with -Werror; also, the
 149 dnl check for -Werror fails after checking and adding the other flags)
 150 AC_CACHE_CHECK([if gcc likes the -Werror flag], rd_cv_gcc_flag__Werror,
 151   [AC_COMPILE_IFELSE(
 152     [AC_LANG_PROGRAM([[]], [[return 0 ]])],
 153     [rd_cv_gcc_flag__Werror="yes"],
 154     [rd_cv_gcc_flag__Werror="no"])])
 155 if test "x$rd_cv_gcc_flag__Werror" = "xyes"; then
 156   WERROR="-Werror"
 157 else
 158   WERROR=""
 159 fi
 160 AC_SUBST(WERROR)
 161
 162 dnl which flags does the compiler support?
 163 if test "x$GCC" = "xyes"; then
 164   for flag in -fno-strict-aliasing -Wall -std=c99 -pedantic -Wundef -Wshadow -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Winline -Wold-style-definition -W; do
 165     oCFLAGS="$CFLAGS"
 166     CFLAGS="$CFLAGS $flag"
 167     cachename=rd_cv_gcc_flag_`echo $flag|sed 's/[[^A-Za-z]]/_/g'`
 168     AC_CACHE_CHECK([if gcc likes the $flag flag], $cachename,
 169        [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[return 0 ]])],[eval $cachename=yes],[eval $cachename=no])])
 170     if eval test \$$cachename = no; then
 171          CFLAGS="$oCFLAGS"
 172     fi
 173   done
 174 fi
 175
 176
 177
 178 AC_SUBST(RRD_DEFAULT_FONT)
 179
 180 CONFIGURE_PART(Checking for Header Files)
 181
 182 dnl Checks for header files.
 183 AC_HEADER_STDC
 184 AC_HEADER_DIRENT
 185 AC_CHECK_HEADERS(langinfo.h stdint.h inttypes.h libgen.h features.h sys/stat.h sys/types.h fcntl.h fp_class.h malloc.h unistd.h ieeefp.h math.h sys/times.h sys/param.h sys/resource.h signal.h float.h stdio.h stdlib.h errno.h string.h ctype.h)
 186
 187 dnl Checks for typedefs, structures, and compiler characteristics.
 188 AC_C_CONST
 189 AC_HEADER_TIME
 190 AC_STRUCT_TM
 191
 192 CONFIGURE_PART(Test Library Functions)
 193
 194 dnl Checks for libraries.
 195 AC_CHECK_FUNC(acos, , AC_CHECK_LIB(m, acos))
 196
 197
 198 dnl add pic flag in any case this makes sure all our code is relocatable
 199 eval `./libtool --config | grep pic_flag`
 200 CFLAGS="$CFLAGS $pic_flag"
 201
 202
 203 dnl Checks for library functions.
 204 AC_FUNC_STRFTIME
 205 AC_FUNC_VPRINTF
 206
 207 AC_C_BIGENDIAN
 208
 209 dnl for each function found we get a definition in config.h
 210 dnl of the form HAVE_FUNCTION
 211
 212 AC_CHECK_FUNCS(nl_langinfo tzset fsync mbstowcs opendir readdir chdir chroot getuid strerror snprintf vsnprintf vasprintf fpclass class fp_class isnan memmove strchr mktime getrusage gettimeofday)
 213
 214 AC_FUNC_STRERROR_R
 215
 216 CONFIGURE_PART(Map/Fadvis/Madvise checking)
 217
 218 dnl Could use these to know if we need to provide a prototype
 219 dnl AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 220
 221 dnl check for fdatasync. Solaris has fdatasync in the librt
 222
 223 AC_CHECK_FUNCS(fdatasync, [],  AC_CHECK_LIB(rt, fdatasync, [LIBS="${LIBS} -lrt"; AC_DEFINE(HAVE_FDATASYNC)],[]))
 224 dnl if there is no fdatasync we may get lucky with fsync
 225 AC_CHECK_FUNCS(fsync)
 226
 227 dnl check for socket and nsl solaris again ... we need this for the new rrd_daemon stuff
 228
 229 AC_CHECK_FUNCS(socket, [],  AC_CHECK_LIB(socket, socket, [LIBS="${LIBS} -lsocket"; AC_DEFINE(HAVE_SOCKET)],[]))
 230 AC_CHECK_FUNCS(getaddrinfo, [],  AC_CHECK_LIB(nsl, getaddrinfo, [LIBS="${LIBS} -lnsl"; AC_DEFINE(HAVE_GETADDRINFO)],[]))
 231
 232
 233
 234 dnl XXX: dunno about windows.. add AC_CHECK_FUNCS(munmap) there too?
 235 if test "x$enable_mmap" = "xyes"; then
 236   case "$host" in
 237   *cygwin*)
 238     # the normal mmap test does not work in cygwin
 239     AC_CHECK_FUNCS(mmap)
 240     if test "x$ac_cv_func_mmap" = "xyes"; then
 241       ac_cv_func_mmap_fixed_mapped=yes
 242     fi
 243   ;;
 244   *)
 245     AC_CHECK_HEADERS(sys/mman.h)
 246     AC_FUNC_MMAP
 247     AC_CHECK_FUNCS(mmap munmap msync)
 248     AC_CHECK_DECLS(madvise, [], [], [#ifdef HAVE_SYS_MMAN_H
 249                                      # include <sys/mman.h>
 250                                      #endif])
 251     if test "x$ac_cv_have_decl_madvise" = "xyes";
 252     then
 253       AC_CHECK_FUNCS(madvise)
 254     else
 255       AC_CHECK_FUNCS(posix_madvise)
 256       if test "x$ac_cv_func_posix_madvise" != "xyes"; then
 257         AC_MSG_WARN([madvise() nor posix_madvise() found.])
 258       fi
 259     fi
 260   ;;
 261   esac
 262   if test "x$ac_cv_func_mmap" != "xyes";
 263   then
 264     AC_MSG_ERROR([--enable-mmap requested but mmap() was not detected])
 265 dnl enable_mmap="no"
 266   fi
 267 fi
 268
 269 dnl can we use posix_fadvise
 270 AC_CHECK_DECLS(posix_fadvise, [], [], [#define _XOPEN_SOURCE 600
 271 #include <fcntl.h>])
 272 AC_CHECK_FUNCS(posix_fadvise)
 273
 274 CONFIGURE_PART(Libintl Processing)
 275
 276 AM_GNU_GETTEXT_VERSION(0.14.4)
 277 AM_GNU_GETTEXT()
 278
 279 CONFIGURE_PART(IEEE Math Checks)
 280
 281
 282 dnl actual code to check if this works
 283 AC_CHECK_FUNCS(fpclassify, ,
 284   [AC_MSG_CHECKING(for fpclassify with <math.h>)
 285     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 286 volatile int x;volatile float f; ]], [[x = fpclassify(f)]])],[AC_MSG_RESULT(yes)
 287       AC_DEFINE(HAVE_FPCLASSIFY)],[AC_MSG_RESULT(no)])])
 288
 289 AC_CHECK_FUNCS(isinf, ,
 290   [AC_MSG_CHECKING(for isinf with <math.h>)
 291     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 292 volatile int x;volatile float f;  ]], [[x = isinf(f)]])],[AC_MSG_RESULT(yes)
 293       AC_DEFINE(HAVE_ISINF)],[AC_MSG_RESULT(no)])])
 294
 295 dnl finite is BSD, isfinite is C99, so prefer the latter
 296 AC_CACHE_CHECK([whether isfinite is broken],[ac_cv_have_broken_isfinite],[
 297 AC_TRY_RUN([
 298 #ifdef HAVE_MATH_H
 299 #include <math.h>
 300 #endif
 301 #ifdef HAVE_FLOAT_H
 302 #include <float.h>
 303 #endif
 304 int main ()
 305 {
 306 #ifdef isfinite
 307 #ifdef LDBL_MAX
 308   if (!isfinite(LDBL_MAX)) return 1;
 309 #endif
 310 #ifdef DBL_MAX
 311   if (!isfinite(DBL_MAX)) return 1;
 312 #endif
 313 #endif
 314 return 0;
 315 }],[ac_cv_have_broken_isfinite=no],[ac_cv_have_broken_isfinite=yes],[
 316 case "${target}" in
 317   hppa*-*-hpux*) ac_cv_have_broken_isfinite=yes ;;
 318   *-solaris2.8) ac_cv_have_broken_isfinite=yes ;;
 319   *-solaris2.9) ac_cv_have_broken_isfinite=yes ;;
 320   *) ac_cv_have_broken_isfinite=no ;;
 321 esac])
 322 ])
 323
 324 dnl the test does not seem to work on solaris 2.8
 325 dnl so lets fix this by hand
 326 case "${target}" in
 327   *-solaris2.8) ac_cv_have_broken_isfinite=yes ;;
 328   *-solaris2.9) ac_cv_have_broken_isfinite=yes ;;
 329 esac
 330
 331 if test "x$ac_cv_have_broken_isfinite" = "xno"; then
 332   AC_DEFINE(HAVE_ISFINITE)
 333 else
 334   AC_CHECK_FUNCS(finite,[],
 335       [AC_CHECK_FUNCS(isfinite,[],
 336          [AC_MSG_CHECKING(for isfinite with <math.h>)
 337           AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 338 volatile int x;volatile float f;  ]],[[x = isfinite(f)]])],[AC_MSG_RESULT(yes)
 339                 AC_DEFINE(HAVE_ISFINITE)],[AC_MSG_RESULT(no)])])])
 340 fi
 341
 342 AC_FULL_IEEE
 343
 344 CONFIGURE_PART(Resolve Portability Issues)
 345
 346 CHECK_FOR_WORKING_MS_ASYNC
 347
 348 dnl Do we need getopt_long
 349
 350 dnl even when including our own getopt implementation
 351 dnl we may want to make sure we use the external
 352 dnl defined by libc to not run into linker resolve trouble
 353
 354 AC_CACHE_CHECK([for opterr], rd_cv_var_int_opterr,
 355 [AC_TRY_LINK([#include <unistd.h>],
 356   [extern int opterr; opterr = 1;],
 357   [rd_cv_var_int_opterr=yes],
 358   [rd_cv_var_int_opterr=no])])
 359 if test x"$rd_cv_var_int_opterr" = x"yes"; then
 360   AC_DEFINE(HAVE_INT_OPTERR, 1, [Define to 1 if you have the global variable 'int opterr'.])
 361 fi
 362
 363 build_getopt=no
 364 RRD_GETOPT_LONG="LIBC_HAS_GETOPT_LONG"
 365 AC_CHECK_FUNC(getopt_long,[],[
 366 RRD_GETOPT_LONG="getopt_long"
 367 build_getopt=yes
 368 ])
 369 AC_SUBST(RRD_GETOPT_LONG)
 370 AM_CONDITIONAL(BUILD_GETOPT,[test $build_getopt = yes])
 371
 372 dnl what does realloc do if it gets called with a NULL pointer
 373
 374 AC_CACHE_CHECK([if realloc can deal with NULL], rd_cv_null_realloc,
 375 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
 376               int main(void){
 377               char *x = NULL;
 378               x = realloc (x,10);
 379               if (x==NULL) return 1;
 380               return 0;
 381              }]])],[rd_cv_null_realloc=yes],[rd_cv_null_realloc=nope],[:])])
 382
 383 if test x"$rd_cv_null_realloc" = xnope; then
 384 AC_DEFINE(NO_NULL_REALLOC)
 385 fi
 386
 387 AC_LANG_PUSH(C)
 388 dnl solaris has some odd defines it needs in order to propperly compile ctime_r
 389 AC_MSG_CHECKING([if ctime_r need special care to act posixly correct])
 390 AC_LINK_IFELSE(
 391     AC_LANG_PROGRAM(
 392            [[#include <time.h>]],
 393            [[ctime_r(NULL,NULL,0)]]
 394                    ),
 395     [ CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
 396       AC_LINK_IFELSE(
 397           AC_LANG_PROGRAM(
 398                 [[#include <time.h>]],
 399                 [[ctime_r(NULL,NULL)]]
 400                          ),
 401           [AC_MSG_RESULT([yes, this seems to be solaris style])],
 402           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 403       )
 404     ],
 405     [ AC_LINK_IFELSE(
 406           AC_LANG_PROGRAM(
 407                 [[#include <time.h>]],
 408                 [[ctime_r(NULL,NULL)]]
 409                          ),
 410           [AC_MSG_RESULT(no)],
 411           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 412       )
 413     ]
 414 )
 415 AC_LANG_POP(C)
 416
 417 dnl Check for pthreads
 418 dnl http://autoconf-archive.cryp.to/acx_pthread.m4
 419
 420 AC_SUBST(MULTITHREAD_CFLAGS)
 421 AC_SUBST(MULTITHREAD_LDFLAGS)
 422
 423 if test $enable_pthread != no; then
 424  ACX_PTHREAD([
 425     MULTITHREAD_CFLAGS=$PTHREAD_CFLAGS
 426     MULTITHREAD_LDFLAGS=$PTHREAD_LIBS
 427              ],
 428              [])
 429 fi
 430
 431 dnl since we use lots of *_r functions all over the code we better
 432 dnl make sure they are known
 433
 434 if test  "x$x_rflag" != "xno"; then
 435    CPPFLAGS="$CPPFLAGS $x_rflag"
 436 fi
 437
 438 AM_CONDITIONAL(BUILD_MULTITHREAD,[test $enable_pthread != no])
 439
 440 AC_LANG_PUSH(C)
 441 dnl see if we have to include malloc/malloc.h
 442 AC_MSG_CHECKING([do we need malloc/malloc.h])
 443 AC_LINK_IFELSE(
 444     AC_LANG_PROGRAM(
 445            [[#include <stdlib.h>]],
 446            [[malloc(1)]]
 447                    ),
 448     [ AC_MSG_RESULT([nope, works out of the box]) ],
 449     [ AC_LINK_IFELSE(
 450           AC_LANG_PROGRAM(
 451                 [[#include <stdlib.h>
 452                   #include <malloc/malloc.h>]],
 453                 [[malloc(1)]]
 454                          ),[
 455            AC_DEFINE([MUST_HAVE_MALLOC_MALLOC_H])
 456            AC_MSG_RESULT([yes we do])],
 457           [AC_MSG_ERROR([Can not figure how to compile malloc])]
 458       )
 459     ]
 460 )
 461
 462 dnl is time_t 32 of 64 bit ?
 463 AC_DEFINE([TIME_T_IS_32BIT], [], [time_t is 32bit])
 464 AC_DEFINE([TIME_T_IS_64BIT], [], [time_t is 64bit])
 465 AC_MSG_CHECKING([the type of time_t])
 466 AC_RUN_IFELSE(
 467     AC_LANG_PROGRAM(
 468         [[#include <time.h>]],
 469         [[if (sizeof(time_t) != 4) return 1; ]]
 470         ),
 471     [ AC_MSG_RESULT([time_t is 32 bit])
 472       AC_DEFINE([TIME_T_IS_32BIT])
 473     ],
 474     [ AC_RUN_IFELSE(
 475         AC_LANG_PROGRAM(
 476         [[#include <time.h>]],
 477         [[if (sizeof(time_t) != 8) return 1; ]]
 478         ),
 479         [
 480           AC_MSG_RESULT([time_t is 64 bit])
 481           AC_DEFINE([TIME_T_IS_64BIT])
 482         ],
 483         [AC_MSG_ERROR([can not figure type of time_t])]
 484       )
 485     ]
 486 )
 487
 488 AC_LANG_POP(C)
 489
 490 CONFIGURE_PART(Find 3rd-Party Libraries)
 491
 492 AC_ARG_ENABLE(libdbi,AS_HELP_STRING([--disable-libdbi],[do not build in support for libdbi]),[have_libdbi=no],[
 493   XXX=$LIBS
 494   LIBS="$LIBS -ldbi -ldl"
 495   AC_MSG_CHECKING(for libdbi)
 496   AC_LINK_IFELSE(
 497     [AC_LANG_PROGRAM([[#include <dbi/dbi.h>]],
 498                      [[dbi_initialize(NULL)]]
 499                     )
 500     ],[AC_DEFINE(HAVE_LIBDBI,[1],[have got libdbi installed])
 501        AC_MSG_RESULT([yes])
 502        have_libdbi=yes
 503     ],[LIBS=$XXX
 504        AC_MSG_RESULT([no])
 505        have_libdbi=no
 506     ]
 507   )
 508 ])
 509 AM_CONDITIONAL(BUILD_LIBDBI,[test $have_libdbi != no])
 510
 511 AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
 512
 513
 514 CORE_LIBS="$LIBS"
 515
 516 dnl EX_CHECK_ALL(z,          zlibVersion,               zlib.h,                 zlib,        1.2.3,  http://www.gzip.org/zlib/, "")
 517 dnl EX_CHECK_ALL(png,        png_access_version_number, png.h,                  libpng,      1.2.10,  http://prdownloads.sourceforge.net/libpng/, "")
 518 dnl EX_CHECK_ALL(freetype,   FT_Init_FreeType,          ft2build.h,             freetype2,   2.1.10,  http://prdownloads.sourceforge.net/freetype/, /usr/include/freetype2)
 519 dnl EX_CHECK_ALL(fontconfig, FcInit,                    fontconfig.h,           fontconfig,  2.3.1,  http://fontconfig.org/release/, /usr/include)
 520 EX_CHECK_ALL(cairo,      cairo_font_options_create,     cairo.h,                cairo-png,   1.4.6,  http://cairographics.org/releases/, "")
 521 EX_CHECK_ALL(cairo,      cairo_svg_surface_create,      cairo-svg.h,            cairo-svg,   1.4.6,  http://cairographics.org/releases/, "")
 522 EX_CHECK_ALL(cairo,      cairo_pdf_surface_create,      cairo-pdf.h,            cairo-pdf,   1.4.6,  http://cairographics.org/releases/, "")
 523 EX_CHECK_ALL(cairo,      cairo_ps_surface_create,       cairo-ps.h,             cairo-ps,    1.4.6,  http://cairographics.org/releases/, "")
 524 EX_CHECK_ALL(glib-2.0,   glib_check_version,            glib.h,                 glib-2.0,    2.12.12, ftp://ftp.gtk.org/pub/glib/2.12/, "")
 525 EX_CHECK_ALL(pango-1.0,  pango_cairo_context_set_font_options,  pango/pango.h,  pangocairo,  1.17,    http://ftp.gnome.org/pub/GNOME/sources/pango/1.17, "")
 526 EX_CHECK_ALL(xml2,       xmlParseFile,                  libxml/parser.h,        libxml-2.0,        2.6.31,  http://xmlsoft.org/downloads.html, /usr/include/libxml2)
 527
 528 if test "$EX_CHECK_ALL_ERR" = "YES"; then
 529   AC_MSG_ERROR([Please fix the library issues listed above and try again.])
 530 fi
 531
 532 ALL_LIBS="$LIBS"
 533 LIBS=
 534
 535 AC_SUBST(CORE_LIBS)
 536 AC_SUBST(ALL_LIBS)
 537
 538 CONFIGURE_PART(Prep for Building Language Bindings)
 539
 540 dnl Check for Perl and friends
 541 PATH=$PATH:/usr/perl5/bin
 542 export PATH
 543 AC_PATH_PROG(PERL, perl, no)
 544 AC_PATH_PROG(POD2MAN, pod2man, no)
 545 AC_PATH_PROG(POD2HTML, pod2html, no)
 546
 547
 548 AC_ARG_ENABLE(perl,AS_HELP_STRING([--disable-perl],[do not build the perl modules]),
 549 [],[enable_perl=yes])
 550
 551
 552 AC_ARG_VAR(PERLCC, [C compiler for Perl modules])
 553 AC_ARG_VAR(PERLCCFLAGS, [CC flags for Perl modules])
 554 AC_ARG_VAR(PERLLD, [Linker for Perl modules])
 555 AC_ARG_VAR(PERLLDFLAGS, [LD flags for Perl modules])
 556
 557 if test "x$PERL" = "xno" -o  x$enable_perl = xno; then
 558         COMP_PERL=
 559 else
 560         COMP_PERL="perl_piped perl_shared"
 561         AC_MSG_CHECKING(for the perl version you are running)
 562         PERL_VERSION=`$PERL -MConfig -e 'print $Config{version}'`
 563         AC_MSG_RESULT($PERL_VERSION)
 564         if test -z "$PERLCC"; then
 565             AC_MSG_CHECKING(for the C compiler perl wants to use to build its modules)
 566             perlcc=`$PERL -MConfig -e 'print $Config{cc}'`
 567             AC_MSG_RESULT($perlcc)
 568             if test ! -x "$perlcc"; then
 569                 AC_PATH_PROG(PERL_CC, ${perlcc}, no)
 570                 if test "$PERL_CC" = "no"; then
 571                     AC_MSG_WARN([
 572 I would not find the Compiler ($perlcc) that was originally used to compile
 573 your perl binary. You should either make sure that this compiler is
 574 available on your system, pick an other compiler and set PERLCC
 575 appropriately, or use a different perl setup that was compiled locally.
 576
 577 I will disable the compilation of the RRDs perl module for now.
 578 ])
 579                     COMP_PERL="perl_piped"
 580                 fi
 581             fi
 582         fi
 583 fi
 584
 585 AC_MSG_CHECKING(Perl Modules to build)
 586 AC_MSG_RESULT(${COMP_PERL:-No Perl Modules will be built})
 587
 588 # Options to pass when configuring perl module
 589 langpref=$prefix
 590 test "$langpref" = '$(DESTDIR)NONE' && langpref='$(DESTDIR)'$ac_default_prefix
 591 test "$langpref" = "NONE" && langpref=$ac_default_prefix
 592
 593 PERL_MAKE_OPTIONS="PREFIX=$langpref LIB=$langpref/lib/perl/$PERL_VERSION"
 594
 595 dnl pass additional perl options when generating Makefile from Makefile.PL
 596 AC_ARG_ENABLE(perl-site-install,
 597 AS_HELP_STRING([--enable-perl-site-install],[by default the rrdtool perl modules are installed together with rrdtool in $prefix/lib/perl. You have to put a 'use lib qw($prefix/lib/perl)' into your scripts when you want to use them. When you set this option the perl modules will get installed wherever your perl setup thinks it is best.]),
 598 [PERL_MAKE_OPTIONS=],[])
 599
 600 if test ! -z "$PERLCC"; then
 601    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CC=$PERLCC"
 602
 603    if test ! -z "$PERLCCFLAGS"; then
 604        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CCFLAGS=$PERLCCFLAGS"
 605    fi
 606
 607    if test -z "$PERLLD"; then
 608        PERLLD=$PERLCC
 609    fi
 610    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LD=$PERLLD"
 611
 612    if test ! -z "$PERLLDFLAGS"; then
 613        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LDFLAGS=$PERLLDFLAGS"
 614    fi
 615 fi
 616
 617 AC_ARG_WITH(perl-options,
 618 [  --with-perl-options=[OPTIONS]  options to pass on command-line when
 619                           generating Makefile from Makefile.PL. If you set this
 620                           option, interesting things may happen unless you know
 621                           what you are doing!],
 622 [PERL_MAKE_OPTIONS=$withval])
 623
 624 AC_SUBST(PERL_MAKE_OPTIONS)
 625 AC_SUBST(PERL)
 626 AC_SUBST(COMP_PERL)
 627 AC_SUBST(PERL_VERSION)
 628
 629 dnl Check for Ruby.
 630 AC_PATH_PROG(RUBY, ruby, no)
 631
 632 AC_ARG_ENABLE(ruby,AS_HELP_STRING([--disable-ruby],[do not build the ruby modules]),
 633 [],[enable_ruby=yes])
 634
 635 AC_MSG_CHECKING(if ruby modules can be built)
 636
 637 if test "x$RUBY" = "xno" -o  x$enable_ruby = xno; then
 638         COMP_RUBY=
 639         AC_MSG_RESULT(No .. Ruby not found or disabled)
 640 else
 641         if $RUBY -e 'require "mkmf"' >/dev/null 2>&1; then
 642                 COMP_RUBY="ruby"
 643                 AC_MSG_RESULT(YES)
 644         else
 645                 COMP_RUBY=
 646                 AC_MSG_RESULT(Ruby found but mkmf is missing! Install the -dev package)
 647         fi
 648 fi
 649
 650 dnl pass additional ruby options when generating Makefile from Makefile.PL
 651 AC_ARG_ENABLE(ruby-site-install,
 652 AS_HELP_STRING([--enable-ruby-site-install],[by default the rrdtool ruby modules are installed together with rrdtool in $prefix/lib/ruby. You have to add $prefix/lib/ruby/$ruby_version/$sitearch to your $: variable for ruby to find the RRD.so file.]),
 653 [RUBY_MAKE_OPTIONS=],[RUBY_MAKE_OPTIONS="sitedir=$langpref/lib/ruby"])
 654
 655
 656 AC_ARG_WITH(ruby-options,
 657 [  --with-ruby-options=[OPTIONS]  options to pass on command-line when
 658                           generating Makefile from extconf.rb. If you set this
 659                           option, interesting things may happen unless you know
 660                           what you are doing!],
 661 [RUBY_MAKE_OPTIONS=$withval])
 662
 663 AC_SUBST(RUBY_MAKE_OPTIONS)
 664 AC_SUBST(RUBY)
 665 AC_SUBST(COMP_RUBY)
 666
 667 dnl Check for Lua.
 668 AC_PATH_PROG(LUA, lua, no)
 669
 670 AC_ARG_ENABLE(lua,AS_HELP_STRING([--disable-lua],[do not build the lua modules]),
 671 [],[enable_lua=yes])
 672
 673 COMP_LUA=
 674 if test "$LUA" = "no" -o "$enable_lua" = "no"; then
 675   enable_lua=no
 676 else
 677   AC_MSG_CHECKING(for lua >= 5.0)
 678   read LUA_MAJOR LUA_MINOR LUA_POINT <<LUA_EOF
 679     $($LUA -v 2>&1 | cut -f2 -d' ' | sed -e 's/\./ /g')
 680 LUA_EOF
 681   if test 0$LUA_MAJOR -lt 5; then
 682     AC_MSG_RESULT([no, version found is $LUA_MAJOR.$LUA_MINOR])
 683   else
 684     AC_MSG_RESULT([$LUA_MAJOR.$LUA_MINOR found])
 685     lua_vdot=$LUA_MAJOR.$LUA_MINOR
 686     lua_vndot=$LUA_MAJOR$LUA_MINOR
 687     lua_version=$LUA_MAJOR.$LUA_MINOR.$LUA_POINT
 688     AC_CHECK_HEADERS(lua$lua_vndot/lua.h,
 689       [AC_CHECK_HEADERS(lua$lua_vndot/lualib.h,
 690         [AC_CHECK_HEADER(lua$lua_vndot/lauxlib.h,
 691           [lua_headerdir=lua$lua_vndot],
 692           [])],
 693         [])],
 694       [AC_CHECK_HEADERS(lua$lua_vdot/lua.h,
 695         [AC_CHECK_HEADERS(lua$lua_vdot/lualib.h,
 696           [AC_CHECK_HEADER(lua$lua_vdot/lauxlib.h,
 697             [lua_headerdir=lua$lua_vdot],
 698             [])],
 699           [])],
 700         [AC_CHECK_HEADERS(lua.h,
 701           [AC_CHECK_HEADERS(lualib.h,
 702             [AC_CHECK_HEADER(lauxlib.h,
 703               [lua_headerdir=""],
 704               [lua_headerdir="no"])],
 705             [])],
 706           [])])])
 707
 708     if test "$lua_headerdir" = "no"; then
 709       enable_lua=no
 710     else
 711       COMP_LUA=lua
 712     fi
 713
 714     if test "$COMP_LUA" != "lua"; then
 715       enable_lua=no
 716       AC_MSG_WARN([Lua $lua_vdot found but not lua.h, lualib.h and lauxlib.h! Please install the -dev packages for Lua $lua_vdot])
 717     else
 718       # OK, headers found, let's check the libraries (LIBS is not used)
 719       LIBS=
 720       lua_havelib=no
 721       LUA_HAVE_COMPAT51=DONT_HAVE_COMPAT51
 722       AC_SEARCH_LIBS(lua_call, lua$lua_vdot lua$lua_vndot lua,
 723         [AC_SEARCH_LIBS(luaL_register, lua$lua_vdot lua$lua_vndot lua,
 724           [lua_havelib=LUA$lua_vndot],
 725           [AC_SEARCH_LIBS(luaL_module, lualib$lua_vndot lualib$lua_vdot lualib,
 726             [lua_havelib=$lua_vndot; $LUA -l compat-5.1 2>/dev/null;
 727              test "$?" = "0" && LUA_HAVE_COMPAT51=HAVE_COMPAT51],
 728             [AC_SEARCH_LIBS(luaL_openlib, lualib$lua_vdot lualib$lua_vndot lualib,
 729               [lua_havelib=$lua_vndot],
 730               [COMP_LUA=], [-lm])], [-lm])], [-lm])],
 731         [COMP_LUA=], [-lm])
 732       lua_libs=$LIBS
 733       LIBS=
 734
 735       # Options to pass when configuring Lua module
 736       if test  "$lua_havelib" != "no"; then
 737         # OK, headers and libs found. Try to set lua flags
 738         # and modules installation dirs with pkg-config
 739         if test "$PKGCONFIG" != "no"; then
 740           if test "$lua_vndot" = "50"; then
 741             lua_pkg_prefix=lualib
 742           else
 743             lua_pkg_prefix=lua
 744           fi
 745           # try with dot, without dot and finally without version
 746           for f in $lua_pkg_prefix$lua_vdot $lua_pkg_prefix$lua_vndot $lua_pkg_prefix; do
 747             lua_exec_prefix=`$PKGCONFIG --variable=prefix $f 2>/dev/null`
 748             # same binaries?
 749             if test "$lua_exec_prefix/bin/lua" = "$LUA"; then
 750                 # OK, found CFLAGS. Get Lua LFLAGS and modules install dir
 751                 LUA_CFLAGS=`$PKGCONFIG --cflags $f 2>/dev/null`
 752                 LUA_LFLAGS=`$PKGCONFIG --libs $f 2>/dev/null`
 753                 LUA_INSTALL_CMOD=`$PKGCONFIG --variable=INSTALL_CMOD $f 2>/dev/null`
 754                 LUA_INSTALL_LMOD=`$PKGCONFIG --variable=INSTALL_LMOD $f 2>/dev/null`
 755                 break
 756             fi
 757           done
 758         fi
 759
 760         LUA_RRD_LIBDIR="$langpref/lib/lua/$lua_vdot"
 761         # if lua 5.0 can't find compat-5.1, force installation of
 762         # compat-5.1.lua together with RRDtool.
 763         if test "$lua_vdot" = "5.0" -a "$LUA_HAVE_COMPAT51" != "HAVE_COMPAT51"; then
 764           lua_need_compat51=1
 765           LUA_INSTALL_LMOD="$LUA_RRD_LIBDIR"
 766         fi
 767
 768         # if not set with pkg-config, use default values in src packages compat-5.1, lua 5.1
 769         if test "$LUA_CFLAGS" = ""; then
 770           AC_MSG_WARN(Setting Lua include and lib flags to defaults in compat-5.1 and lua 5.1 sources)
 771           LUA_CFLAGS="-I/usr/local/include -I/usr/local/include/lua -I/usr/local/include/lua/$lua_vdot"
 772           LUA_LFLAGS="-L/usr/local/lib -L/usr/local/lib/lua -L/usr/local/lib/lua/$lua_vdot $lua_libs"
 773           LUA_INSTALL_CMOD="/usr/local/lib/lua/$lua_vdot"
 774         fi
 775
 776         dnl pass additional lua options
 777         dnl if lua-site-install is not set, overwrite LUA_INSTALL_CMOD already
 778         dnl found and install together with RRDtool, under $langpref.
 779         AC_ARG_ENABLE(lua-site-install,
 780         AS_HELP_STRING([--enable-lua-site-install],[by default the lua module is installed together with rrdtool in $prefix/lib/lua/$lua_version. You have to add $prefix/lib/lua/$lua_version/?.so to package.cpath for lua to find 'rrd.so'. For lua 5.0 you may also need to change LUA_PATH to the same dir, to require 'compat-5.1'. When you set this option the lua modules will get installed wherever your Lua setup thinks it is best. WARNING: if you set this option, system lua modules compat-5.1.lua and rrd.so, if any, may be overwritten.]),
 781         [],
 782         [LUA_INSTALL_CMOD="$LUA_RRD_LIBDIR"; LUA_INSTALL_LMOD="$LUA_RRD_LIBDIR"])
 783
 784         LUA_DEFINES="-DLUA$lua_vndot -D$LUA_HAVE_COMPAT51"
 785         AC_SUBST(LUA)
 786         AC_SUBST(COMP_LUA)
 787         AC_SUBST(LUA_INSTALL_CMOD)
 788         AC_SUBST(LUA_INSTALL_LMOD)
 789         AC_SUBST(LUA_CFLAGS)
 790         AC_SUBST(LUA_LFLAGS)
 791         AC_SUBST(LUA_DEFINES)
 792       else
 793         enable_lua=no
 794         AC_MSG_RESULT([Lua headers found but not the libraries! Please reinstall the dev packages for Lua $LUA_MAJOR.$LUA_MINOR])
 795       fi
 796     fi
 797   fi
 798 fi
 799 dnl If Lua 5.0, we need compat-5.1. Add ours unless already
 800 dnl integrated as in Debian/Ubuntu 5.0 -dev packages.
 801 AM_CONDITIONAL(LUA_NEED_OUR_COMPAT51,
 802       [test "$lua_vdot" = "5.0" -a "$LUA_HAVE_COMPAT51" != "HAVE_COMPAT51"])
 803 AM_CONDITIONAL(LUA_SITE_CINSTALL, [test "$LUA_INSTALL_CMOD" != "$LUA_RRD_LIBDIR"])
 804 AM_CONDITIONAL(LUA_SITE_LINSTALL, [test "$LUA_INSTALL_LMOD" != "$LUA_RRD_LIBDIR"])
 805 AM_CONDITIONAL(LUA50, [test "$lua_vndot" = "50"])
 806 AM_CONDITIONAL(BUILD_LUA, [test "$enable_lua" = "yes"])
 807
 808 enable_tcl_site=no
 809
 810 AC_ARG_ENABLE(tcl,AS_HELP_STRING([--disable-tcl],[do not build the tcl modules]),
 811 [],[enable_tcl=yes])
 812
 813 if test  "$enable_tcl" = "yes"; then
 814   dnl Check for Tcl.
 815   withval=""
 816   AC_ARG_WITH(tcllib,[  --with-tcllib=DIR       location of the tclConfig.sh])
 817   enable_tcl=no
 818   for dir in $withval /usr/lib /usr/local/lib /usr/lib/tcl8.4 /usr/lib/tcl8.3 ; do
 819     AC_MSG_CHECKING(for tclConfig.sh in $dir)
 820     if test -f "$dir/tclConfig.sh" ; then
 821         tcl_config=$dir/tclConfig.sh
 822         enable_tcl=yes
 823         AC_MSG_RESULT(yes)
 824         break
 825     else
 826         AC_MSG_RESULT(no)
 827     fi
 828   done
 829
 830   if test "$enable_tcl" = "no"; then
 831         AC_MSG_WARN([tclConfig.sh not found - Tcl interface will not be built])
 832   else
 833         . $tcl_config
 834         TCL_PACKAGE_DIR="$TCL_PACKAGE_PATH/tclrrd$VERSION"
 835         if test -n "$TCL_INC_DIR"; then
 836           TCL_INCLUDE_SPEC="$TCL_INCLUDE_SPEC -I$TCL_INC_DIR"
 837         fi
 838   fi
 839   AC_ARG_ENABLE(tcl,AS_HELP_STRING([--enable-tcl-site],[install the tcl extension in the tcl tree]),
 840   [],[enable_tcl_site=yes])
 841
 842 fi
 843
 844 AM_CONDITIONAL(BUILD_TCL, test "$enable_tcl" = "yes" )
 845 AM_CONDITIONAL(BUILD_TCL_SITE, test "$enable_tcl_site" = "yes" )
 846
 847
 848 AC_SUBST(TCL_PREFIX)
 849 AC_SUBST(TCL_SHLIB_CFLAGS)
 850 AC_SUBST(TCL_SHLIB_LD)
 851 AC_SUBST(TCL_SHLIB_SUFFIX)
 852 AC_SUBST(TCL_PACKAGE_PATH)
 853 AC_SUBST(TCL_LD_SEARCH_FLAGS)
 854 AC_SUBST(TCL_STUB_LIB_SPEC)
 855 AC_SUBST(TCL_VERSION)
 856 AC_SUBST(TCL_PACKAGE_DIR)
 857 AC_SUBST(TCL_INCLUDE_SPEC)
 858
 859 AC_ARG_ENABLE(python,AS_HELP_STRING([--disable-python],[do not build the python modules]),
 860 [],[enable_python=yes])
 861
 862 if test  "$enable_python" = "yes"; then
 863 dnl Check for python
 864 AM_PATH_PYTHON(2.3,[],[enable_python=no])
 865 AM_CHECK_PYTHON_HEADERS(,[enable_python=no;AC_MSG_WARN(could not find Python headers)])
 866 fi
 867
 868 if test  x$enable_python = xno; then
 869         COMP_PYTHON=
 870 else
 871         COMP_PYTHON="python"
 872 fi
 873
 874 AC_SUBST(COMP_PYTHON)
 875
 876 dnl Check for nroff
 877 AC_PATH_PROGS(NROFF, gnroff nroff)
 878 AC_PATH_PROGS(TROFF, groff troff)
 879
 880 AC_ARG_VAR(RRDDOCDIR, [[DATADIR/doc/PACKAGE-VERSION] Documentation directory])
 881 if test -z "$RRDDOCDIR"; then
 882    RRDDOCDIR='${datadir}/doc/${PACKAGE}-${VERSION}'; fi
 883
 884
 885 CONFIGURE_PART(Apply Configuration Information)
 886
 887 AC_CONFIG_FILES([examples/shared-demo.pl])
 888 AC_CONFIG_FILES([examples/piped-demo.pl])
 889 AC_CONFIG_FILES([examples/stripes.pl])
 890 AC_CONFIG_FILES([examples/bigtops.pl])
 891 AC_CONFIG_FILES([examples/minmax.pl])
 892 AC_CONFIG_FILES([examples/4charts.pl])
 893 AC_CONFIG_FILES([examples/perftest.pl])
 894 AC_CONFIG_FILES([examples/Makefile])
 895 AC_CONFIG_FILES([examples/rrdcached/Makefile])
 896 AC_CONFIG_FILES([doc/Makefile])
 897 AC_CONFIG_FILES([po/Makefile.in])
 898 AC_CONFIG_FILES([intl/Makefile])
 899 AC_CONFIG_FILES([src/Makefile])
 900 AC_CONFIG_FILES([src/librrd.sym.in])
 901 AC_CONFIG_FILES([src/librrd.pc])
 902 AC_CONFIG_FILES([bindings/Makefile])
 903 AC_CONFIG_FILES([bindings/tcl/Makefile])
 904 AC_CONFIG_FILES([bindings/tcl/ifOctets.tcl])
 905 AC_CONFIG_FILES([Makefile])
 906 AC_CONFIG_FILES([bindings/lua/Makefile])
 907
 908 AC_CONFIG_COMMANDS([default],[[ chmod +x examples/*.pl]],[[]])
 909
 910 dnl intl requires our config to be called config.h. indulge it.
 911 AC_CONFIG_COMMANDS_POST([ test -f config.h || ln -s rrd_config.h config.h ])
 912
 913 AC_OUTPUT
 914
 915 AC_MSG_CHECKING(in)
 916 AC_MSG_RESULT(and out again)
 917
 918 echo $ECHO_N "ordering CD from http://tobi.oetiker.ch/wish $ECHO_C" 1>&6
 919 sleep 1
 920 echo $ECHO_N ".$ECHO_C" 1>&6
 921 sleep 1
 922 echo $ECHO_N ".$ECHO_C" 1>&6
 923 sleep 1
 924 echo $ECHO_N ".$ECHO_C" 1>&6
 925 sleep 1
 926 echo $ECHO_N ".$ECHO_C" 1>&6
 927 sleep 1
 928 AC_MSG_RESULT([ just kidding ;-)])
 929 echo
 930 echo "----------------------------------------------------------------"
 931 echo "Config is DONE!"
 932 echo
 933 echo "          With MMAP IO: $enable_mmap"
 934 echo "      Build rrd_getopt: $build_getopt"
 935 echo "       Static programs: $staticprogs"
 936 echo "          Perl Modules: $COMP_PERL"
 937 echo "           Perl Binary: $PERL"
 938 echo "          Perl Version: $PERL_VERSION"
 939 echo "          Perl Options: $PERL_MAKE_OPTIONS"
 940 echo "          Ruby Modules: $COMP_RUBY"
 941 echo "           Ruby Binary: $RUBY"
 942 echo "          Ruby Options: $RUBY_MAKE_OPTIONS"
 943 echo "    Build Lua Bindings: $enable_lua"
 944 if test "$enable_lua" = "yes"; then
 945 echo "            Lua Binary: $LUA"
 946 echo "           Lua Version: $lua_version"
 947 echo "     Lua C-modules dir: $LUA_INSTALL_CMOD"
 948 if test "$lua_need_compat51" = "1"; then
 949 echo "   Lua Lua-modules dir: $LUA_INSTALL_LMOD"
 950 fi
 951 fi
 952 echo "    Build Tcl Bindings: $enable_tcl"
 953 echo " Build Python Bindings: $enable_python"
 954 echo "          Build rrdcgi: $enable_rrdcgi"
 955 echo "       Build librrd MT: $enable_pthread"
 956 echo "           Use gettext: $USE_NLS"
 957 echo "           With libDBI: $have_libdbi"
 958 echo
 959 echo "             Libraries: $ALL_LIBS"
 960 echo
 961 echo "Type 'make' to compile the software and use 'make install' to "
 962 echo "install everything to: $prefix."
 963 echo
 964 echo "       ... that wishlist is NO JOKE. If you find RRDtool useful"
 965 echo "make me happy. Go to http://tobi.oetiker.ch/wish and"
 966 echo "place an order."
 967 echo
 968 echo "                               -- Tobi Oetiker <tobi@oetiker.ch>"
 969 echo "----------------------------------------------------------------"