1 dnl RRDtool AutoConf script ...
2 dnl ---------------------------
3 dnl $Id$
4 dnl
5 dnl Created by Jeff Allen, Tobi Oetiker, Blair Zajac
6 dnl
7 dnl Inspiration from http://autoconf-archive.cryp.to
9 dnl tell automake the this script is for rrdtool
11 dnl Minimum Autoconf version required.
12 AC_PREREQ(2.59)
14 dnl the official version number is
15 dnl a.b.c
16 AC_INIT([rrdtool],[1.4.5])
18 dnl for testing a numberical version number comes handy
19 dnl the released version are
20 dnl a.bccc
21 dnl the devel versions will be something like
22 dnl a.b999yymmddhh
23 NUMVERS=1.4004
24 AC_SUBST(NUMVERS)
26 dnl for the linker to understand which versions the library are compatible with
27 dnl each other we must keep a separate library version cout of the format c:r:a.
28 dnl - if only implementation changed but all interfaces are kept, do r++
29 dnl - if only functionality was added do c++,r=0,a++
30 dnl - if any functionality was removed do c++,r=0,a=0.
31 dnl
32 dnl see http://sourceware.org/autobook/autobook/autobook_91.html
33 dnl
34 LIBVERS=5:4:1
35 AC_SUBST(LIBVERS)
37 AC_CANONICAL_TARGET
38 m4_version_prereq(2.60, [AC_USE_SYSTEM_EXTENSIONS], [#])
39 AM_INIT_AUTOMAKE
40 AM_MAINTAINER_MODE
41 # Enable silent build rules by default, requires at least
42 # Automake-1.11. Disable by either passing --disable-silent-rules to
43 # configure or passing V=1 to make
44 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
45 AC_CONFIG_HEADERS([rrd_config.h])
46 AC_CONFIG_MACRO_DIR([m4])
48 dnl all our local stuff like install scripts and include files
49 dnl is in there
52 dnl determine the type of system we are running on
54 AC_SUBST(VERSION)
56 AC_PREFIX_DEFAULT( /opt/rrdtool-$PACKAGE_VERSION )
58 dnl At the TOP of the HEADER
60 AH_TOP([
61 #ifndef RRD_CONFIG_H
62 #define RRD_CONFIG_H
64 /* IEEE can be prevented from raising signals with fpsetmask(0) */
65 #undef MUST_DISABLE_FPMASK
67 /* IEEE math only works if SIGFPE gets actively set to IGNORE */
68 #undef MUST_DISABLE_SIGFPE
70 /* realloc does not support NULL as argument */
71 #undef NO_NULL_REALLOC
73 /* lets enable madvise defines in NetBSD */
74 #if defined(__NetBSD__)
75 # if !defined(_NETBSD_SOURCE)
76 # define _NETBSD_SOURCE
77 # endif
78 #endif
80 ])
82 AH_BOTTOM([
84 #ifdef MUST_HAVE_MALLOC_MALLOC_H
85 # include <malloc/malloc.h>
86 #endif
88 #include "src/rrd_config_bottom.h"
90 #endif
91 ])
93 dnl Process Special Options
94 dnl -----------------------------------
96 dnl How the vertical axis label is printed
97 AC_ARG_VAR(RRDGRAPH_YLEGEND_ANGLE,
98 [Vertical label angle: -90.0 (default) or 90.0])
99 AC_DEFINE_UNQUOTED(RRDGRAPH_YLEGEND_ANGLE,${RRDGRAPH_YLEGEND_ANGLE:-90.0},
100 [Vertical label angle: -90.0 (default) or 90.0])
102 AC_ARG_ENABLE(rrdcgi,AS_HELP_STRING([--disable-rrdcgi],[disable building of rrdcgi]),
103 [],[enable_rrdcgi=yes])
105 AC_ARG_ENABLE(rrd_graph,AS_HELP_STRING([--disable-rrd_graph],[disable all rrd_graph functions]),
106 [enable_rrdcgi=no],[enable_rrd_graph=yes])
108 if test $enable_rrd_graph != no; then
109 AC_DEFINE([HAVE_RRD_GRAPH], [], [is rrd_graph supported by this install])
110 fi
112 dnl Check if we run on a system that has fonts
113 AC_ARG_WITH(rrd-default-font,
114 [ --with-rrd-default-font=[OPTIONS] set the full path to your default font.],
115 [RRD_DEFAULT_FONT=$withval],[
116 if test -d ${WINDIR:-nodir}/cour.ttf ; then
117 RRD_DEFAULT_FONT=`cd $WINDIR;pwd`/cour.ttf
118 else
119 RRD_DEFAULT_FONT='"DejaVu Sans Mono,Bitstream Vera Sans Mono,monospace,Courier"'
120 fi
121 ])
123 dnl Use mmap in rrd_update instead of seek+write
124 AC_ARG_ENABLE([mmap],
125 AS_HELP_STRING([--disable-mmap],[disable mmap in rrd_update, use seek+write instead]),
126 [],
127 [enable_mmap=yes])
129 AC_ARG_ENABLE(pthread,AS_HELP_STRING([--disable-pthread],[disable multithread support]),
130 [],[enable_pthread=yes])
132 AC_ARG_ENABLE(static-programs,
133 AS_HELP_STRING([--enable-static-programs],[Build static programs]),
134 [case "${enableval}" in
135 yes) staticprogs=yes ;;
136 no) staticprogs=no ;;
137 *) AC_MSG_ERROR(bad value ${enableval} for --enable-static-programs) ;;
138 esac],[staticprogs=no])
139 AM_CONDITIONAL(STATIC_PROGRAMS,[test "x$staticprogs" = "xyes"])
142 CONFIGURE_PART(Audit Compilation Environment)
145 dnl Check for the compiler and static/shared library creation.
146 AC_PROG_CPP
147 AC_PROG_CC
148 AM_PROG_CC_C_O
149 AC_PROG_LIBTOOL
151 dnl Try to detect/use GNU features
152 CFLAGS="$CFLAGS -D_GNU_SOURCE"
154 dnl check for -Werror separatly
155 dnl (quite a few autotool checks do not work with -Werror; also, the
156 dnl check for -Werror fails after checking and adding the other flags)
157 AC_CACHE_CHECK([if gcc likes the -Werror flag], rd_cv_gcc_flag__Werror,
158 [AC_COMPILE_IFELSE(
159 [AC_LANG_PROGRAM([[]], [[return 0 ]])],
160 [rd_cv_gcc_flag__Werror="yes"],
161 [rd_cv_gcc_flag__Werror="no"])])
162 if test "x$rd_cv_gcc_flag__Werror" = "xyes"; then
163 WERROR="-Werror"
164 else
165 WERROR=""
166 fi
167 AC_SUBST(WERROR)
169 dnl which flags does the compiler support?
170 if test "x$GCC" = "xyes"; then
171 for flag in -fno-strict-aliasing -Wall -std=gnu99 -pedantic -Wundef -Wshadow -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Winline -Wold-style-definition -W; do
172 oCFLAGS="$CFLAGS"
173 CFLAGS="$CFLAGS $flag"
174 cachename=rd_cv_gcc_flag_`echo $flag|sed 's/[[^A-Za-z]]/_/g'`
175 AC_CACHE_CHECK([if gcc likes the $flag flag], $cachename,
176 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[return 0 ]])],[eval $cachename=yes],[eval $cachename=no])])
177 if eval test \$$cachename = no; then
178 CFLAGS="$oCFLAGS"
179 fi
180 done
181 fi
185 AC_SUBST(RRD_DEFAULT_FONT)
187 CONFIGURE_PART(Checking for Header Files)
189 dnl Checks for header files.
190 AC_HEADER_STDC
191 AC_HEADER_DIRENT
192 AC_CHECK_HEADERS(langinfo.h stdint.h inttypes.h libgen.h features.h sys/stat.h sys/types.h fcntl.h fp_class.h malloc.h unistd.h ieeefp.h math.h sys/times.h sys/param.h sys/resource.h signal.h float.h stdio.h stdlib.h errno.h string.h ctype.h)
194 dnl Checks for typedefs, structures, and compiler characteristics.
195 AC_C_CONST
196 AC_HEADER_TIME
197 AC_STRUCT_TM
199 CONFIGURE_PART(Test Library Functions)
201 dnl Checks for libraries.
202 AC_CHECK_FUNC(acos, , AC_CHECK_LIB(m, acos))
205 dnl add pic flag in any case this makes sure all our code is relocatable
206 eval `./libtool --config | grep pic_flag`
207 CFLAGS="$CFLAGS $pic_flag"
210 dnl Checks for library functions.
211 AC_FUNC_STRFTIME
212 AC_FUNC_VPRINTF
214 AC_C_BIGENDIAN
216 dnl for each function found we get a definition in config.h
217 dnl of the form HAVE_FUNCTION
219 AC_CHECK_FUNCS(nl_langinfo tzset round rint fsync mbstowcs opendir readdir chdir chroot getuid strerror snprintf vsnprintf vasprintf fpclass class fp_class isnan memmove strchr mktime getrusage gettimeofday)
221 AC_FUNC_STRERROR_R
223 CONFIGURE_PART(Map/Fadvis/Madvise checking)
225 dnl Could use these to know if we need to provide a prototype
226 dnl AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
228 dnl check for fdatasync. Solaris has fdatasync in the librt
230 AC_CHECK_FUNCS(fdatasync, [], AC_CHECK_LIB(rt, fdatasync, [LIBS="${LIBS} -lrt"; AC_DEFINE(HAVE_FDATASYNC)],[]))
231 dnl if there is no fdatasync we may get lucky with fsync
232 AC_CHECK_FUNCS(fsync)
234 dnl check for socket and nsl solaris again ... we need this for the new rrd_daemon stuff
236 AC_CHECK_FUNCS(socket, [], AC_CHECK_LIB(socket, socket, [LIBS="${LIBS} -lsocket"; AC_DEFINE(HAVE_SOCKET)],[]))
237 AC_CHECK_FUNCS(getaddrinfo, [], AC_CHECK_LIB(nsl, getaddrinfo, [LIBS="${LIBS} -lnsl"; AC_DEFINE(HAVE_GETADDRINFO)],[]))
241 dnl XXX: dunno about windows.. add AC_CHECK_FUNCS(munmap) there too?
242 if test "x$enable_mmap" = "xyes"; then
243 case "$host" in
244 *cygwin*)
245 # the normal mmap test does not work in cygwin
246 AC_CHECK_FUNCS(mmap)
247 if test "x$ac_cv_func_mmap" = "xyes"; then
248 ac_cv_func_mmap_fixed_mapped=yes
249 fi
250 ;;
251 *)
252 AC_CHECK_HEADERS(sys/mman.h)
253 AC_FUNC_MMAP
254 AC_CHECK_FUNCS(mmap munmap msync)
255 AC_CHECK_DECLS(madvise, [], [], [#ifdef HAVE_SYS_MMAN_H
256 # include <sys/mman.h>
257 #endif])
258 if test "x$ac_cv_have_decl_madvise" = "xyes";
259 then
260 AC_CHECK_FUNCS(madvise)
261 else
262 AC_CHECK_FUNCS(posix_madvise)
263 if test "x$ac_cv_func_posix_madvise" != "xyes"; then
264 AC_MSG_WARN([madvise() nor posix_madvise() found.])
265 fi
266 fi
267 ;;
268 esac
269 if test "x$ac_cv_func_mmap" != "xyes";
270 then
271 AC_MSG_ERROR([--enable-mmap requested but mmap() was not detected])
272 dnl enable_mmap="no"
273 fi
274 fi
276 dnl can we use posix_fadvise
277 AC_CHECK_DECLS(posix_fadvise, [], [], [#define _XOPEN_SOURCE 600
278 #include <fcntl.h>])
279 AC_CHECK_FUNCS(posix_fadvise)
281 CONFIGURE_PART(Libintl Processing)
283 AM_GNU_GETTEXT_VERSION(0.18)
284 AM_GNU_GETTEXT(external)
286 CONFIGURE_PART(IEEE Math Checks)
289 dnl actual code to check if this works
290 AC_CHECK_FUNCS(fpclassify, ,
291 [AC_MSG_CHECKING(for fpclassify with <math.h>)
292 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
293 volatile int x;volatile float f; ]], [[x = fpclassify(f)]])],[AC_MSG_RESULT(yes)
294 AC_DEFINE(HAVE_FPCLASSIFY)],[AC_MSG_RESULT(no)])])
296 AC_CHECK_FUNCS(isinf, ,
297 [AC_MSG_CHECKING(for isinf with <math.h>)
298 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
299 volatile int x;volatile float f; ]], [[x = isinf(f)]])],[AC_MSG_RESULT(yes)
300 AC_DEFINE(HAVE_ISINF)],[AC_MSG_RESULT(no)])])
302 dnl finite is BSD, isfinite is C99, so prefer the latter
303 AC_CACHE_CHECK([whether isfinite is broken],[ac_cv_have_broken_isfinite],[
304 AC_TRY_RUN([
305 #ifdef HAVE_MATH_H
306 #include <math.h>
307 #endif
308 #ifdef HAVE_FLOAT_H
309 #include <float.h>
310 #endif
311 int main ()
312 {
313 #ifdef isfinite
314 #ifdef LDBL_MAX
315 if (!isfinite(LDBL_MAX)) return 1;
316 #endif
317 #ifdef DBL_MAX
318 if (!isfinite(DBL_MAX)) return 1;
319 #endif
320 #endif
321 return 0;
322 }],[ac_cv_have_broken_isfinite=no],[ac_cv_have_broken_isfinite=yes],[
323 case "${target}" in
324 hppa*-*-hpux*) ac_cv_have_broken_isfinite=yes ;;
325 *-solaris2.8) ac_cv_have_broken_isfinite=yes ;;
326 *-solaris2.9) ac_cv_have_broken_isfinite=yes ;;
327 *) ac_cv_have_broken_isfinite=no ;;
328 esac])
329 ])
331 dnl the test does not seem to work on solaris 2.8
332 dnl so lets fix this by hand
333 case "${target}" in
334 *-solaris2.8) ac_cv_have_broken_isfinite=yes ;;
335 *-solaris2.9) ac_cv_have_broken_isfinite=yes ;;
336 esac
338 if test "x$ac_cv_have_broken_isfinite" = "xno"; then
339 AC_DEFINE(HAVE_ISFINITE)
340 else
341 AC_CHECK_FUNCS(finite,[],
342 [AC_CHECK_FUNCS(isfinite,[],
343 [AC_MSG_CHECKING(for isfinite with <math.h>)
344 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
345 volatile int x;volatile float f; ]],[[x = isfinite(f)]])],[AC_MSG_RESULT(yes)
346 AC_DEFINE(HAVE_ISFINITE)],[AC_MSG_RESULT(no)])])])
347 fi
349 AC_FULL_IEEE
351 CONFIGURE_PART(Resolve Portability Issues)
353 CHECK_FOR_WORKING_MS_ASYNC
355 dnl do we have nl_langinfo(_NL_TIME_WEEK_1STDAY)
356 AC_CHECK_FUNCS(_NL_TIME_WEEK_1STDAY, ,
357 [AC_MSG_CHECKING([for nl_langinfo(_NL_TIME_WEEK_1STDAY) with langinfo.h])
358 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]], [[nl_langinfo(_NL_TIME_WEEK_1STDAY)]])],[AC_MSG_RESULT(yes)
359 AC_DEFINE(HAVE__NL_TIME_WEEK_1STDAY)],[AC_MSG_RESULT(no)])])
361 dnl Do we need getopt_long
363 dnl even when including our own getopt implementation
364 dnl we may want to make sure we use the external
365 dnl defined by libc to not run into linker resolve trouble
367 AC_CACHE_CHECK([for opterr], rd_cv_var_int_opterr,
368 [AC_TRY_LINK([#include <unistd.h>],
369 [extern int opterr; opterr = 1;],
370 [rd_cv_var_int_opterr=yes],
371 [rd_cv_var_int_opterr=no])])
372 if test x"$rd_cv_var_int_opterr" = x"yes"; then
373 AC_DEFINE(HAVE_INT_OPTERR, 1, [Define to 1 if you have the global variable 'int opterr'.])
374 fi
376 build_getopt=no
377 RRD_GETOPT_LONG="LIBC_HAS_GETOPT_LONG"
378 AC_CHECK_FUNC(getopt_long,[],[
379 RRD_GETOPT_LONG="getopt_long"
380 build_getopt=yes
381 ])
382 AC_SUBST(RRD_GETOPT_LONG)
383 AM_CONDITIONAL(BUILD_GETOPT,[test $build_getopt = yes])
385 dnl what does realloc do if it gets called with a NULL pointer
387 AC_CACHE_CHECK([if realloc can deal with NULL], rd_cv_null_realloc,
388 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
389 int main(void){
390 char *x = NULL;
391 x = realloc (x,10);
392 if (x==NULL) return 1;
393 return 0;
394 }]])],[rd_cv_null_realloc=yes],[rd_cv_null_realloc=nope],[:])])
396 if test x"$rd_cv_null_realloc" = xnope; then
397 AC_DEFINE(NO_NULL_REALLOC)
398 fi
400 AC_LANG_PUSH(C)
401 dnl solaris has some odd defines it needs in order to propperly compile ctime_r
402 AC_MSG_CHECKING([if ctime_r need special care to act posixly correct])
403 AC_LINK_IFELSE(
404 AC_LANG_PROGRAM(
405 [[#include <time.h>]],
406 [[ctime_r(NULL,NULL,0)]]
407 ),
408 [ CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
409 AC_LINK_IFELSE(
410 AC_LANG_PROGRAM(
411 [[#include <time.h>]],
412 [[ctime_r(NULL,NULL)]]
413 ),
414 [AC_MSG_RESULT([yes, this seems to be solaris style])],
415 [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
416 )
417 ],
418 [ AC_LINK_IFELSE(
419 AC_LANG_PROGRAM(
420 [[#include <time.h>]],
421 [[ctime_r(NULL,NULL)]]
422 ),
423 [AC_MSG_RESULT(no)],
424 [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
425 )
426 ]
427 )
428 AC_LANG_POP(C)
430 dnl Check for pthreads
431 dnl http://autoconf-archive.cryp.to/acx_pthread.m4
433 AC_SUBST(MULTITHREAD_CFLAGS)
434 AC_SUBST(MULTITHREAD_LDFLAGS)
436 if test $enable_pthread != no; then
437 ACX_PTHREAD([
438 MULTITHREAD_CFLAGS=$PTHREAD_CFLAGS
439 MULTITHREAD_LDFLAGS=$PTHREAD_LIBS
440 ],
441 [])
442 fi
444 dnl since we use lots of *_r functions all over the code we better
445 dnl make sure they are known
447 if test "x$x_rflag" != "xno"; then
448 CPPFLAGS="$CPPFLAGS $x_rflag"
449 fi
451 AM_CONDITIONAL(BUILD_MULTITHREAD,[test $enable_pthread != no])
453 AC_LANG_PUSH(C)
454 dnl see if we have to include malloc/malloc.h
455 AC_MSG_CHECKING([do we need malloc/malloc.h])
456 AC_LINK_IFELSE(
457 AC_LANG_PROGRAM(
458 [[#include <stdlib.h>]],
459 [[malloc(1)]]
460 ),
461 [ AC_MSG_RESULT([nope, works out of the box]) ],
462 [ AC_LINK_IFELSE(
463 AC_LANG_PROGRAM(
464 [[#include <stdlib.h>
465 #include <malloc/malloc.h>]],
466 [[malloc(1)]]
467 ),[
468 AC_DEFINE([MUST_HAVE_MALLOC_MALLOC_H])
469 AC_MSG_RESULT([yes we do])],
470 [AC_MSG_ERROR([Can not figure how to compile malloc])]
471 )
472 ]
473 )
475 dnl is time_t 32 of 64 bit ?
476 AC_DEFINE([TIME_T_IS_32BIT], [], [time_t is 32bit])
477 AC_DEFINE([TIME_T_IS_64BIT], [], [time_t is 64bit])
478 AC_MSG_CHECKING([the type of time_t])
479 AC_RUN_IFELSE(
480 AC_LANG_PROGRAM(
481 [[#include <time.h>]],
482 [[if (sizeof(time_t) != 4) return 1; ]]
483 ),
484 [ AC_MSG_RESULT([time_t is 32 bit])
485 AC_DEFINE([TIME_T_IS_32BIT])
486 ],
487 [ AC_RUN_IFELSE(
488 AC_LANG_PROGRAM(
489 [[#include <time.h>]],
490 [[if (sizeof(time_t) != 8) return 1; ]]
491 ),
492 [
493 AC_MSG_RESULT([time_t is 64 bit])
494 AC_DEFINE([TIME_T_IS_64BIT])
495 ],
496 [AC_MSG_ERROR([can not figure type of time_t])]
497 )
498 ]
499 )
501 AC_LANG_POP(C)
503 CONFIGURE_PART(Find 3rd-Party Libraries)
505 AC_ARG_ENABLE(libdbi,AS_HELP_STRING([--disable-libdbi],[do not build in support for libdbi]),[have_libdbi=no],[
506 XXX=$LIBS
507 LIBS="$LIBS -ldbi -ldl"
508 AC_MSG_CHECKING(for libdbi)
509 AC_LINK_IFELSE(
510 [AC_LANG_PROGRAM([[#include <dbi/dbi.h>]],
511 [[dbi_initialize(NULL)]]
512 )
513 ],[AC_DEFINE(HAVE_LIBDBI,[1],[have got libdbi installed])
514 AC_MSG_RESULT([yes])
515 have_libdbi=yes
516 ],[LIBS=$XXX
517 AC_MSG_RESULT([no])
518 have_libdbi=no
519 ]
520 )
521 ])
522 AM_CONDITIONAL(BUILD_LIBDBI,[test $have_libdbi != no])
524 AC_ARG_ENABLE(libwrap,
525 AS_HELP_STRING([--disable-libwrap],
526 [do not build in support for libwrap (tcp wrapper)]),
527 [have_libwrap=no],[
528 XXX=$LIBS
529 LIBS="$LIBS -lwrap"
530 AC_MSG_CHECKING(for libwrap)
531 AC_LINK_IFELSE(
532 [AC_LANG_PROGRAM([[#include "tcpd.h"]], [[hosts_access(NULL)]])
533 ],[AC_DEFINE(HAVE_LIBWRAP,[1],[have got libwrap installed])
534 AC_MSG_RESULT([yes])
535 have_libwrap=yes
536 ],[LIBS=$XXX
537 AC_MSG_RESULT([no])
538 have_libwrap=no
539 ]
540 )
541 ])
542 AM_CONDITIONAL(BUILD_LIBWRAP,[test $have_libwrap != no])
544 AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
546 AM_CONDITIONAL(BUILD_RRDGRAPH,[test $enable_rrd_graph != no])
549 CORE_LIBS="$LIBS"
551 if test $enable_rrd_graph != no; then
552 dnl EX_CHECK_ALL(z, zlibVersion, zlib.h, zlib, 1.2.3, http://www.gzip.org/zlib/, "")
553 dnl EX_CHECK_ALL(png, png_access_version_number, png.h, libpng, 1.2.10, http://prdownloads.sourceforge.net/libpng/, "")
554 dnl EX_CHECK_ALL(freetype, FT_Init_FreeType, ft2build.h, freetype2, 2.1.10, http://prdownloads.sourceforge.net/freetype/, /usr/include/freetype2)
555 dnl EX_CHECK_ALL(fontconfig, FcInit, fontconfig.h, fontconfig, 2.3.1, http://fontconfig.org/release/, /usr/include)
556 EX_CHECK_ALL(cairo, cairo_font_options_create, cairo.h, cairo-png, 1.4.6, http://cairographics.org/releases/, "")
557 EX_CHECK_ALL(cairo, cairo_svg_surface_create, cairo-svg.h, cairo-svg, 1.4.6, http://cairographics.org/releases/, "")
558 EX_CHECK_ALL(cairo, cairo_pdf_surface_create, cairo-pdf.h, cairo-pdf, 1.4.6, http://cairographics.org/releases/, "")
559 EX_CHECK_ALL(cairo, cairo_ps_surface_create, cairo-ps.h, cairo-ps, 1.4.6, http://cairographics.org/releases/, "")
560 EX_CHECK_ALL(glib-2.0, glib_check_version, glib.h, glib-2.0, 2.12.12, ftp://ftp.gtk.org/pub/glib/2.12/, "")
561 EX_CHECK_ALL(pangocairo-1.0, pango_cairo_context_set_font_options, pango/pango.h, pangocairo, 1.17, http://ftp.gnome.org/pub/GNOME/sources/pango/1.17, "")
563 fi
565 EX_CHECK_ALL(xml2, xmlParseFile, libxml/parser.h, libxml-2.0, 2.6.31, http://xmlsoft.org/downloads.html, /usr/include/libxml2)
567 if test "$EX_CHECK_ALL_ERR" = "YES"; then
568 AC_MSG_ERROR([Please fix the library issues listed above and try again.])
569 fi
571 ALL_LIBS="$LIBS"
572 LIBS=
574 AC_SUBST(CORE_LIBS)
575 AC_SUBST(ALL_LIBS)
577 CONFIGURE_PART(Prep for Building Language Bindings)
579 dnl Check for Perl and friends
580 PATH=$PATH:/usr/perl5/bin
581 export PATH
582 AC_PATH_PROG(PERL, perl, no)
583 AC_PATH_PROG(POD2MAN, pod2man, no)
584 AC_PATH_PROG(POD2HTML, pod2html, no)
587 AC_ARG_ENABLE(perl,AS_HELP_STRING([--disable-perl],[do not build the perl modules]),
588 [],[enable_perl=yes])
591 AC_ARG_VAR(PERLCC, [C compiler for Perl modules])
592 AC_ARG_VAR(PERLCCFLAGS, [CC flags for Perl modules])
593 AC_ARG_VAR(PERLLD, [Linker for Perl modules])
594 AC_ARG_VAR(PERLLDFLAGS, [LD flags for Perl modules])
596 if test "x$PERL" = "xno" -o x$enable_perl = xno; then
597 COMP_PERL=
598 else
599 COMP_PERL="perl_piped perl_shared"
600 AC_MSG_CHECKING(for the perl version you are running)
601 PERL_VERSION=`$PERL -MConfig -e 'print $Config{version}'`
602 AC_MSG_RESULT($PERL_VERSION)
603 if test -z "$PERLCC"; then
604 AC_MSG_CHECKING(for the C compiler perl wants to use to build its modules)
605 perlcc=`$PERL -MConfig -e 'print $Config{cc}'`
606 AC_MSG_RESULT($perlcc)
607 if test ! -x "$perlcc"; then
608 AC_PATH_PROG(PERL_CC, ${perlcc}, no)
609 if test "$PERL_CC" = "no"; then
610 AC_MSG_WARN([
611 I would not find the Compiler ($perlcc) that was originally used to compile
612 your perl binary. You should either make sure that this compiler is
613 available on your system, pick an other compiler and set PERLCC
614 appropriately, or use a different perl setup that was compiled locally.
616 I will disable the compilation of the RRDs perl module for now.
617 ])
618 COMP_PERL="perl_piped"
619 fi
620 fi
621 fi
622 fi
624 AC_MSG_CHECKING(Perl Modules to build)
625 AC_MSG_RESULT(${COMP_PERL:-No Perl Modules will be built})
627 # Options to pass when configuring perl module
628 langpref=$prefix
629 test "$langpref" = '$(DESTDIR)NONE' && langpref='$(DESTDIR)'$ac_default_prefix
630 test "$langpref" = "NONE" && langpref=$ac_default_prefix
632 PERL_MAKE_OPTIONS="PREFIX=$langpref LIB=$langpref/lib/perl/$PERL_VERSION"
634 dnl pass additional perl options when generating Makefile from Makefile.PL
635 AC_ARG_ENABLE(perl-site-install,
636 AS_HELP_STRING([--enable-perl-site-install],[by default the rrdtool perl modules are installed together with rrdtool in $prefix/lib/perl. You have to put a 'use lib qw($prefix/lib/perl)' into your scripts when you want to use them. When you set this option the perl modules will get installed wherever your perl setup thinks it is best.]),
637 [PERL_MAKE_OPTIONS=],[])
639 if test ! -z "$PERLCC"; then
640 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CC=$PERLCC"
642 if test ! -z "$PERLCCFLAGS"; then
643 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CCFLAGS=$PERLCCFLAGS"
644 fi
646 if test -z "$PERLLD"; then
647 PERLLD=$PERLCC
648 fi
649 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LD=$PERLLD"
651 if test ! -z "$PERLLDFLAGS"; then
652 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LDFLAGS=$PERLLDFLAGS"
653 fi
654 fi
656 AC_ARG_WITH(perl-options,
657 [ --with-perl-options=[OPTIONS] options to pass on command-line when
658 generating Makefile from Makefile.PL. If you set this
659 option, interesting things may happen unless you know
660 what you are doing!],
661 [PERL_MAKE_OPTIONS=$withval])
663 AC_SUBST(PERL_MAKE_OPTIONS)
664 AC_SUBST(PERL)
665 AC_SUBST(COMP_PERL)
666 AC_SUBST(PERL_VERSION)
668 dnl Check for Ruby.
669 AC_PATH_PROG(RUBY, ruby, no)
671 AC_ARG_ENABLE(ruby,AS_HELP_STRING([--disable-ruby],[do not build the ruby modules]),
672 [],[enable_ruby=yes])
674 AC_MSG_CHECKING(if ruby modules can be built)
676 if test "x$RUBY" = "xno" -o x$enable_ruby = xno; then
677 COMP_RUBY=
678 AC_MSG_RESULT(No .. Ruby not found or disabled)
679 else
680 if $RUBY -e 'require "mkmf"' >/dev/null 2>&1; then
681 COMP_RUBY="ruby"
682 AC_MSG_RESULT(YES)
683 else
684 COMP_RUBY=
685 AC_MSG_RESULT(Ruby found but mkmf is missing! Install the -dev package)
686 fi
687 fi
689 dnl pass additional ruby options when generating Makefile from Makefile.PL
690 AC_ARG_ENABLE(ruby-site-install,
691 AS_HELP_STRING([--enable-ruby-site-install],[by default the rrdtool ruby modules are installed together with rrdtool in $prefix/lib/ruby. You have to add $prefix/lib/ruby/$ruby_version/$sitearch to your $: variable for ruby to find the RRD.so file.]),
692 [RUBY_MAKE_OPTIONS=],[RUBY_MAKE_OPTIONS="sitedir=$langpref/lib/ruby"])
695 AC_ARG_WITH(ruby-options,
696 [ --with-ruby-options=[OPTIONS] options to pass on command-line when
697 generating Makefile from extconf.rb. If you set this
698 option, interesting things may happen unless you know
699 what you are doing!],
700 [RUBY_MAKE_OPTIONS=$withval])
702 AC_SUBST(RUBY_MAKE_OPTIONS)
703 AC_SUBST(RUBY)
704 AC_SUBST(COMP_RUBY)
706 dnl Check for Lua.
707 AC_PATH_PROG(LUA, lua, no)
709 AC_ARG_ENABLE(lua,AS_HELP_STRING([--disable-lua],[do not build the lua modules]),
710 [],[enable_lua=yes])
712 COMP_LUA=
713 if test "$LUA" = "no" -o "$enable_lua" = "no"; then
714 enable_lua=no
715 else
716 AC_MSG_CHECKING(for lua >= 5.0)
717 read LUA_MAJOR LUA_MINOR LUA_POINT <<LUA_EOF
718 $($LUA -v 2>&1 | cut -f2 -d' ' | sed -e 's/\./ /g')
719 LUA_EOF
720 if test 0$LUA_MAJOR -lt 5; then
721 AC_MSG_RESULT([no, version found is $LUA_MAJOR.$LUA_MINOR])
722 else
723 AC_MSG_RESULT([$LUA_MAJOR.$LUA_MINOR found])
724 lua_vdot=$LUA_MAJOR.$LUA_MINOR
725 lua_vndot=$LUA_MAJOR$LUA_MINOR
726 lua_version=$LUA_MAJOR.$LUA_MINOR.$LUA_POINT
727 AC_CHECK_HEADERS(lua$lua_vndot/lua.h,
728 [AC_CHECK_HEADERS(lua$lua_vndot/lualib.h,
729 [AC_CHECK_HEADER(lua$lua_vndot/lauxlib.h,
730 [lua_headerdir=lua$lua_vndot],
731 [])],
732 [])],
733 [AC_CHECK_HEADERS(lua$lua_vdot/lua.h,
734 [AC_CHECK_HEADERS(lua$lua_vdot/lualib.h,
735 [AC_CHECK_HEADER(lua$lua_vdot/lauxlib.h,
736 [lua_headerdir=lua$lua_vdot],
737 [])],
738 [])],
739 [AC_CHECK_HEADERS(lua.h,
740 [AC_CHECK_HEADERS(lualib.h,
741 [AC_CHECK_HEADER(lauxlib.h,
742 [lua_headerdir=""],
743 [lua_headerdir="no"])],
744 [])],
745 [])])])
747 if test "$lua_headerdir" = "no"; then
748 enable_lua=no
749 else
750 COMP_LUA=lua
751 fi
753 if test "$COMP_LUA" != "lua"; then
754 enable_lua=no
755 AC_MSG_WARN([Lua $lua_vdot found but not lua.h, lualib.h and lauxlib.h! Please install the -dev packages for Lua $lua_vdot])
756 else
757 # OK, headers found, let's check the libraries (LIBS is not used)
758 LIBS=
759 lua_havelib=no
760 LUA_HAVE_COMPAT51=DONT_HAVE_COMPAT51
761 AC_SEARCH_LIBS(lua_call, lua$lua_vdot lua$lua_vndot lua,
762 [AC_SEARCH_LIBS(luaL_register, lua$lua_vdot lua$lua_vndot lua,
763 [lua_havelib=LUA$lua_vndot],
764 [AC_SEARCH_LIBS(luaL_module, lualib$lua_vndot lualib$lua_vdot lualib,
765 [lua_havelib=$lua_vndot; $LUA -l compat-5.1 2>/dev/null;
766 test "$?" = "0" && LUA_HAVE_COMPAT51=HAVE_COMPAT51],
767 [AC_SEARCH_LIBS(luaL_openlib, lualib$lua_vdot lualib$lua_vndot lualib,
768 [lua_havelib=$lua_vndot],
769 [COMP_LUA=], [-lm])], [-lm])], [-lm])],
770 [COMP_LUA=], [-lm])
771 lua_libs=$LIBS
772 LIBS=
774 # Options to pass when configuring Lua module
775 if test "$lua_havelib" != "no"; then
776 # OK, headers and libs found. Try to set lua flags
777 # and modules installation dirs with pkg-config
778 if test "$PKGCONFIG" != "no"; then
779 if test "$lua_vndot" = "50"; then
780 lua_pkg_prefix=lualib
781 else
782 lua_pkg_prefix=lua
783 fi
784 # try with dot, without dot and finally without version
785 for f in $lua_pkg_prefix$lua_vdot $lua_pkg_prefix$lua_vndot $lua_pkg_prefix; do
786 lua_exec_prefix=`$PKGCONFIG --variable=prefix $f 2>/dev/null`
787 # same binaries?
788 if test "$lua_exec_prefix/bin/lua" = "$LUA"; then
789 # OK, found CFLAGS. Get Lua LFLAGS and modules install dir
790 LUA_CFLAGS=`$PKGCONFIG --cflags $f 2>/dev/null`
791 LUA_LFLAGS=`$PKGCONFIG --libs $f 2>/dev/null`
792 LUA_INSTALL_CMOD=`$PKGCONFIG --variable=INSTALL_CMOD $f 2>/dev/null`
793 LUA_INSTALL_LMOD=`$PKGCONFIG --variable=INSTALL_LMOD $f 2>/dev/null`
794 break
795 fi
796 done
797 fi
799 LUA_RRD_LIBDIR="$langpref/lib/lua/$lua_vdot"
800 # if lua 5.0 can't find compat-5.1, force installation of
801 # compat-5.1.lua together with RRDtool.
802 if test "$lua_vdot" = "5.0" -a "$LUA_HAVE_COMPAT51" != "HAVE_COMPAT51"; then
803 lua_need_compat51=1
804 LUA_INSTALL_LMOD="$LUA_RRD_LIBDIR"
805 fi
807 # if not set with pkg-config, use default values in src packages compat-5.1, lua 5.1
808 if test "$LUA_CFLAGS" = ""; then
809 AC_MSG_WARN(Setting Lua include and lib flags to defaults in compat-5.1 and lua 5.1 sources)
810 LUA_CFLAGS="-I/usr/local/include -I/usr/local/include/lua -I/usr/local/include/lua/$lua_vdot"
811 LUA_LFLAGS="-L/usr/local/lib -L/usr/local/lib/lua -L/usr/local/lib/lua/$lua_vdot $lua_libs"
812 LUA_INSTALL_CMOD="/usr/local/lib/lua/$lua_vdot"
813 fi
815 dnl pass additional lua options
816 dnl if lua-site-install is not set, overwrite LUA_INSTALL_CMOD already
817 dnl found and install together with RRDtool, under $langpref.
818 AC_ARG_ENABLE(lua-site-install,
819 AS_HELP_STRING([--enable-lua-site-install],[by default the lua module is installed together with rrdtool in $prefix/lib/lua/$lua_version. You have to add $prefix/lib/lua/$lua_version/?.so to package.cpath for lua to find 'rrd.so'. For lua 5.0 you may also need to change LUA_PATH to the same dir, to require 'compat-5.1'. When you set this option the lua modules will get installed wherever your Lua setup thinks it is best. WARNING: if you set this option, system lua modules compat-5.1.lua and rrd.so, if any, may be overwritten.]),
820 [],
821 [LUA_INSTALL_CMOD="$LUA_RRD_LIBDIR"; LUA_INSTALL_LMOD="$LUA_RRD_LIBDIR"])
823 LUA_DEFINES="-DLUA$lua_vndot -D$LUA_HAVE_COMPAT51"
824 AC_SUBST(LUA)
825 AC_SUBST(COMP_LUA)
826 AC_SUBST(LUA_INSTALL_CMOD)
827 AC_SUBST(LUA_INSTALL_LMOD)
828 AC_SUBST(LUA_CFLAGS)
829 AC_SUBST(LUA_LFLAGS)
830 AC_SUBST(LUA_DEFINES)
831 else
832 enable_lua=no
833 AC_MSG_RESULT([Lua headers found but not the libraries! Please reinstall the dev packages for Lua $LUA_MAJOR.$LUA_MINOR])
834 fi
835 fi
836 fi
837 fi
838 dnl If Lua 5.0, we need compat-5.1. Add ours unless already
839 dnl integrated as in Debian/Ubuntu 5.0 -dev packages.
840 AM_CONDITIONAL(LUA_NEED_OUR_COMPAT51,
841 [test "$lua_vdot" = "5.0" -a "$LUA_HAVE_COMPAT51" != "HAVE_COMPAT51"])
842 AM_CONDITIONAL(LUA_SITE_CINSTALL, [test "$LUA_INSTALL_CMOD" != "$LUA_RRD_LIBDIR"])
843 AM_CONDITIONAL(LUA_SITE_LINSTALL, [test "$LUA_INSTALL_LMOD" != "$LUA_RRD_LIBDIR"])
844 AM_CONDITIONAL(LUA50, [test "$lua_vndot" = "50"])
845 AM_CONDITIONAL(BUILD_LUA, [test "$enable_lua" = "yes"])
847 enable_tcl_site=no
849 AC_ARG_ENABLE(tcl,AS_HELP_STRING([--disable-tcl],[do not build the tcl modules]),
850 [],[enable_tcl=yes])
852 if test "$enable_tcl" = "yes"; then
853 dnl Check for Tcl.
854 withval=""
855 AC_ARG_WITH(tcllib,[ --with-tcllib=DIR location of the tclConfig.sh])
856 enable_tcl=no
857 for dir in $withval /usr/lib /usr/local/lib /usr/lib/tcl8.4 /usr/lib/tcl8.3 ; do
858 AC_MSG_CHECKING(for tclConfig.sh in $dir)
859 if test -f "$dir/tclConfig.sh" ; then
860 tcl_config=$dir/tclConfig.sh
861 enable_tcl=yes
862 AC_MSG_RESULT(yes)
863 break
864 else
865 AC_MSG_RESULT(no)
866 fi
867 done
869 if test "$enable_tcl" = "no"; then
870 AC_MSG_WARN([tclConfig.sh not found - Tcl interface will not be built])
871 else
872 . $tcl_config
873 TCL_PACKAGE_DIR="$TCL_PACKAGE_PATH/tclrrd$VERSION"
874 if test -n "$TCL_INC_DIR"; then
875 TCL_INCLUDE_SPEC="$TCL_INCLUDE_SPEC -I$TCL_INC_DIR"
876 fi
877 fi
878 AC_ARG_ENABLE(tcl-site,AS_HELP_STRING([--enable-tcl-site],[install the tcl extension in the tcl tree]),
879 [],[enable_tcl_site=yes])
881 fi
883 AM_CONDITIONAL(BUILD_TCL, test "$enable_tcl" = "yes" )
884 AM_CONDITIONAL(BUILD_TCL_SITE, test "$enable_tcl_site" = "yes" )
887 AC_SUBST(TCL_PREFIX)
888 AC_SUBST(TCL_SHLIB_CFLAGS)
889 AC_SUBST(TCL_SHLIB_LD)
890 AC_SUBST(TCL_SHLIB_SUFFIX)
891 AC_SUBST(TCL_PACKAGE_PATH)
892 AC_SUBST(TCL_LD_SEARCH_FLAGS)
893 AC_SUBST(TCL_STUB_LIB_SPEC)
894 AC_SUBST(TCL_VERSION)
895 AC_SUBST(TCL_PACKAGE_DIR)
896 AC_SUBST(TCL_INCLUDE_SPEC)
898 AC_ARG_ENABLE(python,AS_HELP_STRING([--disable-python],[do not build the python modules]),
899 [],[enable_python=yes])
901 if test "$enable_python" = "yes"; then
902 dnl Check for python
903 AM_PATH_PYTHON(2.3,[],[enable_python=no])
904 AM_CHECK_PYTHON_HEADERS(,[enable_python=no;AC_MSG_WARN(could not find Python headers)])
905 fi
907 if test x$enable_python = xno; then
908 COMP_PYTHON=
909 else
910 COMP_PYTHON="python"
911 fi
913 AC_SUBST(COMP_PYTHON)
915 dnl Check for nroff
916 AC_PATH_PROGS(NROFF, gnroff nroff)
917 AC_PATH_PROGS(TROFF, groff troff)
919 AC_ARG_VAR(RRDDOCDIR, [[DATADIR/doc/PACKAGE-VERSION] Documentation directory])
920 if test -z "$RRDDOCDIR"; then
921 RRDDOCDIR='${datadir}/doc/${PACKAGE}-${VERSION}'; fi
924 CONFIGURE_PART(Apply Configuration Information)
926 AC_CONFIG_FILES([examples/shared-demo.pl])
927 AC_CONFIG_FILES([examples/piped-demo.pl])
928 AC_CONFIG_FILES([examples/stripes.pl])
929 AC_CONFIG_FILES([examples/bigtops.pl])
930 AC_CONFIG_FILES([examples/minmax.pl])
931 AC_CONFIG_FILES([examples/4charts.pl])
932 AC_CONFIG_FILES([examples/perftest.pl])
933 AC_CONFIG_FILES([examples/Makefile])
934 AC_CONFIG_FILES([examples/rrdcached/Makefile])
935 AC_CONFIG_FILES([doc/Makefile])
936 AC_CONFIG_FILES([po/Makefile.in])
937 AC_CONFIG_FILES([src/Makefile])
938 AC_CONFIG_FILES([src/librrd.sym.in])
939 AC_CONFIG_FILES([src/librrd.pc])
940 AC_CONFIG_FILES([bindings/Makefile])
941 AC_CONFIG_FILES([bindings/tcl/Makefile])
942 AC_CONFIG_FILES([bindings/tcl/ifOctets.tcl])
943 AC_CONFIG_FILES([Makefile])
944 AC_CONFIG_FILES([bindings/lua/Makefile])
946 AC_CONFIG_COMMANDS([default],[[ chmod +x examples/*.pl]],[[]])
948 dnl intl requires our config to be called config.h. indulge it.
949 AC_CONFIG_COMMANDS_POST([ test -f config.h || ln -s rrd_config.h config.h ])
951 AC_OUTPUT
953 AC_MSG_CHECKING(in)
954 AC_MSG_RESULT(and out again)
956 echo $ECHO_N "ordering CD from http://tobi.oetiker.ch/wish $ECHO_C" 1>&6
957 sleep 1
958 echo $ECHO_N ".$ECHO_C" 1>&6
959 sleep 1
960 echo $ECHO_N ".$ECHO_C" 1>&6
961 sleep 1
962 echo $ECHO_N ".$ECHO_C" 1>&6
963 sleep 1
964 echo $ECHO_N ".$ECHO_C" 1>&6
965 sleep 1
966 AC_MSG_RESULT([ just kidding ;-)])
967 echo
968 echo "----------------------------------------------------------------"
969 echo "Config is DONE!"
970 echo
971 echo " With MMAP IO: $enable_mmap"
972 echo " Build rrd_getopt: $build_getopt"
973 echo " Build rrd_graph: $enable_rrd_graph"
974 echo " Static programs: $staticprogs"
975 echo " Perl Modules: $COMP_PERL"
976 echo " Perl Binary: $PERL"
977 echo " Perl Version: $PERL_VERSION"
978 echo " Perl Options: $PERL_MAKE_OPTIONS"
979 echo " Ruby Modules: $COMP_RUBY"
980 echo " Ruby Binary: $RUBY"
981 echo " Ruby Options: $RUBY_MAKE_OPTIONS"
982 echo " Build Lua Bindings: $enable_lua"
983 if test "$enable_lua" = "yes"; then
984 echo " Lua Binary: $LUA"
985 echo " Lua Version: $lua_version"
986 echo " Lua C-modules dir: $LUA_INSTALL_CMOD"
987 if test "$lua_need_compat51" = "1"; then
988 echo " Lua Lua-modules dir: $LUA_INSTALL_LMOD"
989 fi
990 fi
991 echo " Build Tcl Bindings: $enable_tcl"
992 echo " Build Python Bindings: $enable_python"
993 echo " Build rrdcgi: $enable_rrdcgi"
994 echo " Build librrd MT: $enable_pthread"
995 echo " Use gettext: $USE_NLS"
996 echo " With libDBI: $have_libdbi"
997 echo " With libwrap: $have_libwrap"
998 echo
999 echo " Libraries: $ALL_LIBS"
1000 echo
1001 echo "Type 'make' to compile the software and use 'make install' to "
1002 echo "install everything to: $prefix."
1003 echo
1004 echo " ... that wishlist is NO JOKE. If you find RRDtool useful"
1005 echo "make me happy. Go to http://tobi.oetiker.ch/wish and"
1006 echo "place an order."
1007 echo
1008 echo " -- Tobi Oetiker <tobi@oetiker.ch>"
1009 echo "----------------------------------------------------------------"