git-gui/lib/blame.tcl

   1 # git-gui blame viewer
   2 # Copyright (C) 2006, 2007 Shawn Pearce
   3
   4 class blame {
   5
   6 image create photo ::blame::img_back_arrow -data {R0lGODlhGAAYAIUAAPwCBEzKXFTSZIz+nGzmhGzqfGTidIT+nEzGXHTqhGzmfGzifFzadETCVES+VARWDFzWbHzyjAReDGTadFTOZDSyRDyyTCymPARaFGTedFzSbDy2TCyqRCyqPARaDAyCHES6VDy6VCyiPAR6HCSeNByWLARyFARiDARqFGTifARiFAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAACH5BAEAAAAALAAAAAAYABgAAAajQIBwSCwaj8ikcsk0BppJwRPqHEypQwHBis0WDAdEFyBIKBaMAKLBdjQeSkFBYTBAIvgEoS6JmhUTEwIUDQ4VFhcMGEhyCgoZExoUaxsWHB0THkgfAXUGAhoBDSAVFR0XBnCbDRmgog0hpSIiDJpJIyEQhBUcJCIlwA22SSYVogknEg8eD82qSigdDSknY0IqJQXPYxIl1dZCGNvWw+Dm510GQQAh/mhDcmVhdGVkIGJ5IEJNUFRvR0lGIFBybyB2ZXJzaW9uIDIuNQ0KqSBEZXZlbENvciAxOTk3LDE5OTguIEFsbCByaWdodHMgcmVzZXJ2ZWQuDQpodHRwOi8vd3d3LmRldmVsY29yLmNvbQA7}
   7
   8 # Persistant data (survives loads)
   9 #
  10 field history {}; # viewer history: {commit path}
  11 field header    ; # array commit,key -> header field
  12
  13 # Tk UI control paths
  14 #
  15 field w          ; # top window in this viewer
  16 field w_back     ; # our back button
  17 field w_path     ; # label showing the current file path
  18 field w_columns  ; # list of all column widgets in the viewer
  19 field w_line     ; # text column: all line numbers
  20 field w_amov     ; # text column: annotations + move tracking
  21 field w_asim     ; # text column: annotations (simple computation)
  22 field w_file     ; # text column: actual file data
  23 field w_cviewer  ; # pane showing commit message
  24 field status     ; # status mega-widget instance
  25 field old_height ; # last known height of $w.file_pane
  26
  27 # Tk UI colors
  28 #
  29 variable active_color #c0edc5
  30 variable group_colors {
  31         #d6d6d6
  32         #e1e1e1
  33         #ececec
  34 }
  35
  36 # Switches for original location detection
  37 #
  38 variable original_options [list -C -C]
  39 if {[git-version >= 1.5.3]} {
  40         lappend original_options -w ; # ignore indentation changes
  41 }
  42
  43 # Current blame data; cleared/reset on each load
  44 #
  45 field commit               ; # input commit to blame
  46 field path                 ; # input filename to view in $commit
  47
  48 field current_fd        {} ; # background process running
  49 field highlight_line    -1 ; # current line selected
  50 field highlight_column  {} ; # current commit column selected
  51 field highlight_commit  {} ; # sha1 of commit selected
  52
  53 field total_lines       0  ; # total length of file
  54 field blame_lines       0  ; # number of lines computed
  55 field amov_data            ; # list of {commit origfile origline}
  56 field asim_data            ; # list of {commit origfile origline}
  57
  58 field r_commit             ; # commit currently being parsed
  59 field r_orig_line          ; # original line number
  60 field r_final_line         ; # final line number
  61 field r_line_count         ; # lines in this region
  62
  63 field tooltip_wm        {} ; # Current tooltip toplevel, if open
  64 field tooltip_t         {} ; # Text widget in $tooltip_wm
  65 field tooltip_timer     {} ; # Current timer event for our tooltip
  66 field tooltip_commit    {} ; # Commit(s) in tooltip
  67
  68 constructor new {i_commit i_path} {
  69         global cursor_ptr
  70         variable active_color
  71         variable group_colors
  72
  73         set commit $i_commit
  74         set path   $i_path
  75
  76         make_toplevel top w
  77         wm title $top "[appname] ([reponame]): File Viewer"
  78
  79         frame $w.header -background gold
  80         label $w.header.commit_l \
  81                 -text {Commit:} \
  82                 -background gold \
  83                 -anchor w \
  84                 -justify left
  85         set w_back $w.header.commit_b
  86         label $w_back \
  87                 -image ::blame::img_back_arrow \
  88                 -borderwidth 0 \
  89                 -relief flat \
  90                 -state disabled \
  91                 -background gold \
  92                 -activebackground gold
  93         bind $w_back <Button-1> "
  94                 if {\[$w_back cget -state\] eq {normal}} {
  95                         [cb _history_menu]
  96                 }
  97                 "
  98         label $w.header.commit \
  99                 -textvariable @commit \
 100                 -background gold \
 101                 -anchor w \
 102                 -justify left
 103         label $w.header.path_l \
 104                 -text {File:} \
 105                 -background gold \
 106                 -anchor w \
 107                 -justify left
 108         set w_path $w.header.path
 109         label $w_path \
 110                 -background gold \
 111                 -anchor w \
 112                 -justify left
 113         pack $w.header.commit_l -side left
 114         pack $w_back -side left
 115         pack $w.header.commit -side left
 116         pack $w_path -fill x -side right
 117         pack $w.header.path_l -side right
 118
 119         panedwindow $w.file_pane -orient vertical
 120         frame $w.file_pane.out
 121         frame $w.file_pane.cm
 122         $w.file_pane add $w.file_pane.out \
 123                 -sticky nsew \
 124                 -minsize 100 \
 125                 -height 100 \
 126                 -width 100
 127         $w.file_pane add $w.file_pane.cm \
 128                 -sticky nsew \
 129                 -minsize 25 \
 130                 -height 25 \
 131                 -width 100
 132
 133         set w_line $w.file_pane.out.linenumber_t
 134         text $w_line \
 135                 -takefocus 0 \
 136                 -highlightthickness 0 \
 137                 -padx 0 -pady 0 \
 138                 -background white -borderwidth 0 \
 139                 -state disabled \
 140                 -wrap none \
 141                 -height 40 \
 142                 -width 6 \
 143                 -font font_diff
 144         $w_line tag conf linenumber -justify right -rmargin 5
 145
 146         set w_amov $w.file_pane.out.amove_t
 147         text $w_amov \
 148                 -takefocus 0 \
 149                 -highlightthickness 0 \
 150                 -padx 0 -pady 0 \
 151                 -background white -borderwidth 0 \
 152                 -state disabled \
 153                 -wrap none \
 154                 -height 40 \
 155                 -width 5 \
 156                 -font font_diff
 157         $w_amov tag conf author_abbr -justify right -rmargin 5
 158         $w_amov tag conf curr_commit
 159         $w_amov tag conf prior_commit -foreground blue -underline 1
 160         $w_amov tag bind prior_commit \
 161                 <Button-1> \
 162                 "[cb _load_commit $w_amov @amov_data @%x,%y];break"
 163
 164         set w_asim $w.file_pane.out.asimple_t
 165         text $w_asim \
 166                 -takefocus 0 \
 167                 -highlightthickness 0 \
 168                 -padx 0 -pady 0 \
 169                 -background white -borderwidth 0 \
 170                 -state disabled \
 171                 -wrap none \
 172                 -height 40 \
 173                 -width 4 \
 174                 -font font_diff
 175         $w_asim tag conf author_abbr -justify right
 176         $w_asim tag conf curr_commit
 177         $w_asim tag conf prior_commit -foreground blue -underline 1
 178         $w_asim tag bind prior_commit \
 179                 <Button-1> \
 180                 "[cb _load_commit $w_asim @asim_data @%x,%y];break"
 181
 182         set w_file $w.file_pane.out.file_t
 183         text $w_file \
 184                 -takefocus 0 \
 185                 -highlightthickness 0 \
 186                 -padx 0 -pady 0 \
 187                 -background white -borderwidth 0 \
 188                 -state disabled \
 189                 -wrap none \
 190                 -height 40 \
 191                 -width 80 \
 192                 -xscrollcommand [list $w.file_pane.out.sbx set] \
 193                 -font font_diff
 194
 195         set w_columns [list $w_amov $w_asim $w_line $w_file]
 196
 197         scrollbar $w.file_pane.out.sbx \
 198                 -orient h \
 199                 -command [list $w_file xview]
 200         scrollbar $w.file_pane.out.sby \
 201                 -orient v \
 202                 -command [list scrollbar2many $w_columns yview]
 203         eval grid $w_columns $w.file_pane.out.sby -sticky nsew
 204         grid conf \
 205                 $w.file_pane.out.sbx \
 206                 -column [expr {[llength $w_columns] - 1}] \
 207                 -sticky we
 208         grid columnconfigure \
 209                 $w.file_pane.out \
 210                 [expr {[llength $w_columns] - 1}] \
 211                 -weight 1
 212         grid rowconfigure $w.file_pane.out 0 -weight 1
 213
 214         set w_cviewer $w.file_pane.cm.t
 215         text $w_cviewer \
 216                 -background white -borderwidth 0 \
 217                 -state disabled \
 218                 -wrap none \
 219                 -height 10 \
 220                 -width 80 \
 221                 -xscrollcommand [list $w.file_pane.cm.sbx set] \
 222                 -yscrollcommand [list $w.file_pane.cm.sby set] \
 223                 -font font_diff
 224         $w_cviewer tag conf still_loading \
 225                 -font font_uiitalic \
 226                 -justify center
 227         $w_cviewer tag conf header_key \
 228                 -tabs {3c} \
 229                 -background $active_color \
 230                 -font font_uibold
 231         $w_cviewer tag conf header_val \
 232                 -background $active_color \
 233                 -font font_ui
 234         $w_cviewer tag raise sel
 235         scrollbar $w.file_pane.cm.sbx \
 236                 -orient h \
 237                 -command [list $w_cviewer xview]
 238         scrollbar $w.file_pane.cm.sby \
 239                 -orient v \
 240                 -command [list $w_cviewer yview]
 241         pack $w.file_pane.cm.sby -side right -fill y
 242         pack $w.file_pane.cm.sbx -side bottom -fill x
 243         pack $w_cviewer -expand 1 -fill both
 244
 245         set status [::status_bar::new $w.status]
 246
 247         menu $w.ctxm -tearoff 0
 248         $w.ctxm add command \
 249                 -label "Copy Commit" \
 250                 -command [cb _copycommit]
 251
 252         foreach i $w_columns {
 253                 for {set g 0} {$g < [llength $group_colors]} {incr g} {
 254                         $i tag conf color$g -background [lindex $group_colors $g]
 255                 }
 256
 257                 $i conf -cursor $cursor_ptr
 258                 $i conf -yscrollcommand [list many2scrollbar \
 259                         $w_columns yview $w.file_pane.out.sby]
 260                 bind $i <Button-1> "
 261                         [cb _hide_tooltip]
 262                         [cb _click $i @%x,%y]
 263                         focus $i
 264                 "
 265                 bind $i <Any-Motion>  [cb _show_tooltip $i @%x,%y]
 266                 bind $i <Any-Enter>   [cb _hide_tooltip]
 267                 bind $i <Any-Leave>   [cb _hide_tooltip]
 268                 bind_button3 $i "
 269                         [cb _hide_tooltip]
 270                         set cursorX %x
 271                         set cursorY %y
 272                         set cursorW %W
 273                         tk_popup $w.ctxm %X %Y
 274                 "
 275                 bind $i <Shift-Tab> "[list focus $w_cviewer];break"
 276                 bind $i <Tab>       "[list focus $w_cviewer];break"
 277         }
 278
 279         foreach i [concat $w_columns $w_cviewer] {
 280                 bind $i <Key-Up>        {catch {%W yview scroll -1 units};break}
 281                 bind $i <Key-Down>      {catch {%W yview scroll  1 units};break}
 282                 bind $i <Key-Left>      {catch {%W xview scroll -1 units};break}
 283                 bind $i <Key-Right>     {catch {%W xview scroll  1 units};break}
 284                 bind $i <Key-k>         {catch {%W yview scroll -1 units};break}
 285                 bind $i <Key-j>         {catch {%W yview scroll  1 units};break}
 286                 bind $i <Key-h>         {catch {%W xview scroll -1 units};break}
 287                 bind $i <Key-l>         {catch {%W xview scroll  1 units};break}
 288                 bind $i <Control-Key-b> {catch {%W yview scroll -1 pages};break}
 289                 bind $i <Control-Key-f> {catch {%W yview scroll  1 pages};break}
 290         }
 291
 292         bind $w_cviewer <Shift-Tab> "[list focus $w_file];break"
 293         bind $w_cviewer <Tab>       "[list focus $w_file];break"
 294         bind $w_cviewer <Button-1> [list focus $w_cviewer]
 295         bind $w_file    <Visibility> [list focus $w_file]
 296
 297         grid configure $w.header -sticky ew
 298         grid configure $w.file_pane -sticky nsew
 299         grid configure $w.status -sticky ew
 300         grid columnconfigure $top 0 -weight 1
 301         grid rowconfigure $top 0 -weight 0
 302         grid rowconfigure $top 1 -weight 1
 303         grid rowconfigure $top 2 -weight 0
 304
 305         set req_w [winfo reqwidth  $top]
 306         set req_h [winfo reqheight $top]
 307         set scr_h [expr {[winfo screenheight $top] - 100}]
 308         if {$req_w < 600} {set req_w 600}
 309         if {$req_h < $scr_h} {set req_h $scr_h}
 310         set g "${req_w}x${req_h}"
 311         wm geometry $top $g
 312         update
 313
 314         set old_height [winfo height $w.file_pane]
 315         $w.file_pane sash place 0 \
 316                 [lindex [$w.file_pane sash coord 0] 0] \
 317                 [expr {int($old_height * 0.70)}]
 318         bind $w.file_pane <Configure> \
 319         "if {{$w.file_pane} eq {%W}} {[cb _resize %h]}"
 320
 321         _load $this {}
 322 }
 323
 324 method _load {jump} {
 325         variable group_colors
 326
 327         _hide_tooltip $this
 328
 329         if {$total_lines != 0 || $current_fd ne {}} {
 330                 if {$current_fd ne {}} {
 331                         catch {close $current_fd}
 332                         set current_fd {}
 333                 }
 334
 335                 foreach i $w_columns {
 336                         $i conf -state normal
 337                         $i delete 0.0 end
 338                         foreach g [$i tag names] {
 339                                 if {[regexp {^g[0-9a-f]{40}$} $g]} {
 340                                         $i tag delete $g
 341                                 }
 342                         }
 343                         $i conf -state disabled
 344                 }
 345
 346                 $w_cviewer conf -state normal
 347                 $w_cviewer delete 0.0 end
 348                 $w_cviewer conf -state disabled
 349
 350                 set highlight_line -1
 351                 set highlight_column {}
 352                 set highlight_commit {}
 353                 set total_lines 0
 354         }
 355
 356         if {$history eq {}} {
 357                 $w_back conf -state disabled
 358         } else {
 359                 $w_back conf -state normal
 360         }
 361
 362         # Index 0 is always empty.  There is never line 0 as
 363         # we use only 1 based lines, as that matches both with
 364         # git-blame output and with Tk's text widget.
 365         #
 366         set amov_data [list [list]]
 367         set asim_data [list [list]]
 368
 369         $status show "Reading $commit:[escape_path $path]..."
 370         $w_path conf -text [escape_path $path]
 371         if {$commit eq {}} {
 372                 set fd [open $path r]
 373         } else {
 374                 set fd [git_read cat-file blob "$commit:$path"]
 375         }
 376         fconfigure $fd -blocking 0 -translation lf -encoding binary
 377         fileevent $fd readable [cb _read_file $fd $jump]
 378         set current_fd $fd
 379 }
 380
 381 method _history_menu {} {
 382         set m $w.backmenu
 383         if {[winfo exists $m]} {
 384                 $m delete 0 end
 385         } else {
 386                 menu $m -tearoff 0
 387         }
 388
 389         for {set i [expr {[llength $history] - 1}]
 390                 } {$i >= 0} {incr i -1} {
 391                 set e [lindex $history $i]
 392                 set c [lindex $e 0]
 393                 set f [lindex $e 1]
 394
 395                 if {[regexp {^[0-9a-f]{40}$} $c]} {
 396                         set t [string range $c 0 8]...
 397                 } elseif {$c eq {}} {
 398                         set t {Working Directory}
 399                 } else {
 400                         set t $c
 401                 }
 402                 if {![catch {set summary $header($c,summary)}]} {
 403                         append t " $summary"
 404                         if {[string length $t] > 70} {
 405                                 set t [string range $t 0 66]...
 406                         }
 407                 }
 408
 409                 $m add command -label $t -command [cb _goback $i]
 410         }
 411         set X [winfo rootx $w_back]
 412         set Y [expr {[winfo rooty $w_back] + [winfo height $w_back]}]
 413         tk_popup $m $X $Y
 414 }
 415
 416 method _goback {i} {
 417         set dat [lindex $history $i]
 418         set history [lrange $history 0 [expr {$i - 1}]]
 419         set commit [lindex $dat 0]
 420         set path [lindex $dat 1]
 421         _load $this [lrange $dat 2 5]
 422 }
 423
 424 method _read_file {fd jump} {
 425         if {$fd ne $current_fd} {
 426                 catch {close $fd}
 427                 return
 428         }
 429
 430         foreach i $w_columns {$i conf -state normal}
 431         while {[gets $fd line] >= 0} {
 432                 regsub "\r\$" $line {} line
 433                 incr total_lines
 434                 lappend amov_data {}
 435                 lappend asim_data {}
 436
 437                 if {$total_lines > 1} {
 438                         foreach i $w_columns {$i insert end "\n"}
 439                 }
 440
 441                 $w_line insert end "$total_lines" linenumber
 442                 $w_file insert end "$line"
 443         }
 444
 445         set ln_wc [expr {[string length $total_lines] + 2}]
 446         if {[$w_line cget -width] < $ln_wc} {
 447                 $w_line conf -width $ln_wc
 448         }
 449
 450         foreach i $w_columns {$i conf -state disabled}
 451
 452         if {[eof $fd]} {
 453                 close $fd
 454
 455                 # If we don't force Tk to update the widgets *right now*
 456                 # none of our jump commands will cause a change in the UI.
 457                 #
 458                 update
 459
 460                 if {[llength $jump] == 1} {
 461                         set highlight_line [lindex $jump 0]
 462                         $w_file see "$highlight_line.0"
 463                 } elseif {[llength $jump] == 4} {
 464                         set highlight_column [lindex $jump 0]
 465                         set highlight_line [lindex $jump 1]
 466                         $w_file xview moveto [lindex $jump 2]
 467                         $w_file yview moveto [lindex $jump 3]
 468                 }
 469
 470                 _exec_blame $this $w_asim @asim_data \
 471                         [list] \
 472                         { copy/move tracking}
 473         }
 474 } ifdeleted { catch {close $fd} }
 475
 476 method _exec_blame {cur_w cur_d options cur_s} {
 477         lappend options --incremental
 478         if {$commit eq {}} {
 479                 lappend options --contents $path
 480         } else {
 481                 lappend options $commit
 482         }
 483         lappend options -- $path
 484         set fd [eval git_read --nice blame $options]
 485         fconfigure $fd -blocking 0 -translation lf -encoding binary
 486         fileevent $fd readable [cb _read_blame $fd $cur_w $cur_d]
 487         set current_fd $fd
 488         set blame_lines 0
 489
 490         $status start \
 491                 "Loading$cur_s annotations..." \
 492                 {lines annotated}
 493 }
 494
 495 method _read_blame {fd cur_w cur_d} {
 496         upvar #0 $cur_d line_data
 497         variable group_colors
 498         variable original_options
 499
 500         if {$fd ne $current_fd} {
 501                 catch {close $fd}
 502                 return
 503         }
 504
 505         $cur_w conf -state normal
 506         while {[gets $fd line] >= 0} {
 507                 if {[regexp {^([a-z0-9]{40}) (\d+) (\d+) (\d+)$} $line line \
 508                         cmit original_line final_line line_count]} {
 509                         set r_commit     $cmit
 510                         set r_orig_line  $original_line
 511                         set r_final_line $final_line
 512                         set r_line_count $line_count
 513                 } elseif {[string match {filename *} $line]} {
 514                         set file [string range $line 9 end]
 515                         set n    $r_line_count
 516                         set lno  $r_final_line
 517                         set oln  $r_orig_line
 518                         set cmit $r_commit
 519
 520                         if {[regexp {^0{40}$} $cmit]} {
 521                                 set commit_abbr work
 522                                 set commit_type curr_commit
 523                         } elseif {$cmit eq $commit} {
 524                                 set commit_abbr this
 525                                 set commit_type curr_commit
 526                         } else {
 527                                 set commit_type prior_commit
 528                                 set commit_abbr [string range $cmit 0 3]
 529                         }
 530
 531                         set author_abbr {}
 532                         set a_name {}
 533                         catch {set a_name $header($cmit,author)}
 534                         while {$a_name ne {}} {
 535                                 if {$author_abbr ne {}
 536                                         && [string index $a_name 0] eq {'}} {
 537                                         regsub {^'[^']+'\s+} $a_name {} a_name
 538                                 }
 539                                 if {![regexp {^([[:upper:]])} $a_name _a]} break
 540                                 append author_abbr $_a
 541                                 unset _a
 542                                 if {![regsub \
 543                                         {^[[:upper:]][^\s]*\s+} \
 544                                         $a_name {} a_name ]} break
 545                         }
 546                         if {$author_abbr eq {}} {
 547                                 set author_abbr { |}
 548                         } else {
 549                                 set author_abbr [string range $author_abbr 0 3]
 550                         }
 551                         unset a_name
 552
 553                         set first_lno $lno
 554                         while {
 555                            $first_lno > 1
 556                         && $cmit eq [lindex $line_data [expr {$first_lno - 1}] 0]
 557                         && $file eq [lindex $line_data [expr {$first_lno - 1}] 1]
 558                         } {
 559                                 incr first_lno -1
 560                         }
 561
 562                         set color {}
 563                         if {$first_lno < $lno} {
 564                                 foreach g [$w_file tag names $first_lno.0] {
 565                                         if {[regexp {^color[0-9]+$} $g]} {
 566                                                 set color $g
 567                                                 break
 568                                         }
 569                                 }
 570                         } else {
 571                                 set i [lsort [concat \
 572                                         [$w_file tag names "[expr {$first_lno - 1}].0"] \
 573                                         [$w_file tag names "[expr {$lno + $n}].0"] \
 574                                         ]]
 575                                 for {set g 0} {$g < [llength $group_colors]} {incr g} {
 576                                         if {[lsearch -sorted -exact $i color$g] == -1} {
 577                                                 set color color$g
 578                                                 break
 579                                         }
 580                                 }
 581                         }
 582                         if {$color eq {}} {
 583                                 set color color0
 584                         }
 585
 586                         while {$n > 0} {
 587                                 set lno_e "$lno.0 lineend + 1c"
 588                                 if {[lindex $line_data $lno] ne {}} {
 589                                         set g [lindex $line_data $lno 0]
 590                                         foreach i $w_columns {
 591                                                 $i tag remove g$g $lno.0 $lno_e
 592                                         }
 593                                 }
 594                                 lset line_data $lno [list $cmit $file $oln]
 595
 596                                 $cur_w delete $lno.0 "$lno.0 lineend"
 597                                 if {$lno == $first_lno} {
 598                                         $cur_w insert $lno.0 $commit_abbr $commit_type
 599                                 } elseif {$lno == [expr {$first_lno + 1}]} {
 600                                         $cur_w insert $lno.0 $author_abbr author_abbr
 601                                 } else {
 602                                         $cur_w insert $lno.0 { |}
 603                                 }
 604
 605                                 foreach i $w_columns {
 606                                         if {$cur_w eq $w_amov} {
 607                                                 for {set g 0} \
 608                                                         {$g < [llength $group_colors]} \
 609                                                         {incr g} {
 610                                                         $i tag remove color$g $lno.0 $lno_e
 611                                                 }
 612                                                 $i tag add $color $lno.0 $lno_e
 613                                         }
 614                                         $i tag add g$cmit $lno.0 $lno_e
 615                                 }
 616
 617                                 if {$highlight_column eq $cur_w} {
 618                                         if {$highlight_line == -1
 619                                          && [lindex [$w_file yview] 0] == 0} {
 620                                                 $w_file see $lno.0
 621                                                 set highlight_line $lno
 622                                         }
 623                                         if {$highlight_line == $lno} {
 624                                                 _showcommit $this $cur_w $lno
 625                                         }
 626                                 }
 627
 628                                 incr n -1
 629                                 incr lno
 630                                 incr oln
 631                                 incr blame_lines
 632                         }
 633
 634                         while {
 635                            $cmit eq [lindex $line_data $lno 0]
 636                         && $file eq [lindex $line_data $lno 1]
 637                         } {
 638                                 $cur_w delete $lno.0 "$lno.0 lineend"
 639
 640                                 if {$lno == $first_lno} {
 641                                         $cur_w insert $lno.0 $commit_abbr $commit_type
 642                                 } elseif {$lno == [expr {$first_lno + 1}]} {
 643                                         $cur_w insert $lno.0 $author_abbr author_abbr
 644                                 } else {
 645                                         $cur_w insert $lno.0 { |}
 646                                 }
 647
 648                                 if {$cur_w eq $w_amov} {
 649                                         foreach i $w_columns {
 650                                                 for {set g 0} \
 651                                                         {$g < [llength $group_colors]} \
 652                                                         {incr g} {
 653                                                         $i tag remove color$g $lno.0 $lno_e
 654                                                 }
 655                                                 $i tag add $color $lno.0 $lno_e
 656                                         }
 657                                 }
 658
 659                                 incr lno
 660                         }
 661
 662                 } elseif {[regexp {^([a-z-]+) (.*)$} $line line key data]} {
 663                         set header($r_commit,$key) $data
 664                 }
 665         }
 666         $cur_w conf -state disabled
 667
 668         if {[eof $fd]} {
 669                 close $fd
 670                 if {$cur_w eq $w_asim} {
 671                         _exec_blame $this $w_amov @amov_data \
 672                                 $original_options \
 673                                 { original location}
 674                 } else {
 675                         set current_fd {}
 676                         $status stop {Annotation complete.}
 677                 }
 678         } else {
 679                 $status update $blame_lines $total_lines
 680         }
 681 } ifdeleted { catch {close $fd} }
 682
 683 method _click {cur_w pos} {
 684         set lno [lindex [split [$cur_w index $pos] .] 0]
 685         _showcommit $this $cur_w $lno
 686 }
 687
 688 method _load_commit {cur_w cur_d pos} {
 689         upvar #0 $cur_d line_data
 690         set lno [lindex [split [$cur_w index $pos] .] 0]
 691         set dat [lindex $line_data $lno]
 692         if {$dat ne {}} {
 693                 lappend history [list \
 694                         $commit $path \
 695                         $highlight_column \
 696                         $highlight_line \
 697                         [lindex [$w_file xview] 0] \
 698                         [lindex [$w_file yview] 0] \
 699                         ]
 700                 set commit [lindex $dat 0]
 701                 set path   [lindex $dat 1]
 702                 _load $this [list [lindex $dat 2]]
 703         }
 704 }
 705
 706 method _showcommit {cur_w lno} {
 707         global repo_config
 708         variable active_color
 709
 710         if {$highlight_commit ne {}} {
 711                 foreach i $w_columns {
 712                         $i tag conf g$highlight_commit -background {}
 713                         $i tag lower g$highlight_commit
 714                 }
 715         }
 716
 717         if {$cur_w eq $w_asim} {
 718                 set dat [lindex $asim_data $lno]
 719                 set highlight_column $w_asim
 720         } else {
 721                 set dat [lindex $amov_data $lno]
 722                 set highlight_column $w_amov
 723         }
 724
 725         $w_cviewer conf -state normal
 726         $w_cviewer delete 0.0 end
 727
 728         if {$dat eq {}} {
 729                 set cmit {}
 730                 $w_cviewer insert end "Loading annotation..." still_loading
 731         } else {
 732                 set cmit [lindex $dat 0]
 733                 set file [lindex $dat 1]
 734
 735                 foreach i $w_columns {
 736                         $i tag conf g$cmit -background $active_color
 737                         $i tag raise g$cmit
 738                 }
 739
 740                 set author_name {}
 741                 set author_email {}
 742                 set author_time {}
 743                 catch {set author_name $header($cmit,author)}
 744                 catch {set author_email $header($cmit,author-mail)}
 745                 catch {set author_time [clock format \
 746                         $header($cmit,author-time) \
 747                         -format {%Y-%m-%d %H:%M:%S}
 748                 ]}
 749
 750                 set committer_name {}
 751                 set committer_email {}
 752                 set committer_time {}
 753                 catch {set committer_name $header($cmit,committer)}
 754                 catch {set committer_email $header($cmit,committer-mail)}
 755                 catch {set committer_time [clock format \
 756                         $header($cmit,committer-time) \
 757                         -format {%Y-%m-%d %H:%M:%S}
 758                 ]}
 759
 760                 if {[catch {set msg $header($cmit,message)}]} {
 761                         set msg {}
 762                         catch {
 763                                 set fd [git_read cat-file commit $cmit]
 764                                 fconfigure $fd -encoding binary -translation lf
 765                                 if {[catch {set enc $repo_config(i18n.commitencoding)}]} {
 766                                         set enc utf-8
 767                                 }
 768                                 while {[gets $fd line] > 0} {
 769                                         if {[string match {encoding *} $line]} {
 770                                                 set enc [string tolower [string range $line 9 end]]
 771                                         }
 772                                 }
 773                                 set msg [encoding convertfrom $enc [read $fd]]
 774                                 set msg [string trim $msg]
 775                                 close $fd
 776
 777                                 set author_name [encoding convertfrom $enc $author_name]
 778                                 set committer_name [encoding convertfrom $enc $committer_name]
 779
 780                                 set header($cmit,author) $author_name
 781                                 set header($cmit,committer) $committer_name
 782                         }
 783                         set header($cmit,message) $msg
 784                 }
 785
 786                 $w_cviewer insert end "commit $cmit\n" header_key
 787                 $w_cviewer insert end "Author:\t" header_key
 788                 $w_cviewer insert end "$author_name $author_email" header_val
 789                 $w_cviewer insert end "  $author_time\n" header_val
 790
 791                 $w_cviewer insert end "Committer:\t" header_key
 792                 $w_cviewer insert end "$committer_name $committer_email" header_val
 793                 $w_cviewer insert end "  $committer_time\n" header_val
 794
 795                 if {$file ne $path} {
 796                         $w_cviewer insert end "Original File:\t" header_key
 797                         $w_cviewer insert end "[escape_path $file]\n" header_val
 798                 }
 799
 800                 $w_cviewer insert end "\n$msg"
 801         }
 802         $w_cviewer conf -state disabled
 803
 804         set highlight_line $lno
 805         set highlight_commit $cmit
 806
 807         if {[lsearch -exact $tooltip_commit $highlight_commit] != -1} {
 808                 _hide_tooltip $this
 809         }
 810 }
 811
 812 method _copycommit {} {
 813         set pos @$::cursorX,$::cursorY
 814         set lno [lindex [split [$::cursorW index $pos] .] 0]
 815         set dat [lindex $amov_data $lno]
 816         if {$dat ne {}} {
 817                 clipboard clear
 818                 clipboard append \
 819                         -format STRING \
 820                         -type STRING \
 821                         -- [lindex $dat 0]
 822         }
 823 }
 824
 825 method _show_tooltip {cur_w pos} {
 826         if {$tooltip_wm ne {}} {
 827                 _open_tooltip $this $cur_w
 828         } elseif {$tooltip_timer eq {}} {
 829                 set tooltip_timer [after 1000 [cb _open_tooltip $cur_w]]
 830         }
 831 }
 832
 833 method _open_tooltip {cur_w} {
 834         set tooltip_timer {}
 835         set pos_x [winfo pointerx $cur_w]
 836         set pos_y [winfo pointery $cur_w]
 837         if {[winfo containing $pos_x $pos_y] ne $cur_w} {
 838                 _hide_tooltip $this
 839                 return
 840         }
 841
 842         if {$tooltip_wm ne "$cur_w.tooltip"} {
 843                 _hide_tooltip $this
 844
 845                 set tooltip_wm [toplevel $cur_w.tooltip -borderwidth 1]
 846                 wm overrideredirect $tooltip_wm 1
 847                 wm transient $tooltip_wm [winfo toplevel $cur_w]
 848                 set tooltip_t $tooltip_wm.label
 849                 text $tooltip_t \
 850                         -takefocus 0 \
 851                         -highlightthickness 0 \
 852                         -relief flat \
 853                         -borderwidth 0 \
 854                         -wrap none \
 855                         -background lightyellow \
 856                         -foreground black
 857                 $tooltip_t tag conf section_header -font font_uibold
 858                 pack $tooltip_t
 859         } else {
 860                 $tooltip_t conf -state normal
 861                 $tooltip_t delete 0.0 end
 862         }
 863
 864         set pos @[join [list \
 865                 [expr {$pos_x - [winfo rootx $cur_w]}] \
 866                 [expr {$pos_y - [winfo rooty $cur_w]}]] ,]
 867         set lno [lindex [split [$cur_w index $pos] .] 0]
 868         if {$cur_w eq $w_amov} {
 869                 set dat [lindex $amov_data $lno]
 870                 set org {}
 871         } else {
 872                 set dat [lindex $asim_data $lno]
 873                 set org [lindex $amov_data $lno]
 874         }
 875
 876         set cmit [lindex $dat 0]
 877         set tooltip_commit [list $cmit]
 878
 879         set author_name {}
 880         set summary     {}
 881         set author_time {}
 882         catch {set author_name $header($cmit,author)}
 883         catch {set summary     $header($cmit,summary)}
 884         catch {set author_time [clock format \
 885                 $header($cmit,author-time) \
 886                 -format {%Y-%m-%d %H:%M:%S}
 887         ]}
 888
 889         $tooltip_t insert end "commit $cmit\n"
 890         $tooltip_t insert end "$author_name  $author_time\n"
 891         $tooltip_t insert end "$summary"
 892
 893         if {$org ne {} && [lindex $org 0] ne $cmit} {
 894                 set save [$tooltip_t get 0.0 end]
 895                 $tooltip_t delete 0.0 end
 896
 897                 set cmit [lindex $org 0]
 898                 set file [lindex $org 1]
 899                 lappend tooltip_commit $cmit
 900
 901                 set author_name {}
 902                 set summary     {}
 903                 set author_time {}
 904                 catch {set author_name $header($cmit,author)}
 905                 catch {set summary     $header($cmit,summary)}
 906                 catch {set author_time [clock format \
 907                         $header($cmit,author-time) \
 908                         -format {%Y-%m-%d %H:%M:%S}
 909                 ]}
 910
 911                 $tooltip_t insert end "Originally By:\n" section_header
 912                 $tooltip_t insert end "commit $cmit\n"
 913                 $tooltip_t insert end "$author_name  $author_time\n"
 914                 $tooltip_t insert end "$summary\n"
 915
 916                 if {$file ne $path} {
 917                         $tooltip_t insert end "In File: " section_header
 918                         $tooltip_t insert end "$file\n"
 919                 }
 920
 921                 $tooltip_t insert end "\n"
 922                 $tooltip_t insert end "Copied Or Moved Here By:\n" section_header
 923                 $tooltip_t insert end $save
 924         }
 925
 926         $tooltip_t conf -state disabled
 927         _position_tooltip $this
 928 }
 929
 930 method _position_tooltip {} {
 931         set max_h [lindex [split [$tooltip_t index end] .] 0]
 932         set max_w 0
 933         for {set i 1} {$i <= $max_h} {incr i} {
 934                 set c [lindex [split [$tooltip_t index "$i.0 lineend"] .] 1]
 935                 if {$c > $max_w} {set max_w $c}
 936         }
 937         $tooltip_t conf -width $max_w -height $max_h
 938
 939         set req_w [winfo reqwidth  $tooltip_t]
 940         set req_h [winfo reqheight $tooltip_t]
 941         set pos_x [expr {[winfo pointerx .] +  5}]
 942         set pos_y [expr {[winfo pointery .] + 10}]
 943
 944         set g "${req_w}x${req_h}"
 945         if {$pos_x >= 0} {append g +}
 946         append g $pos_x
 947         if {$pos_y >= 0} {append g +}
 948         append g $pos_y
 949
 950         wm geometry $tooltip_wm $g
 951         raise $tooltip_wm
 952 }
 953
 954 method _hide_tooltip {} {
 955         if {$tooltip_wm ne {}} {
 956                 destroy $tooltip_wm
 957                 set tooltip_wm {}
 958                 set tooltip_commit {}
 959         }
 960         if {$tooltip_timer ne {}} {
 961                 after cancel $tooltip_timer
 962                 set tooltip_timer {}
 963         }
 964 }
 965
 966 method _resize {new_height} {
 967         set diff [expr {$new_height - $old_height}]
 968         if {$diff == 0} return
 969
 970         set my [expr {[winfo height $w.file_pane] - 25}]
 971         set o [$w.file_pane sash coord 0]
 972         set ox [lindex $o 0]
 973         set oy [expr {[lindex $o 1] + $diff}]
 974         if {$oy < 0}   {set oy 0}
 975         if {$oy > $my} {set oy $my}
 976         $w.file_pane sash place 0 $ox $oy
 977
 978         set old_height $new_height
 979 }
 980
 981 }